xml-ausgabe sortieren

[xlive]

hi,

habe eine kleine data selector mit xml/css gebastelt. es werden daten nach eingabe von drei parametern aus einer .xml selektiert und ausgeben.
die darstellung der werte in flash geschieht nach der reihenfolge, wie die daten aus der .xml ausgelesen werden.
jetzt soll aber die reihenfolge der daten nach der min. geschwindigkeit sortiert werden, d.h. der kleinste wert steht in der ersten zeile.
schreibe ich nun das ganze in einer Array.sort(). was aber aufgrund der xml.dynamik der anwendung nicht ganz einfach ist?!

erklärung zur anwendung eingaben der drei parameter:
combobox1: typ der düse
volumen: eingabe < 50
combobox2: geschwindikeit wählen

bei der ausgabe erscheint dann der düsentyp, die min/max geschwindigkeit und eine tabelle.
nicht für alle eingebenen werte, gibt es auch ein passende ausgabewerte->erscheint dann fehlermeldung "kein wert vorhanden"

hier mal drei parameter mit denen es klappt.
Größe: M
Volumen: 50
Geschwindigkeit:25

datei ist gepostet unter: http://www.flashbanditen.de/xmlsort.zip

gruß xlive

[hgseib]

wenn du sortieren willst, dann musst du auch ein array haben. XML wird nicht sortiert!
wenn deine XML-daten geladen wurden, dann erstelle direkt daraus ein mehrdimensionales array. das kannst du dann nach den unterschiedlichsten kriterien sortieren.


----------
zu deiner selectauswahl
wenn du deine daten empfangen hast, dann kannst du überprüfen, was überhaupt da ist. was nicht existiert brauchst du erst garnicht in den selects anzubieten.

----------
gliedere deinen spagetticode!
je teilaufgabe eine function. an deren namen kann man dann den programmablauf erkennen und die funktionalität von einzelnen schritten besser testen.

----------
du erstellst einen ziemlich 'aufgeblasenen' code. das trägt nicht unbedingt zur übersichtlichkeit bei:

content_mc.attachMovie("player_mc", "player_" add playernum, contentlevel);
content_mc["player_" add playernum]._x = xDiv*(playerwidth+20);
content_mc["player_" add playernum]._y = yDiv+5;
content_mc["player_" add playernum].artikel = rootnd.childNodes[i].childNodes[k].childNodes[0].firstChild;
content_mc["player_" add playernum].picture.loadMovie("./" add rootnd.childNodes[i].childNodes[k].childNodes[1].firstChild);
content_mc["player_" add playernum].link = rootnd.childNodes[i].childNodes[k].childNodes[2].firstChild;
...
// ist das selbe:
var _mc = content_mc.attachMovie("player_mc", "player_"+playernum, contentlevel);
_mc._x = xDiv*(playerwidth+20);
_mc._y = yDiv+5;
var nodes = rootnd.childNodes[i].childNodes[k].childNodes;
_mc.artikel = nodes[0].firstChild;
_mc.picture.loadMovie("./"+nodes[1].firstChild);
_mc.link = nodes[2].firstChild;
... 

das ist kürzer, somit weniger tippfehler möglich, kann einfacher geändert werden und wesentlich schneller, da du z.b. ständig mit childNodes aus dem XML ein array machst. einmal langt doch ;-)
und warum lädst du farbige rechtecke als jpg's ???

[xlive]

hi,

genau ein new array muss he, soweit ist das schon klar. nur leider stehe auf dem schlauch.
die frage ist wann bzw. wo ich das array anlege, denke mal vor dem attacheMovie, d.h. die werte werden dann sortiert, attached und ausgeben. nur wenn ich, das new Array in die schleife schreibe, wird es ja bei jedem schleifendurchlauf neu angelegt?!
hier mal ein wenig script denke mal hier muss eingriff stattfinden

