Wie mach ich aus Flash5-Script Flash6-Script ??

[ghazii]

Hallo zusammen,

ich hab das Problem, das ich einen Effekt im Flash5-Actionscript1 hab und diesen in einen Hauptmovie laden muss, der unter Flash6-Actionscript2 veröffentlicht wurde.

Ich vermute, das es an dem "prototype" liegt.
Wie kann ich diese Zeile umschreiben, sodas es funzt ??

movieclip.prototype.sinusInit = function () {
	_visible=0;

Wäre über Hilfe echt dankbar...

Gruß
Micha

[Der Frager]

Mal so testen:

PHP-Code:

MovieClip.prototype.sinusInit = function () {
    _visible=0;
} 


...obwohl Flash6 eigentlich auch noch nicht caase-sensitive war!?

[ghazii]

Das hat leider nicht geholfen

Ich hab mal die .fla angehängt.

wie gesagt:
als Flash5 geht´s als Flash 6 nicht

[Der Frager]

_parent ohne this davor ist meistens mist...

PHP-Code:

stop();
fscommand("allowscale", false);
MovieClip.prototype.sinusInit = function() {
    this._visible = 0;
    startx = this._x;
    starty = this._y;
    lWert = 50;
    inhalt = " The Ultimate Challenge :: 24. August 2007 :: Stadthalle Alsdorf :: Der erste Käfig Free-Fight in der EUREGIO";
    inhalt = inhalt.toUpperCase();
    anzahl = inhalt.length;
    for (i=1; i<=anzahl; i++) {
        this._parent.zeichen.duplicateMovieClip("zeichen"+i, i);
        this._parent["zeichen"+i].text = inhalt.substr(i, 1);
    }
};
MovieClip.prototype.sinusText = function(tempo, faktorX, faktorY, breite, hoehe) {
    j += tempo;
    calX = startx-(j*breite/faktorX);
    calY = starty+((Math.sin(j*Math.PI/180))*hoehe/faktorY);
    x1 = this._x;
    y1 = this._y;
    x0 = calX;
    y0 = calY;
    wertX = (x1-x0)/2;
    wertY = (y1-y0)/2;
    winkel = ((Math.atan2(wertY, wertX)/Math.PI*180));
    this._rotation = winkel-180;
    this._x = calX;
    this._y = calY;
    for (i=1; i<=lWert; i++) {
        calX2 = calX+(i*14);
        calY2 = starty+((Math.sin((j-(i*14))*Math.PI/180))*hoehe/faktorY);
        if (this._parent["zeichen"+i]._x<600) {
            sx1 = this._parent["zeichen"+i]._x;
            sy1 = this._parent["zeichen"+i]._y;
            sx0 = calX2;
            sy0 = calY2;
            swertX = (sx1-sx0)/2;
            swertY = (sy1-sy0)/2;
            swinkel = ((Math.atan2(swertY, swertX)/Math.PI*180));
        }
        this._parent["zeichen"+i]._x = calX2;
        this._parent["zeichen"+i]._y = calY2;
        this._parent["zeichen"+i]._rotation = swinkel-180;
        if (this._parent["zeichen"+i]._x<-10) {
            removeMovieClip(this._parent["zeichen"+i]);
            lWert++;
        }
    }
};
//movieclip.prototype.kill = function() {
//    for (a in this) {
//        this[a].removeMovieClip();
//    }
//}; 


[ghazii]

TAUSEND DANK !!!!
Es funzt