wohin mit dem Script?

[*perplex*]

Hallo,
Im Script2 werden externe Bilder geladen. Den Ladevorgang möchte ich mit dem Script1 grafisch aufpeppen. Dummerweise funktioniert die Berechnung der Prozente nicht richtig. Wo/wie muss das erste Script im zweiten plaziert werden?

Script1:

PHP-Code:

prozente = Math.round(b/a*100);
balken.maske._xscale = prozente;
ausgabe.text = "LOADING "+prozente+"%"; 


Script2:

PHP-Code:

stop();
balken.maske._xscale = 0;
a= 275557;                         //entspricht der Anzahl der zu ladenden Bytes
b = getBytesLoaded();
_global.pfad = "corporatedesign/CNimage/";
var anzahl = 7;
var c = 0;
var d = 0;
function preload(vor, nach) {
    for (var i = 1; i<=anzahl; i++) {
        mc = this.createEmptyMovieClip("mc"+i, i);
        mc._alpha = 0;
        wat = this.createEmptyMovieClip("watcher"+i, 100+i);
        wat.t = mc;
        mc.loadMovie(pfad+vor+i+nach+".jpg");
        //trace(vor+i+nach+".jpg");
        wat.onEnterFrame = function() {
            if (this.t.getBytesLoaded()>=this.t.getBytesTotal() && this.t.getBytesLoaded()>10) {
                //trace(this.t+" geladen");
                removeMovieClip(this.t);
                removeMovieClip(this);
                if (++c == anzahl) {
                    if (d == 0) {
                        d++;
                        c = 0;
                        preload("bild", "a");
                    } else if (d == 1) {
                        d++;
                        c = 0;
                        preload("tn00", "");
                    } else if (d == 2) {
                        //trace("Alle Bilder im Cache...");
                        //trace("d ="+d+" und c ="+c);
                        gotoAndPlay(_currentframe+1);
                    }
                }
            }
        };
    }
}
preload("bild", ""); 


Danke,
Chris

[bamboocha]

Script1 kommt in Script2 und zwar in den wat.onEnterFrame gleich auf die nächste Zeile!
btw. das Skript kommt mir bekannt vor...

PHP-Code:

wat.onEnterFrame = function() { 
            var a = this.t.getBytesLoaded();
            var b = this.t.getBytesTotal();
            prozente = Math.round(b/a*100); 
            balken.maske._xscale = prozente; //Hier noch den Pfad anpassen!
            ausgabe.text = "LOADING "+prozente+"%"; //DITO - Pfad!
            if (a>=b && a>10) { 
                ... 


[*perplex*]

Zitat von bamboocha

das Skript kommt mir bekannt vor...

jo, hatt ich schon öfters mal gepostet

hab jetzt noch folgendes Problem mit der Ladeanzeige:

PHP-Code:

var a = this.t.getBytesTotal();
var b = this.t.getBytesLoaded(); 


Dieser Bestandteil des Scripts sorgt dafür, dass ich nicht einen Ladebalken für alle Bilder habe, sondern einen pro Bild. Sieht uncool aus, wenn sich der Ladevorgang (scheinbar) x-mal wiederholt.

Deshalb hatte ich ihm ja für a den festen Wert mitgegeben, stellvertretend für das PHP-Script was bei mir nicht geklappt hat (Du erinnerst Dich vielleicht noch daran). Aber mit diesem Wert hat er die Funktion nicht mehr bis zum Ende ausgeführt.

Hast Du dafür evtl. noch einen Lösungsansatz?

Besten Dank!
Chris

[bamboocha]

axo...!
Kein Wunder, wenn du einfach so wichtig Infos unterschlägst!
Hmmm... da müsste man nochmal über die Bücher... *hmmmm*
Das wird schwierig, da ne globale Anzeige zu basteln, da du die Bilder ja nacheinander lädst...
Das einzige, was du machen könntest ist, alle Bilder gleichzeitig zu laden und jene, die du noch nicht brauchst unsichtbar zu machen (_visible = false) oder aber aber der Bühen zu verschieben!?

[*perplex*]

Hi bamboocha,

wie müsste denn der Aufruf aussehen, um alle Bilder gleichzeitig zu laden? Doch nicht etwa so:

PHP-Code:

loadMovie(pfad+"bild1.jpg");
loadMovie(pfad+"bild2.jpg");
loadMovie(pfad+"bild3.jpg");
usw. 


[bamboocha]

Kommt darauf an, welche du alle laden willst...
aber grundsätzlich schon...
aber lässt sich sicherlich in ner Schleife lösen...

[*perplex*]

Hi bamboocha,
ich steh momentan noch etwas auf dem Schlauch und bitte Dich deshalb nochmals um Mithilfe.
Hier ist mein Script-Ansatz. Das Ziel ist Dir ja bekannt (externe Bilder für den späteren Gebrauch in den Cache laden inkl. grafischem Ladebalken)

PHP-Code:

stop();
balken.maske._xscale = 0;
//_global.pfad = "corporatedesign/CNimage/";
_global.pfad = "";

var anzahl = 7;
for (var i = 1; i<=anzahl; i++) {
        mc = this.createEmptyMovieClip("mc"+i, i);
        mc._alpha = 0;
        mc.loadMovie(pfad+"Bild"+i+".jpg");
        mc.loadMovie(pfad+"Bild"+i+"a.jpg");
        mc.loadMovie(pfad+"tn00"+i+".jpg");
        a = getBytesTotal();
        trace(a);
        b = getBytesLoaded();
        trace(b);
        prozente = Math.round(b/a*100);
        balken.maske._xscale = prozente;
        ausgabe.text = "LOADING "+prozente+"%";
        if (i==7) {
            gotoAndPlay(_currentframe+1);
        }
} 


Gruß,
Chris

[Der Frager]

Tag!

...was ist denn "a" nun? Im ersten Script hast du da eine feste Zahl drin stehen. Jetzt fängst du mit getBytesTotal() an? Außerdem kannst du nicht 3 Bilder in den selben mc laden - und - du musst schon mc.getBytesLoaded() benutzen, sonst fragst du die Bytes vom Hauptfilm ab.

Außerdem könntest du vor dem Laden auch alle zuladenden Bilder in ein Array schieben. Dann könntest du dir diesen "preload (vor,nach)"-Krempel auch schenken.

Wer schreib solche Scheiß-Preloader???

Ach warte, das war ja ich .

[bamboocha]

Probiers mal so (preloadIt wäre dann überflüssig):

PHP-Code:

stop(); 
balken.maske._xscale = 0; 
//_global.pfad = "corporatedesign/CNimage/"; 
var pfad = ""; 
var anzahl = 7; 
var arrLoader = new Array();
for (var i = 1; i<=anzahl; i++) { 
        mc = this.createEmptyMovieClip("mc"+i, i); 
        mc._alpha = 0;
        for(var z = 1; z < 4; z++) {
            var inhalt = mc.createEmptyMovieClip("inhalt"+z, z);
            arrLoader.push(inhalt);
        }
        mc.inhalt1.loadMovie(pfad+"Bild"+i+".jpg"); 
        mc.inhalt2.loadMovie(pfad+"Bild"+i+"a.jpg"); 
        mc.inhalt3.loadMovie(pfad+"tn00"+i+".jpg");  
}
var watcher = this.createEmptyMovieClip("watcher", anzahl+1);
watcher.onEnterFrame = function() {
    var b = 0;
    var a = 0;
    for(var i = 0; i < this._parent.arrLoader.length; i++) {
        a += this._parent.arrLoader.getBytesLoaded();
        b += this._parent.arrLoader.getBytesTotal();
    }
    prozente = Math.round(b/a*100); 
    balken.maske._xscale = prozente; 
    ausgabe.text = "LOADING "+prozente+"%"; 
    if(a == b && a > 10) {
        trace("alles geladen!");
        delete this.onEnterFrame;
        this.removeMovieClip();
    }
} 


[*perplex*]

Zitat von Der Frager

Wer schreib solche ******-Preloader???

Ach warte, das war ja ich .

@bamboocha,
Der bringt bei der Ausgabe immer nur NaN.
Mir fällts schwer da was zu modifizieren, da mir die Vorgehensweise unklar ist.

PHP-Code:

a += this._parent.arrLoader.getBytesLoaded(); //stimmt hier der Pfad??? 


[bamboocha]

ach menschenskinder...! Das i vergessen!

PHP-Code:

a += this._parent.arrLoader[i].getBytesLoaded(); //Pfad stimmt, allerdings ist n'Array halt noch keine Nummer! :D 


[*perplex*]

@bamboocha
habs eingebaut aber egal was ich mache: NaN oder infinity.
Hier nochmal das ganze Script:

PHP-Code:

stop(); 
balken.maske._xscale = 0; 
_global.pfad = "corporatedesign/CNimage/";
var anzahl = 7; 
var arrLoader = new Array();
for (var i = 1; i<=anzahl; i++) { 
        mc = this.createEmptyMovieClip("mc"+i, i);
        mc._alpha = 0;
        for(var z = 1; z < 4; z++) {
            var inhalt = mc.createEmptyMovieClip("inhalt"+z, z);
            arrLoader.push(inhalt);
        }
        mc.inhalt1.loadMovie(pfad+"Bild"+i+".jpg");
        mc.inhalt2.loadMovie(pfad+"Bild"+i+"a.jpg");
        mc.inhalt3.loadMovie(pfad+"tn00"+i+".jpg");
}
var watcher = this.createEmptyMovieClip("watcher", anzahl+1);
watcher.onEnterFrame = function() {
    var a = 0;
    var b = 0;
    for(var i = 0; i < this._parent.arrLoader.length; i++) {
        a += this._parent.arrLoader[i].getBytesLoaded(); // vertauscht man a mit b kommt infinity
        b += this._parent.arrLoader.getBytesTotal();     // hier hatt ich auch mal das [i] mit drin
    }
    prozente = Math.round(b/a*100); 
    balken.maske._xscale = prozente; 
    ausgabe.text = "LOADING "+prozente+"%"; 
    if(a == b && a > 10) {
        trace("alles geladen!");
        delete this.onEnterFrame;
        this.removeMovieClip();
        gotoAndPlay("start");
    }
} 


[bamboocha]

das i muss bei beiden stehen! GetBytesLoaded und GetBytesTotal!

[*perplex*]

Zitat von bamboocha

das i muss bei beiden stehen! GetBytesLoaded und GetBytesTotal!

In diesem Fall bekomme ich (auch) ein infinity zurück

Gruß
Chris

[bamboocha]

So funktionierts bei mir!

PHP-Code:

stop(); 
balken.maske._xscale = 0; 
_global.pfad = "corporatedesign/CNimage/";
var anzahl = 7; 
var arrLoader = new Array();
for (var i = 1; i<=anzahl; i++) { 
        mc = this.createEmptyMovieClip("mc"+i, i);
        mc._alpha = 0;
        for(var z = 1; z < 4; z++) {
            var inhalt = mc.createEmptyMovieClip("inhalt"+z, z);
            arrLoader.push(inhalt);
        }
        mc.inhalt1.loadMovie(pfad+"Bild"+i+".jpg");
        mc.inhalt2.loadMovie(pfad+"Bild"+i+"a.jpg");
        mc.inhalt3.loadMovie(pfad+"tn00"+i+".jpg");
}
var watcher = this.createEmptyMovieClip("watcher", anzahl+1);
watcher.onEnterFrame = function() {
    var a = 0;
    var b = 0;
    for(var i = 0; i < this._parent.arrLoader.length; i++) {
        a += this._parent.arrLoader[i].getBytesLoaded(); //bei beiden das i rein!
        b += this._parent.arrLoader[i].getBytesTotal();
    }
    prozente = Math.round(a/b*100); //und hier geladen durch Total nicht umgekehrt!
    balken.maske._xscale = prozente; 
    ausgabe.text = "LOADING "+prozente+"%";
    if(a == b && a > 10) {
        trace("alles geladen!");
        delete this.onEnterFrame;        
        this.removeMovieClip();
        gotoAndPlay("start");
    }
}