rootnd = mein_xml.childNodes[0].childNodes[5];
var noresult:Number = 0;
//Hier wird _root.comboBox1.getValue() übergeben, d.h. ob VF, F, M usw.)
for (i=droplet1; i<droplet2; i++) {
    //Der Wert(km/h) der zweiten Combobox
    var columnB4:Number = ((combowert2/1200)*volumen);
    var j:Number = 0;
    //Hier werden werden die ausgewählten Werte (min/max) eingelesen 
    for (k=0; k<rootnd.childNodes[i].childNodes.length; k++) {
        _root["columnF"+j] = new Number(rootnd.childNodes[i].childNodes[k].childNodes[6].firstChild.toString());
        _root["columnG"+j] = new Number(rootnd.childNodes[i].childNodes[k].childNodes[7].firstChild.toString());
        trace("Alle Werte: "+_root["columnF"+j]);
        var valuevmin:Number = (Math.round(((_root["columnF"+j]*1200)/volumen)*10)/10);
        var valuevmax:Number = Math.floor(((_root["columnG"+j]*1200)/volumen)*10)/10;
        //--
        //Erfüllen die Werte aus der ersten Combobox die Bedingung, werden die dazugehörigen Nodes eingelesen
        if (columnB4>_root["columnF"+j] && columnB4<_root["columnG"+j]) {
            //
            noresult = 1;
            ausgabe_txt12.text = "";
            trace("Ausgabe: "+_root["columnF"+j]);
            switch (rootnd.childNodes[i].nodeName) {
            case "droplet" :
                contentlevel++;
                playernum++;
                if (xDiv == 1) {
                    xDiv = 0;
                    yDiv = content_mc._height;
                }
                //Play_mc attachen und ausrichten
                var ausgabe = content_mc.attachMovie("player_mc", "player_" add playernum, contentlevel);
                ausgabe._x = xDiv*(playerwidth+20);
                ausgabe._y = yDiv+5;
                var nodes = rootnd.childNodes[i].childNodes[k].childNodes;
                //player_mc LadeBefehle absetzen, Felder befüllen und Link setzen
                ausgabe.artikel = nodes[0].firstChild;
                ausgabe.picture.loadMovie("./" add nodes[1].firstChild);
                ausgabe.link = nodes[2].firstChild;
                //Abfrage um bei Ganzzahlen ein Komma zu setzen
                var valuevmin1:String = valuevmin.toString();
                if (valuevmin1.indexOf(".", 0) == -1) {
                    ausgabe.vmin = valuevmin1+".0";
                } else {
                    ausgabe.vmin = valuevmin1;
                }
                //--
                var valuevmax1:String = valuevmax.toString();
                if (valuevmax1.indexOf(".", 0) == -1) {
                    ausgabe.vmax = valuevmax1+".0";
                } else {
                    ausgabe.vmax = valuevmax1;
                }
                //Balkenanzeige
                ausgabe.balken._x = ((valuevmin*3)+218);
                ausgabe.balken._width = ((valuevmax-valuevmin)*3);
                //--------------------------------------------------------------------------
                //Highlighten 
                //Artikel No.
                ausgabe.button.onRollOver = function() {
                    this._parent.button.artikelcolor.textColor = 0xAACEAB;
                    _root["container"+i]._x = 0;
                    _root["container"+i]._y = 325;
                    _root["container"+i].loadMovie(this._parent.link);
                };
                ausgabe.button.onRollOut = function() {
                    this._parent.button.artikelcolor.textColor = 0x0A510A;
                    _root["container"+i].unloadMovie();
                };
                //--------------------------------------------------------------------------
                xDiv++;
                //}
                //Da jetzt ein neuer Wert kommt, muß unbedigt yDiv neu gesetzt werden, damit auch auf jeden Fall gewährleistet ist, daß die Abstände stimmen;
                yDiv = content_mc._height;
                xDiv = 0;
                yDiv++;
                break;
            case "FRAGEN" :
                break;
            }
        }
        j += 1;
    }
}
if (noresult == 0) {
    ausgabe_txt12.text = _root.errorvalue4;
} 

