webcambilder faden

[heschen]

HAI,

folgendes:

Die Bilder einer Webcam möchte ich in ein Flashmovie einbauen:

---------------schnipp----------------

_root.createEmptyMovieClip("con",1);

loading = function() {
loadMovie("http://server.de/cam/bild.jpg?nocache=" + Math.random(),_root.con);
}
loading();
setInterval(loading,20000);

---------------schnapp----------------

Das funktioniert auch tadellos.

Schön wäre jetzt, wenn ich einen Übergang zwischen 2 Fotos hinkriegen würde. Wenn ich einfach ein MC drüberlege und fade, scheitert es an der Synchronisation mit dem Foto. Liegt wohl an der Ladezeit.

Hat jemand eine Idee?

Danke.
gruss hes

Im OOP-Bereich gab es diesen Thread , der sich mit Bildübergängen befasste. Vielleicht ist ja etwas passendes dabei...

[heschen]

Jau.
OOP ist mein heimliches Steckenpferd *g*. Trotzdem danke.

Wenn ich das richtig sehe, dann müssten die *.jpg´s auf dem Server in *.swf´s konvertiert werden . Das ginge ja noch. Hier gab es übrigens auch mal einen Thread zu einem Converter.

Die Frage ist auch, wie ich den Cache ausschalten soll. Es geht ja immer nur um ein Bild.

Ich dachte da eher an einen etwas kürzeren Weg.

gruß hes

[HAY]

hi
hatte hier noch was.vieleicht hilfts.

alpha_wert = 0;
fade=5
con_nr=1
this.createEmptyMovieClip("con1", 2);
this.createEmptyMovieClip("con2", 1);
this.con2._alpha = this.con1._alpha=0;
function bildladen(){
            clearInterval(bild_id);
            _root["con"+con_nr].loadMovie("bild.jpg")
                    _root.onEnterFrame=function(){
                    //testen ob bild geladen ist
                    if(prozent==100){
                    //bild einblenden und nächsten interval setzen
                    blend_id = setInterval(einblenden, 30)
                    bild_id = setInterval(bildladen, 20000)
                    delete this.onEnterFrame
                    }
                    var bl = _root["con"+con_nr].getBytesLoaded() || 0;
            var bt = _root["con"+con_nr].getBytesTotal() || 1;
            prozent = Math.round(bl * 100 / bt);
                    }
}
function einblenden () {
    alpha_wert += fade;
    _root["con"+con_nr]._alpha = alpha_wert;
    if (alpha_wert>=100) {
        // interval beenden
        clearInterval(blend_id);
        // container numer wechseln
        con_nr = (con_nr == 2) ? 1 : 2;
        alpha_wert = 0;
        _root["con"+con_nr]._alpha = alpha_wert;
        // tiefe wechseln
        _root.con1.swapDepths(_root.con2);
    }
}
bildladen() 

äh mit cache must noch was machen.

[heschen]

HAI Hay,

das Script funktioniert nur teilweise.
Erstmalig fadet das Bild ein, nach 20 sek folgt der Bildwechsel ohne Fade, danach tut sich gar nichts mehr.
Eigentlich sollte der Wechsel zwischen den Container funktionieren.
Guckst Du noch mal drüber? Ich finde den Fehler nicht.
Danke.

Zur Info/No Cache:

---------------schnipp------------------

_root["con"+con_nr].loadMovie("http://server.de/cam/bild.jpg?nocache=" + Math.random())

---------------schnapp------------------



gruß hes

[HAY]

hi
hast du eine adresse mit bildern.

[heschen]

Hi,

ich habe mal die Webcam gestartet. Mangels beweglichen Motiv filme ich eine super Flashanimation ab.

www.hebatec-meineseite.de/cam/bild.jpg

Die Cam läuft jetzt erstmal die nächsten Tage.

Merci.
gruß hes

[HAY]

hi
war ein kleiner fehler drinn.
du must das online auf deinem server testen sonst funzt es nicht.

alpha_wert = 0;
fade=5
con_nr=1
this.createEmptyMovieClip("con1", 2);
this.createEmptyMovieClip("con2", 1);
this.con2._alpha = this.con1._alpha=0;
function bildladen(){
            clearInterval(bild_id);
            _root["con"+con_nr].loadMovie("cam/bild.jpg?nocache=" + Math.random())
                    _root.onEnterFrame=function(){
                    var bl = _root["con"+con_nr].getBytesLoaded() || 0;
            var bt = _root["con"+con_nr].getBytesTotal() || 1;
            prozent = Math.round(bl * 100 / bt);
                    //testen ob bild geladen ist
                    if(prozent==100){
                    //bild einblenden und nächsten interval setzen
                    blend_id = setInterval(einblenden, 30)
                    bild_id = setInterval(bildladen,15000)
                    delete this.onEnterFrame
                    }
              }
}
function einblenden () {
    alpha_wert += fade;
    _root["con"+con_nr]._alpha = alpha_wert;
    if (alpha_wert>=100) {
        // interval beenden
        clearInterval(blend_id);
        // container numer wechseln
        con_nr = (con_nr == 2) ? 1 : 2;
        alpha_wert = 0;
        _root["con"+con_nr]._alpha = alpha_wert;
        // tiefe wechseln
        _root.con1.swapDepths(_root.con2);
    }
}
bildladen() 

[heschen]

Hallo Harry,
funktioniert jetzt.

Da sage ich doch vielen Dank und wünsche noch einen schönen Tag.



gruß hes