Zeichen zählen etc.

[AmeKi]

Hallo,

da ich letztens so nette Hilfe bekommen habe, hoffe ich dass mir diesmal auch jemand helfen kann. Folgende Situation:

Ich habe ein Eingabefeld(count) und 2 dynamische Textfelder(ausgabe+ascii)

So nun zählt das Skript die Zeichen die eingegeben wurden in count und gibt diese in ausgabe aus. Daraufhin checkt es noch welcher Buchstabe eingegeben wurde und gibt diesem Buchstaben einen Wert (z.B. 0.2). In dem Feld ascii gibt er nun die Summe aus diesen Werten ein (z.B. A=2, B=3 würde bei ascii 5 stehen).
Funzt auch alles super nur das Prob ist wenn jemand einen Buchstaben entfernt weil er sich vertippt hat oder sowas dann zieht er die Werte nicht wieder ab. Ist zwar logisch weil ich nirgendwo festgelegt habe dass er das tun soll nur ich hab keine Ahnung wie ich das lösen soll. Weil wenn ich nämlich der BACKSPACE Taste sage lösche wert dann weiss diese zwar den letzten Wert aber nicht den davor. Heisst wenn ich im Textfeld ABC stehen habe und die Summe dieser wäre zum Beispiel 5 dann auf BACKSPACE klicke zieht der nur den Wert von C ab aber nicht den von B und A weil er die ja nicht mehr kennt...

Für alle die es nicht ganz verstanden haben hier der Code auf einem MC

onClipEvent (keyDown){
  if(Key.getCode() == 71) { // TASTE G
i= i+0.5
 
  } else if(Key.getCode() == 82) { // TASTE R
i= i+0.7
 
  }  else if(Key.getCode() == 69) { // TASTE E
i= i+0.6
 
  } 
  else if(Key.getCode() == 78) { // TASTE N
i= i+0.4
 
  } 
}
 
onClipEvent(enterFrame) {
//trace (_root.count.length);
_root.ausgabe.text=_root.count.length+" Zeichen" // check bei enter frame wieviele zeichen eingegeben wurden //
//_root.ascii.text= Key.getCode(); // gibt ascii code der letzten gedrückten zeichen wieder
 
updateAfterEvent();
} 

Ich bedanke mich schonmal für Ideen
Das .fla liegt hier: www.green-eye.de/soundkonfi/testcount.fla

gruß
AmeKi

[bokel]

Am einfachsten durchläufst du bei jeder Änderung den ganzen Eingabestring und rechnest die Summe aus.

mfg. r

[AmeKi]

ok ist eine Idee und wie zähl ich nun die einzelnen buchstaben aus dem Textfeld?!?

[bokel]

Schau dir mal String.charAt an, damit kannst du auf einzelne Buchstaben eines Strings zugreifen. Oder du splittest den String komplett in ein Array mit meinStringAlsArray = meinString.split("");

mfg. r

[AmeKi]

hmmm die FUnktion ist gut nur krieg ich das trotzdem irgendwie nicht hin. Hab jetzt einiges probiert aber es funktioniert noch nicht so ganz. Ich krieg das nicht hin dass der mir im Textfeld all a's oder b's etc zählt. Ich hab das zwar jetzt so dass der den letzten Buchstaben sich merkt aber wenn man schnell was eingibt und dann schnell wieder löscht dann kommt Flash da sehr durcheinander...

Hast du vielleicht Zeit/Lust mir ein kleines fla zu basteln mit einem Beispiel?
Weil so wie es jetzt ist ist es nicht wirklich gut...

wahrscheinlich ist es ganz einfach und ich komm da nicht drauf *grml*

[Der Frager]

Hi!
Hier mal nur der Check auf den Buchstaben "a":

this.der_txt.onChanged = function() {
    var as = 0;
    for (var x = 0; x<this.text.length; x++) {
        if (this.text.charAt(x) == "a") {
            as++;
        }
        trace("Im Text sind "+as+" as!")
    }
}; 

[bokel]

Klar, kein Problem. Einfach einen neuen Film aufmachen und das folgende Script in den ersten Frame kopieren:

createTextField("tfInput", 0, 0, 0, 100, 20);
createTextField("tfLength", 1, 0, 25, 100, 20);
createTextField("tfSum", 2, 0, 50, 100, 20);
 
tfInput.border = true;
tfInput.type = "input";
tfLength.border = true;
tfSum.border = true;
 
tfLength.update = function( text){
    this.text = text.length + " Zeichen";
}
 
tfSum.update = function( text){
    var sum = 0;
    for( var i=0; i<text.length; i++){
        var ch = text.charAt(i);
        if(ch == "G") { 
          sum += 0.5;
        } else if(ch == "R") { 
          sum += 0.7;
        } else if(ch == "E") {
          sum += 0.6;
        } else if(ch == "N") {
          sum += 0.4;
        }
    }
    this.text = sum;
}
 
tfInput.onChanged = function(){
    tfLength.update( this.text);
    tfSum.update( this.text);
} 

Das musst du jetzt nur noch auf deine Fla anpassen.
Gemein, nicht wahr?


mfg. r

[AmeKi]

SUPER vielen Dank euch Beiden für die Hilfe es funktioniert super...

Das mit dem anpassen hat wunderbar geklappt ist ja nich das Problem gewesen

[bokel]

Super, dass es jetzt klappt,
mfg. r