gruß xlive

[hgseib]

bitte deinen endlosen spagetticode entwirren:
- die XML-daten müssen geladen werden. das ergibt eine eigenständige function. so eine funktion kann man auch für andere projekte nutzen.
- die tabelle löschen == eine eigenständige funktion
- die tabelle anzeigen == eine eigenständige funktion (vorraussichtlich sogar mehrere)
- das xml in ein array überführen == eine eigenständige funktion
usw.
damit man mal durchblicken kann ;-)

dann:
function fINIT() {
fTabelleClear();
fXML_load();
fXML2Array();
}

selects.onChange() {
parameter = xyz;
fTabelleClear();
fTabelleShow();
}

column kannst du ruhig zusammenfassen und bei data ein id ergänzen.

PHP-Code:

<?xml version="1.0"?>
<element>
  <level>...</level>
  <selector>...</selector>
  <combobox>...</combobox>   
  <table>...</table>
  <error>...</error>
  <data id='data'>
    <droplet size="VF">
      <nozzle>
        <name>XR11001</name>
        <flag>data/orange.jpg</flag>
        <link>data/b40.jpg</link>
        <column>0.23,2.5,4.5,0.36,0.49</column>    
      </nozzle>
      <nozzle>
        <name>XR110015</name>
        <flag>data/lightgreen.jpg</flag>
        <link>data/b41.jpg</link>
        <column>0.34,3.5,4.5,0.64,0.72</column>    
      </nozzle>
      <nozzle>
        <name>TF 035</name>
        <flag>data/darkblue.jpg</flag>
        <link>data/b32.jpg</link>
        <column>,,,0.39,0.83</column>
      </nozzle>
    </droplet>
  </data>
</element>

droplet_ary = [];
fXML_load("data/data2.xml");
//
function fXML_load(vFileName) {
    var _xml = new XML();
    _xml.ignoreWhite = true;
    _xml.load(vFileName);
    _xml.onLoad = function(ok) {
        if (ok) {
            fXML2Array(this);
            fTest();
        } else {
            trace("fehler");
        }
    };
}
function fXML2Array(_xml) {
    // durch id='xxx' kann man geziehlt werte auslesen
    var droplet = _xml['data'].childNodes;
    for (var i in droplet) {
        var nozzle_ary = [];
        var nozzle = droplet[i].childNodes;
        for (var j in nozzle) {
            var nj = nozzle[j].childNodes;
            var name = nj[0].firstChild;
            var flag = nj[1].firstChild;
            var link = nj[2].firstChild;
            var column = nj[3].firstChild.toString().split(',');
            for (var k in column) {
                column[k] = Number(column[k]);
            }
            nozzle_ary.push({name:name, flag:flag, link:link, column:column});
        }
        droplet_ary.push({size:droplet[i].attributes.size, nozzle:nozzle_ary});
    }
}
function fTest() {
    for (var i in droplet_ary) {
        trace(droplet_ary[i].size);
        trace(droplet_ary[i].nozzle[0].name);
        var h = droplet_ary[i].nozzle[0].column[0];
        if (!isNaN(h)) {
            trace(h);
        }
    }
} 

[xlive]

hi,

ersmal danke für das professionelle script. werde jetzt mal versuchen, das ganze mit meinen bescheidenen programmierkenntnissen in mein script einzuarbeiten.
werde mich diesbezüglich bestimmt nochmal melden

danke. bis dahin.

gruß xlive

[xlive]

hi,

bastel noch an der xml-sortierung. danke nochmal hgseib für dein script, leider klappt es noch nicht ganz, dass ganze in mein script einzubauen und es drängt schon etwas die zeit. die anwendung ist soweit fertig und läuft wunderbar, bis auf die sortierung. habe nun mal eine teilscript zum testen der sortierung rausgenommen und nun folgendes problem:
wenn in das array die werte aus columnF schreibe, kann ich sie aufssteigend sortieren, gut.
jetzt sollen noch die dazugehörigen werte aus columnG mit ausgegeben werden, .d.h. wenn die werte aus columnF sortiert werden, müssen natürlich die werte aus columG mitsortiert werden.

