Welcher Script ist besser???

[cbt]

Ich habe eine Frage: ist es immer gut, wenn man code nur in der Timeline von _root schreiben??

Ich habe 2 Scripts (selbe Funktion aber unterschiedliche Schreibeweise) :
-einer wird nur in der timeline von _root schreiben.
-der andere wird einen Teil in der timline von movie "mc" und einen Teil in time von _root

Ich würde gern wissen, welcher ist besser für den Computer??:
In der Bibliothek haben wir ein movieclip mit der linkage: "mc"

1.Script (in der timeline von _root):

for(i=0; i<10; i++){
 
    _root.attachMovie("mc","mc"+i,i)
    _root.["mc"+i]._x=random(550);

    _root["mc"+i].onEnterFrame=function(){
          //do something 

         .....
    }
}

2.Script:

ein Teil in der timeline von movie "mc":

this.onEnterFrame=function(){
     //do something wie oben 
     ....
}

Und der andere Teil in der timeline von _root:

for(i=0; i<10; i++){
    _root.attachMovie("mc","mc"+i,i)
    _root.["mc"+i]._x=random(550);
}

Ich glaube, der 2.Script ist besser, oder??
Denn der Computer muss weniger Abeit machen.

Beim 1.Script muss der Computer für jeder einzelne Instance von mc ein onEnterFrame function bestimmen. Also:
mc0.onEnterFrame=function(){...};
mc1.onEnterFrame=function(){...};
...

Wie glauben Sie??
Ich wäre sehr dankbar für Ihre Antworten

gruss,
cbt

[Deluxe]

hi,
wir können uns hier auf ein perdu einigen
Die 2. scripts geben sich im grund nichts.
klar hast du wenn du zB 10 enterFrame evnts manuell in die mcs einfügst dem movie etwas arbeit abgenommen aber diese ms an rechenzeit is völlig irrelevant wenn es nicht um 10000 objekte geht.

ich finde das 1.script angenehmer, schließlich muß ich dort weniger tun.


besten grüße
deluxe

[cbt]

Zitat von Deluxe

hi,
Die 2. scripts geben sich im grund nichts.
klar hast du wenn du zB 10 enterFrame evnts manuell in die mcs einfügst dem movie etwas arbeit abgenommen aber diese ms an rechenzeit is völlig irrelevant wenn es nicht um 10000 objekte geht.

naja, wenn ich sehr viele mcs erstellen möchte, heißt das, dass der 2.Script besser ist ???
Und außerdem, wenn in der onEnterFrame function () der Flash sehr viel Arbeit machen muss:
Also:

onEnterFrame=function(){
        //viel viel Arbeit machen muss
}

Dann ist der Script 2 viel besser oder??? Denn die instance mcs brauchen nur den Script des MovieClips "mc" in der Bibliothek übernehmen (inheritance), ähnlich wie wir ein Class für movie "mc" erstellen, oder??

auch besten Grüße ,

cbt

[hgseib]

da in beiden fällen jedes mc ein onEnterFrame bekommt sind deine "beiden" lösungen vollkommen identisch.

die testwert-unterschiede sind so gering, dass sie kaum auf die unterschiedlichen arbeitsmethoden bezogen werden können.

somit ist eher die frage, welche methode eleganter und wartungsfreundlicher ist.

bei variante 1 existierten je mc eine neue function, was speichertechnisch sehr ungeschickt ist.
bei variante 2 und 3 sind die listings verstreut und man muss sie für änderungen erst suchen.
bei variante 4 sind die fehler von 1 bis 3 nicht gegeben. ist übersichtlich und speicheroptimiert.
variante 5 ist eleganter als 4. die vorteile von classen kommen bei diesem einfachen beispiel natürlich noch nicht zur geltung.
variante 6 fällt etwas aus dem rahmen, da es hier keine x onEnterFrame's gibt, sondern tatsächlich nur eins. ein vorteil ist (zumindestens hier) nicht zu erkennen. nachteilig wird es, wenn die schleife zu lange dauert, dann "mäckert" flash.

fazit: variante 4 bzw classen sind zu bevorzugen.

var gTestAnz = 40;
var gTestDauer = 30*1000; // 30 sekunden
//
var sum = 0;
var iv = setInterval(fStopp, gTestDauer);
function fStopp() {
    clearInterval(_root.iv);
    trace(_root.sum);
}
// variante 1 == 36000
for (i=0; i<gTestAnz; i++) {
    mc = _root.attachMovie("mc", "mc"+i, i);
    mc._x = Math.random()*550;
    mc._y = Math.random()*350;
    mc.onEnterFrame = function() {
        _root.sum++;
        this._x++;
    };
}
/*
//  variante 2 == 35880 (programm in mc2)
//  variante 3 == 36000 (programm in mc3)
for (i=0; i<gTestAnz; i++) {
    mc = _root.attachMovie("mc3", "mc"+i, i);
    mc._x = Math.random()*550;
    mc._y = Math.random()*350;
}
*/
/*
// variante 4 == 36040
function fMC() {
    _root.sum++;
    this._x++;
}
for (i=0; i<gTestAnz; i++) {
    mc = _root.attachMovie("mc", "mc"+i, i);
    mc._x = Math.random()*550;
    mc._y = Math.random()*350;
    mc.onEnterFrame = fMC;
}
*/
/*
// variante 5 == 35840
function MeMC_Class() {}
MeMC_Class.prototype = new MovieClip();
MeMC_Class.prototype.onEnterFrame = function() {
    _root.sum++;
    this._x++;
};
Object.registerClass("mc", MeMC_Class);
//
for (i=0; i<gTestAnz; i++) {
    mc = _root.attachMovie("mc", "mc"+i, i);
    mc._x = Math.random()*550;
    mc._y = Math.random()*350;
}
*/
/*
// variante 6 == 35920
var gAry = new Array();
for (i=0; i<gTestAnz; i++) {
    mc = _root.attachMovie("mc", "mc"+i, i);
    mc._x = Math.random()*550;
    mc._y = Math.random()*350;
    gAry[i] = mc;
}
_root.onEnterFrame = function() {
    for (i in gAry) {
        gAry[i]._x++;
        _root.sum++;
    }
};
*/ 

anhang: flash6