Wieder mal eine Pause / setInterval Frage :(

[Transmitter]

Hi,

ich bräuchte eine Pause in meinem Skript, aber leider klappt es nicht, ich weiß nicht wo ich sie einfügen soll bzw. wie.

Hier das Skript:

PHP-Code:

var arr = [];
var tween_handler:Object = '';
var tl = this;
var x_posis = [1, 110 , 219, 328, 437]; 

for (var x = 1; x<=9; x++)
{ 
    arr.push("MC"+x); 
}

function auswahl()
{ 
    var arr1 = arr.concat(); 
    for (var i = 0; i<5; i++)
    { 
        var clip = arr1.splice(random(arr1.length), 1); 
        // trace ( clip );
        trace ("fertig ausgewählt");
        tl.attachMovie(clip, clip, i, {_x:x_posis[i], _y:1}); 
        tl["t"+i] = new Tween(tl[clip], "_alpha", Strong.easeIn, 0, 100, 2, true);
        tl["t"+i].obj = tl[clip];
        tl["t"+i].onMotionFinished = function()
        {
            new Tween(this.obj, "_alpha", Strong.easeIn, 100, 0, 2, true); 
        };
    } 
}

// Das erste mal manuell starten: 
auswahl ( );


function updateTimer():Void
{
    // trace (getTimer());
    auswahl ( );
}


var intervalID:Number = setInterval(updateTimer, 4000); 


Es wird eine Auswahl aus ein paar MCs erstellt, willkürlich nebeneinander angeordnet, von 0 auf 100 eingefadet, JETZT soll das Skript 8 Sekunden anhalten, dann wieder von 100 auf 0 ausfaden.

Beispiele wie

PHP-Code:

_root.sleeptime=setInterval(function() {
if (test != null){
    callFunction(test);
  } 
},20000) 


habe ich viele gefunden, aber ich weiß nicht wie bzw. wo ich das bei mir einbauen muss

Könnt ihr mir da helfen?
Danke schon mal
Bye, Transmitter

aber ich weiß nicht wie bzw. wo ich das bei mir einbauen muss

Das kommt darauf an, wo du die Pause setzen willst. Z.B. bietet sich die onMotionFinished-Funktion an, weil da die Bewegung beendet ist.

[Transmitter]

Zitat von agedoubleju

Das kommt darauf an, wo du die Pause setzen willst. Z.B. bietet sich die onMotionFinished-Funktion an, weil da die Bewegung beendet ist.

Die Pause soll zwischen Fadeout und Fadein, sodass die Bilder länger zu sehen sind.
Ich hatte einen Versuch gestartet das vor die onMotionFinished Funktion zu setzen, aber bin da kläglich gescheitert
Wie sollte das denn aussehen?

Wie sollte das denn aussehen?

Hab ich doch geschrieben... Anscheinend wird doch im onMotionFinished der Alpha wieder zurückgesetzt. D.h. in der Funktion solltest du zuerst deine Intervallpause setzen und nach der Pause den new Tween in einer eigenen Funktion starten, bspw.:

PHP-Code:

tl["t"+i].onMotionFinished = function()
        {
            _level0.intervalID2  = setInterval(weiter, 8000,this); 
             
        }; 
function weiter(obj){
   clearInterval(_level0.intervalID2);
   new Tween(this.obj, "_alpha", Strong.easeIn, 100, 0, 2, true);
} 


[Transmitter]

Ja, das stimmt .. so werden die Bilder länger angezeigt.
Aber der Fadeout funktioniert nicht mehr, das ist ein harter Cut von 100 auf 0.
Kann man den Fadeout dann auch wieder anzeigen lassen?

[Transmitter]

Ich schieb das nochmal nach oben.

Scheint nicht zu gehen, oder doch?

[Der Frager]

Hallo!
Nee, das this bei setInterval bezieht sich auf den Tween selbst und nicht auf den getweenten MC. So z.B. geht's:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
//
var tl = this;
var clip = "dein_mc";
var i = 0;
//
tl["t"+i] = new Tween(tl[clip], "_alpha", Strong.easeIn, 0, 100, 2, true);
tl["t"+i].mc = tl[clip]
//
tl["t"+i].onMotionFinished = function() {
    _level0.intervalID2 = setInterval(weiter, 1000, this.mc);
};
//
function weiter(obj) {
    clearInterval(_level0.intervalID2);
    new Tween(obj, "_alpha", Strong.easeIn, 100, 0, 2, true);
} 


[Transmitter]

Ich schieb das nochmal nach oben, das funktioniert leider immer noch nicht.

Ich habe das Gefühl, dass Flash nicht weiß welches Objekt ausgefadet werden soll.
Wenn ich weiter in setInterval aufrufe, wo wird denn da bei deinem Vorschlag der Parameter übergeben?

[Der Frager]

PHP-Code:

tl["t"+i] = new Tween(tl[clip], "_alpha", Strong.easeIn, 0, 100, 2, true);
//neuen Tween mit dem MC aus der Var "clip" 
tl["t"+i].mc = tl[clip] 
//diesen MC dem Tween anhängen
// 
tl["t"+i].onMotionFinished = function() { // wenn Tween fertig ist
    _level0.intervalID2 = setInterval(weiter, 1000, this.mc); 
//den Intervall "weiter" starten, 1000 wäre eine Sekunde, this.mc übergibt das Objekt
}; 
// 
function weiter(obj) { 
//obj wird hier also mit übergeben und enthält den MC
    clearInterval(_level0.intervalID2); 
    new Tween(obj, "_alpha", Strong.easeIn, 100, 0, 2, true); 
// der hier wierder ausgeblendet wird
} 


Wenn das bei dir nicht klappt, dann mach mal eine Beispieldatei fertig.

[Transmitter]

Bringt leider auch keinen Erfolg, ich hänge mal einen Barebone an und hoffe du kannst mir helfen.
Ich bin da absolut ratlos

[Der Frager]

Gut, bei mehreren Objekten überschreibst du ja den Intetervall... Guckst du hier:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
var tl = this;
var MCArray = [];
var x_posis = [50, 160, 279];
// MCs in ein Array laden:
for (var x = 1; x<=3; x++) {
    MCArray.push("MC"+x);
}
function auswahl() {
    var arr1 = MCArray.concat();
    for (var i = 0; i<2; i++) {
        // Ein MC auswählen:
        var clip = arr1.splice(random(arr1.length), 1);
        // Diesen MC zu this hinzufügen:
        tl.attachMovie(clip, clip, i, {_x:x_posis[i], _y:50});
        //neuen Tween mit dem MC aus der Var "clip"  
        tl["t"+i] = new Tween(tl[clip], "_alpha", Strong.easeIn, 0, 100, 2, true);
        //diesen MC dem Tween anhängen
        tl["t"+i].mc = tl[clip];
        tl["t"+i].onMotionFinished = function() {
            // wenn Tween fertig ist 
            this.mc.intervalID2 = setInterval(weiter, 4000, this.mc);
            //den Intervall "weiter" starten, 1000 wäre eine Sekunde, this.mc übergibt das Objekt 
        };
    }
}
function weiter(obj) {
    //obj wird hier also mit übergeben und enthält den MC 
    clearInterval(obj.intervalID2);
    new Tween(obj, "_alpha", Strong.easeIn, 100, 0, 2, true);
    // der hier wierder ausgeblendet wird 
}
auswahl(); 


[Transmitter]

Achja .. daran scheint es gelegen zu haben. :-S

Vielen Dank, jetzt kann ich wieder ruhig schlafen.