Zeichenfunktion

[MartinaBiomech]

Hallo, sicherlich ein nur kleines Problem. Auf der Homepage von macromedia findet sich für das Zeichnen einer Linie in Abhängigkeit von der Position zweier MC folgendes Script:

// place the two handles for the endpoints
_root.attachMovie("squareHandle", "h1", 5);
_root.attachMovie("squareHandle", "h2", 6);
h1._x = 50;
h1._y = 150;
h2._x = 250;
h2._y = 150;
// create a clip to draw to
_root.createEmptyMovieClip("mc", 1);
// this function redraws the line
function draw() {
	// clear out the old line
	mc.clear();
	// set our line style
	mc.lineStyle(1, 0x000000);
	// draw the line based on handle locations
	mc.moveTo(h1._x, h1._y);
	mc.lineTo(h2._x, h2._y);
}
// call draw every 25 milliseconds
setInterval(draw, 25);

Jetzt wollte ich das ganze in eine eigene Funktion schreiben. Die Linie ist sichtbar aber sie wird beim Bewegung der MC's nicht mehr neu gezeichnet. Wo habe ich den Fehler eingebaut. Danke und Gruß Martina

function zeichnen(movieClip, pos1X, pos1Y, pos2X, pos2Y) {
	movieClip.clear();
	movieClip.lineStyle(1, 0x000000);
	movieClip.moveTo(pos1X, pos1Y);
	movieClip.lineTo(pos2X, pos2Y);
}
_root.attachMovie("squareHandle", "h1", 5);
_root.attachMovie("squareHandle", "h2", 6);
h1._x = 50;
h1._y = 150;
h2._x = 250;
h2._y = 150;
_root.createEmptyMovieClip("mc", 1);
zeichnen(mc, h1._x, h1._y, h2._x, h2._y);
setInterval(zeichnen, 25);

[Janoscharlipp]

durch das Interval wird zwar zeichen aufgerufen, allerdings ohne Parameter.
Du musst also erstmal die Koordinaten der MovieClips auslesen, z.B. so:

PHP-Code:

function zeichnen(movieClip, pos1X, pos1Y, pos2X, pos2Y) {
    movieClip.clear();
    movieClip.lineStyle(1, 0x000000);
    movieClip.moveTo(pos1X, pos1Y);
    movieClip.lineTo(pos2X, pos2Y);
}
_root.attachMovie("squareHandle", "h1", 5);
_root.attachMovie("squareHandle", "h2", 6);
h1._x = 50;
h1._y = 150;
h2._x = 250;
h2._y = 150;
_root.createEmptyMovieClip("mc", 1);
zeichnen(mc, h1._x, h1._y, h2._x, h2._y);

function positionen(timeline) {
  var h1 = timeline.h1;
  var h2 = timeline.h2;
  zeichnen(timeline, h1._x, h1._y, h2._x, h2._y);
}

setInterval(positionen, 25, mc); 


[MartinaBiomech]

Dein Code hat zur Folge das beim Filmtesten die Linie sich kurz zeigt und dann wieder verschwindet. Auch beim Bewegen der MC passiert nicht. Kannst du vielleicht noch mal schauen? Danke Martina

[Janoscharlipp]

sry, ich dachte h1 und h2 lägen in mc.

PHP-Code:

function zeichnen(movieClip, pos1X, pos1Y, pos2X, pos2Y) {
    movieClip.clear();
    movieClip.lineStyle(1, 0x000000);
    movieClip.moveTo(pos1X, pos1Y);
    movieClip.lineTo(pos2X, pos2Y);
}

_root.attachMovie("squareHandle", "h1", 5);
_root.attachMovie("squareHandle", "h2", 6);

h1.onPress = h2.onPress = function(){this.startDrag(true);};
h1.onRelease = h2.onRelease = h1.onReleaseOutside = h2.onReleaseOutside = function(){this.stopDrag();};

h1._x = 50;
h1._y = 150;
h2._x = 250;
h2._y = 150;

_root.createEmptyMovieClip("mc", 1);
zeichnen(_root.mc, h1._x, h1._y, h2._x, h2._y);

function positionen(timeline, canvas) {
  var h1 = timeline.h1;
  var h2 = timeline.h2;
  zeichnen(canvas, h1._x, h1._y, h2._x, h2._y);
  updateAfterEvent();
}

setInterval(positionen, 10, this, _root.mc);