bsp:
vor sortierung:
2 -> 20
3 -> 30
1 -> 10

nach sortierung:
1 -> 10
2 -> 20
3 -> 30

rootnd = mein_xml.childNodes[0].childNodes[5];
personDB = new Array();
for (i=droplet1; i<droplet2; i++) {
    var columnB4:Number = ((combowert2/1200)*volumen);
    for (k=0; k<rootnd.childNodes[i].childNodes.length; k++) {
        xmlpath = rootnd.childNodes[i].childNodes[k];
        var columnF = new Number(xmlpath.childNodes[6].firstChild.toString());
        var columnG = new Number(xmlpath.childNodes[7].firstChild.toString());
        //--
        //personDB.push(columnF);
        personDB.push({min:columnF, max:columnG});
        
    }
 
}
var sortwert = personDB.sort();
//--
// Sortieren 
function sortieren(sortwert) {
    personDB = sortwert;
    //min = max;
    for (i=0; i<personDB.length; i++) {
        //output1.text += personDB[i]+"\n";
        output1.text += personDB[i]["min"]+"\n";
        output2.text += personDB[i]["max"]+"\n";
    }
}
sortieren(sortwert); 

nur leider haut es nicht ganz hin. wie kann ich meine array aufsteigend nach columF sortieren das die dazugehörigen werte aus columnG mit sortiert werden?
gruß xlive

P.S.: hgseib, werde mir auf alle dein script in einer ruhigeren minute mal ganz genau anschauen.

[subHero]

zugegebenermassen: ich verstehe nicht so ganz genau, was dein problem ist, aber eins ist sicher: ein blick in die hilfe hilft (autsch) immer.

personDB=new Array();
personDB.push({min: .36, max: .49});
personDB.push({min: .64, max: .72});
personDB.push({min: .39, max: .83});
personDB.push({min: .6, max: .75});
// zur veranschaulichung
minSortedArr=personDB.slice();
maxSortedArr=personDB.slice();
minSortedArr.sortOn("min", Array.NUMERIC);
maxSortedArr.sortOn("max", Array.NUMERIC); 

hoffe'shilft
-sh

[xlive]

danke für den tipp. aus der hilfe bin ich nicht so recht schlau geworden.
habe es also jetzt mal so gemacht, und? puuuhh, es funktioniert bis jetzt...
kurz zur erklärung was das ganze soll
habe eine xml-tabelle mit zwei "spalten". in der einen steht vmin. in der anderen die vmax. die ausgabe der geschwindigkeitswerte in flash soll nach vmin. sortiert werden, d.h. jetzt muss für produkt a natürlich der vmax-wert noch der gleiche sein wie auch in der tabelle, muss also in der richtigen reihenfolge mit vmin sortiert werden.

rootnd = mein_xml.childNodes[0].childNodes[5];
personDB = new Array();
for (i=droplet1; i<droplet2; i++) {
    var columnB4:Number = ((combowert2/1200)*volumen);
    for (k=0; k<rootnd.childNodes[i].childNodes.length; k++) {
        xmlpath = rootnd.childNodes[i].childNodes[k];
        var columnF = new Number(xmlpath.childNodes[6].firstChild.toString());
        var columnG = new Number(xmlpath.childNodes[7].firstChild.toString());
        //--
        //personDB.push(columnF);
        personDB.push({min:columnF, max:columnG});
    }
}
minSortedArr = personDB.slice();
minSortedArr.sortOn("min", Array.NUMERIC);
// Sortieren 
function sortieren(minSortedArr) {
    personDB = minSortedArr;
    for (i=0; i<personDB.length; i++) {
        output1.text += personDB[i]["min"]+"\n";
        output2.text += personDB[i]["max"]+"\n";
    }
}
sortieren(minSortedArr); 

gruß xlive