welcher Button war aktiv

[markus78]

Hi Zusammen!

Ich steh vor einem kompletten Rätsel und ich hab keine Ahnung wie ich das lösen soll!


Also ich hab nehmen wir mal an 3. Buttons

So nun ist der erste aktiv (wie das auch immer gehen soll)
Dann klicke ich auf den 2. Button.

Wie weiß ich nun welcher Button vorher aktiv war?

Warum das?
Es soll erst eine Aktion ausgeführt werden, wenn ich einen anderen button drücke. Kann man aber glaube ich nicht anders lösen, denn die Buttons werden dynamisch erstellt, d.h. es kann 5 oder 15 buttons geben.

freue mich auf jeden Anregung

besten dank
markus

[screamingworld]

Hi Markus,

verstehe ich noch nicht ganz?
also es soll eine funktion ausgeführt werden wenn 2 buttons gedrückt worden sind? oder wie?

[RustyCake]

var welcher = " nix";
this.lila.onPress = function() {
    _root.texter.text = welcher+" war gedrückt!";
    welcher = this._name;
};
this.blau.onPress = function() {
    _root.texter.text = welcher+" war gedrückt!";
    welcher = this._name;
}; 

[Alois]

es geht ja wohl in erster Linie darum, den gedrückten Button aktiv und den vorher aktiven inaktiv zu schalten...
dafür bietet sich die Funktion watch() an, ein kleines Beispiel, erstelle einen mc mit 2 Frames (Frame1=inaktiv,Frame2=aktiv) mit einem stop() in frame1, gib ihm den Instanznamen 'mc0' und dann nur noch folgendes script in die Hauptzeitleiste:

control=new Object();
control.watch('neu',function(id,alterWert,neuerWert){
        alterWert.gotoAndStop(1);
     neuerWert.gotoAndStop(2);
        return neuerWert;
});
for(i=0;i<5;i++){
if(i!=0){
    mc0.duplicateMovieClip("mc"+i,i,{_x:mc0._x+i*mc0._width})
}
    this["mc"+i].onRelease=function(){
    control.neu=this;
    }
} 

...und fertig.

Gruß

Alois

[markus78]

danke ich hab es geschafft.

Es war im Endeffekt genau das was ihr beide gemacht habt, vereint.


besten dank
markus

[markus78]

so jetzt hab ich das ganze nochmal neu gecodet!
und ich komm einfach nicht drauf, woran das liegen kann.

Button1 ist aktiv die dazugehörigen LB sind auch aktiv. User hat etwas in die Listboxen eingetragen.

Es geht mir darum, der User soll, wenn er auf einen andern Button klickt dort wieder etwas in die Listboxen eingeben können. Das ist nicht das Problem.
Wenn er danach nochmals auf den Button 1 klickt, dann soll all das wiederkommen, was er bevor er auf button 2 geklickt hat, eingegeben hat.

Bei if (this["welcher"+z]==2) wird überprüft, ob der den Button schon mal gedrückt hat, das funktioniert auch einwandfrei. Also bräuchte ich dann nur noch das Script schreiben, damit er die Einträge wieder zurück in Listboxen schreibt.
ABer das Problem ist, wenn ich das unter dem else-Zweig dazuschalte, dann wird nicht mehr beim erstenmal gecheckt, ob der Button schon mal gedruckt wurde. Versteh ich aber nicht wieso!

Könnte sich das wer mal von euch bitte ansehen?

zahllist=2  //anzahl der Listboxen
 
_root.kurse0=[]   // ich kann doch nicht 10x _root.kurse0 - kurse10 schreiben
_root.kurse1=[]   // ausserdem versteh ich nciht warum ich root schreiben muß. gibt es auch eine andere Möglichkeit
 
 
 
gedruckt = ["mc0"]
 
welcher ="mc0"
control=new Object();
control.watch('neu',function(id,alterWert,neuerWert){
        alterWert.gotoAndStop(1);
        neuerWert.gotoAndStop(2);
        return neuerWert;
});
 
 
 
for(i=0;i<5;i++){
        if(i!=0){
                mc0.duplicateMovieClip("mc"+i,i,{_x:mc0._x+i*mc0._width})
                mc0.gotoAndStop(2)
        }
        this["mc"+i].onRelease=function(){
                _root.kurse0.length=0   // muss auch anderes gehen
                _root.kurse1.length=0
                mc0.gotoAndStop(1)
                control.neu=this;
                druck=welcher
                trace(welcher+" war gedrückt!")
            welcher = this._name;
                
                _root["Skz"+druck] = [[], []];
                trace (["Skz"+druck])
                
                gedruckt.push(this._name)
                trace (gedruckt)
                
                trace ("AKTUELL: "+welcher)
                for(i in gedruckt){
              if(gedruckt[i].indexOf(welcher,0) > -1) { 
                    this["welcher"+z]++
                    trace ("welcher+z  "+this["welcher"+z])
                    //trace("TEST "+test[i]) 
                        if (this["welcher"+z]==2){
                            trace ("JETZT"+gedruckt[i])
                            this["welcher"+z]=0
                            gedruckt.pop()
                            
                        }
                        else {
                            
                    /*    for (var z = 0; z<=zahllist; z++) {
                                anzahl = _root["LB"+z].getLength();
                            //  trace("LB"+z+": "+anzahl);
                                for (i=0; i<anzahl; i++) {
                            //    trace("INHALT: "+_root["LB"+z].getItemAt(i).label);
                                    var tt = _root["LB"+z].getItemAt(i).label;
                                    _root["kurse"+z].push(tt);
                                }
                            //  trace("ARRAY:" +_root.kurse0)
                            //  trace("ARRAY1:" +_root.kurse1)
                        
                            }
                            _root["Skz"+druck][0].push(kurse0) //muss auch anders gehen
                            _root["Skz"+druck][1].push(kurse1)
                            trace("ALL: "+["Skz"+druck]+" "+_root["Skz"+druck])
                            //_root.LB0.removeAll()
                            //_root.LB1.removeAll()
                            */  
                        } 
                  }
                    
            }
                
        }
} 

was mir auch noch gerade eingefallen ist, ich hab keine Ahnung, wie ich den gefüllten Array:"_root["Skz"+druck] in der if (this["welcher"+z]==2) Schleife verwenden kann.


besten dank
markus

[markus78]

könnte das was helfen, wenn man das mit einer fuction oder prototype realisiert. Leider kenn ich mich bei beiden dingen nicht so aus. Aber hätte das einen Sinn?

[Alois]

alles was man machen kann immer geht auch ohne funktionen/prototypen
funktionen und prototypen helfen das script übersichticher mache, würden also in Deinem Fall schon helfen diesen chaotischen spaghetticode zu entschlüsseln, wenn Du genau wüsstest was Du tust....allerdings zeigt mir das script schon, daß es per copy&paste entwickelt wurde, z.B. auch diese Aussage:

Es war im Endeffekt genau das was ihr beide gemacht habt, vereint.

...stimmt nicht, tatsächlich hast Du praktisch zweimal dasselbe mit zwei verschiedenen scripts gemacht, entweder rustys weg oder meiner, aber beide führt zu jeder Menge unnötigen script...
...was mir nach Durchsicht des scripts immer noch nicht klar ist, was soll das Ding überhaupt machen, da werden arrays erstellt und hin- und hergeschoben...irgendwas soll dann scheinbar auch noch remote eingefügt werden...mir scheint da noch einiges an script zuviel rumzuschwirren...mal ein paar direkte Fragen:
was soll das mit _root.kurse0-10....ist das abhängig von der Menge der Schaltflächen ,oder was, und warum benutzt Du da kein zweidimensinales array ???
Das hier:
_root.kurse0.length=0;
...kann überhaupt nicht funktioniern, length ist eine Eigenschaft und keine variable...
wofür brauchst Du eigentlich das gedruckt-array???...musst Du nur wissen ob die Schaltfläche einmal gedrückt wurde (und danach ist egal wie oft) oder was, dann bist Du allerdings einen äusserst komplizierten Weg gegangen
das kann auch nicht gehen:
if(gedruckt[i].indexOf(welcher,0) > -1) {
this["welcher"+z]++
trace ("welcher+z "+this["welcher"+z])
//trace("TEST "+test[i])
if (this["welcher"+z]==2){
trace ("JETZT"+gedruckt[i])
this["welcher"+z]=0
gedruckt.pop()
....
die variable z wird nirgendwo gesetzt...
....das solls erstmal sein, also versuch mal zu beschreiben was ablaufen soll, dann kann ich vielleicht auch helfen...

Gruß

Alois

[markus78]

Hallo Alois!

Also es geht darum, es werden dyn. Buttons erzeugt, wieviele, das hängt davon ab, wieviele der User vorher ausgewählt hat.
So nun hat er wie in diesem Beispiel. 5 Buttons ausgewählt. (also das passt schon mal mit dem [mc+i]

Zu jeder Schaltfläche kann es bis zu 8 Listboxen geben. Die werden aber nicht dynamisch erzeugt, die werden nur von unsichtbar auf sichtbar geschalten. Denn anderes ist es, für mich auf jeden Fall, zu kompliziert. (wird aber hier nicht berücksichtigt, denn wenn es für 2 Listboxen funktioniert, dann funtkioniert es für 8 genauso)
Die Schaltfläche Nummer eins ist am Anfang aktiv.
So nun trägt der User in die Listboxen "Werte" ein. Die nur für den button 1 gelten.

Wenn der User nun auf den zweiten Button klickt, sind alle Listboxen wieder leer. und er kann auch da wieder etwas eintragen. Das wiederrum nur für Button 2 gilt. usw.....
Klickt er wieder auf einen Button, bei dem er schon die Werte eingetragen hat, dann soll all das wieder drinnen stehen, was er vorher eingegeben hat. DAs wäre die Theorie.
__________________________________________________ _

Zu deinen Fragen:

Jede Listbox ist gleich einem Array mit dem Namen kurse. Da ich den aber überall ansprechen wollte, dachte ich mir ich mach das mit _root.

All die einzelnen Kurse -Arrays (_root.kurse0-_root.kurse7) werden dann in einen 8 dimensionale Array gespeichert. 8dim. weil es 8 Listboxen sind.
Und der ganze Inhalt von dem 8 dim. Array gilt dann für einen Button. D.h. also z.b. Button1= [[_root.kurse0],....,[_root.kurse7]]
was gleichbedeutend ist Button1= (Inhalt Listbox0),....,(Inhalt Listbox 7)


den gedrückt Array brauche ich, damit ich weiß, welchen der Buttons ich schon gedrückt habe. Denn es kann ja sein, dass er die buttons 1,2,3 drückt und dann vielleicht erst wieder auf den Button1 drückt.


_root.kurse0.length=0;
funktioniert, setzt den Inhalt des Arrays wieder auf leer.



Ich sprech ja hier einmal von 8 listboxen und einmal nur von 2, wenn es dich verwirrt hat, dann hier nochmal kurz die Erklärung. 8Listboxen werden es im Endeffekt sein, hier sind es aber nur 2. Denn wenn es für 2 funktioniert, dann funktioniert es später auch für 8


Würde mich über eine Anregung, wie ich das lösen könnte freuen.

besten dank
markus

P.S.: ich hoffe ich hab es einigermassen verständlich erklärt.

[Alois]

Geschrieben von markus78
....werden dann in einen 8 dimensionale Array gespeichert. 8dim. weil es 8 Listboxen sind.
Und der ganze Inhalt von dem 8 dim. Array gilt dann für einen Button. D.h. also z.b. Button1= [[_root.kurse0],....,[_root.kurse7]]

...das ist ein eindimensionales Array mit 8 Elementen ein achtdimensionales wäre z.B. sowas:
bigArray=[[[[[[[[]]]]]]]];
....ich denke nicht, daß du sowas brauchst

....den gedrückt Array brauche ich, damit ich weiß, welchen der Buttons ich schon gedrückt habe. Denn es kann ja sein, dass er die buttons 1,2,3 drückt und dann vielleicht erst wieder auf den Button1 drückt.

ja und? wofür jetzt das gedrückt array???

_root.kurse0.length=0;
funktioniert, setzt den Inhalt des Arrays wieder auf leer.

..sicher?, ich habs vorhin getestet und es hat nicht funktioniert, aber selbst wenn es funktioniert, ist es eigentlich falsch, richtig wäre _root.kurse0=[];


...ich setz mich dann jetzt mal ran und scripte Dir mal ein Beispiel...

also bis gleich

Gruß

Alois

[RustyCake]

So ich glaub ich check zwar immer noch net was geht!!
aber eine array durchsuch funktion kann ich Dir liefern!!

myArray = [];
function suche(array, was_suchen) {
    for (var i = 0; i<array.length; i++) {
        if (array[i] == was_suchen) {
            return i;
        }
    }
    return null;
}
for (var j = 1; j<=5; j++) {
    this["button_"+j].onPress = function() {
        if (suche(myArray, this._name) == null) {
            trace("In myArray ist " +this._name+ " noch nicht vorhanden");
            myArray.push(this._name);
        } else {
            trace("In myArray ist "+this._name+" vorhanden");
        }
    };
} 

[markus78]

Geschrieben von Alois
...das ist ein eindimensionales Array mit 8 Elementen ein achtdimensionales wäre z.B. sowas:
bigArray=[[[[[[[[]]]]]]]];
....ich denke nicht, daß du sowas brauchst

Nein das war falsch ich meinte nicht einen 8 dim, sondern eines mit 8 Elementen

ja und? wofür jetzt das gedrückt array???

damit ich weiß welchen Button ich gedrückt habe. Wenn du dir das von Rusty anschaust, der hat es doch auch so gemacht wie ich, der hat doch auch einen Array hergenommen, oder?

..sicher?, ich habs vorhin getestet und es hat nicht funktioniert, aber selbst wenn es funktioniert, ist es eigentlich falsch, richtig wäre _root.kurse0=[];

aber bei dem was du schreibst, da wird ja immer wieder ein neuer Array gebildet. Bei mir wird er nur auf 0 gesetzt

...ich setz mich dann jetzt mal ran und scripte Dir mal ein Beispiel...

danke dir, das ist sehr nett

markus

[Alois]

So fertig,
es hat doch noch etwas gedauert, erst hatte ich selbst noch was anderes zu tun, dann musste ich mich erstmal in die Funktionen der listbox-Komponente einlesen und dann hab ich es noch ordentlich auskommentiert.
Möglicherweise wolltest Du mit dem gedrückt-Array was ähnliches machen, wie das was ich jetzt mit dem kurs_index-array mache, da merkt sich flash nämlich 'was' innerhalb einer Listbox gewählt wurde.
Ausserdem habe ich einen Auswerten Button zum Testen eingefügt,...

...uff, Datei zu gross, dann eben das script:

//erstmal ein einfaches Array zun Ausprobieren
zahllist = 3;
_global.kurse = [];
for (var i = 0; i<5; i++) {
    _global.kurse[i] = [];
    for (j=0; j<zahllist; j++) {
        _global.kurse[i][j] = ["Ball "+i+j, "Hund "+i+j, "Apfel "+i+j];
    }
}
//ein Handler der den zur Zeit aktiven Zustand in ein speichert
MovieClip.prototype.LBhandler = function() {
    _global.kurs_index[btn][this._name.substr(2)] = this.getSelectedIndex();
};
//der Handler wird den Listboxen zugewiesen
for (i=0; i<zahllist; i++) {
    this["LB"+i].setChangeHandler("LBhandler", this["LB"+i]);
}
//das control-Object
control = new Object();
//die watch funktion wird aktiv, wenn die Variable control.neu sich ändert
control.watch('neu', function (id, alterWert, neuerWert) {
    // die Schaltflächen heissen mc0...mc1 usw
    // mit substr(2) wird alles vor der dritten Stelle abgeschnitten
    // ergo ist der Wert von btn dann 0...1 usw.
    btn = neuerWert._name.substr(2);
    // alterWert ist der wert von control.neu vor der Änderung
    alterWert.gotoAndStop(1);
    // neuerWert ist der wert von control.neu nach der Änderung
    neuerWert.gotoAndStop(2);
    for (var j = 0; j<zahllist; j++) {
        // die Werte werdem aus dem kurse-Array an die Listbox übergeben
        neuerWert._parent["LB"+j].setDataProvider(kurse[btn][j]);
        // wenn der noch kein kurs gewählt noch kein listbox-handler
        if (kurs_index[btn][j] != undefined) {
            // der bisher gewählte kurs wird gesetzt
            neuerWert._parent["LB"+j].setSelectedIndex(_global.kurs_index[btn][j]);
        }
    }
    // es gehört zum objekt watch syntax, den neuen Wert zuückzugeben
    return neuerWert;
});
//der kurs-index array
_global.kurs_index = [];
for (i=0; i<kurse.length; i++) {
    //die 'zweite Dimension' des kurs_index arrays
    _global.kurs_index[i] = [];
    if (i != 0) {
        //Schaltflächen werde dupliziert
        mc0.duplicateMovieClip("mc"+i, i, {_x:mc0._x+i*mc0._width});
    }
    //wenn die Schaltflächen verschiedene Namen haben sollen
    //dann ein textfeld in den mc einfügen und
    //this["mc"+i].textfeld.text=nameAusNamensArray[i];
    this["mc"+i].onRelease = function() {
        //das ist alles ....
        control.neu = this;
    };
}
//jetzt noch die erste Schaltfläche aktivieren
control.neu = this.mc0;
//Auswerten ginge z.B. so:
auswerten.onRelease = function() {
    for (var i = 0; i<kurse.length; i++) {
        trace("Button "+i);
        trace("--------------------");
        for (var j = 0; j<kurs_index[i].length; j++) {
            trace("LB"+j+"="+kurs_index[i][j]+"..."+kurse[i][j][kurs_index[i][j]]);
        }
        trace("");
    }
}; 

[markus78]

Danke!
Wow, ich bin total sprachlos!
Ich kanns nicht glauben. Danke nochmal.

Ich werd mir das jetzt mal ansehen, und werd es versuchen, dass es unterschiedliche einträge in der Listbox sind. Dann werd ich das mal in das ganze Projekt einbauen, und wenn es noch probleme gibt, dürfte ich mich nochmal an dich wenden?

besten dank
markus

[Alois]

Geschrieben von markus78
...
aber bei dem was du schreibst, da wird ja immer wieder ein neuer Array gebildet. Bei mir wird er nur auf 0 gesetzt
...

äh ja/nein/vielleicht...
mit kurse0=[]; sollte das bestehende array überschrieben werden und somit der übriggebliebeneSpeicherbereich den das array nutzte wieder freigegeben werden
mit kurse0.length=0; wird einfach der Wert der (offensichtlich doch als variable definierte) von length verkürzt, somit sollten die Werte die in den arrayelementen lagen ohne Bindung weiter im Systemspeicher rumschwirren, das dürfte, wenn Du es oft genug machst zum Systemabsturz führen..
...allerdings weiss ich nicht ob sich flash wirklich so verhält, um sicher zu gehen, daß der Speicher freigegeben wird müsste man es wohl so machen:
delete(kurse0);
kurse0=[];

Gruß

alois