warum funktioniert das nicht?

[mcmueh]

Hallo Zusammen!

Der unten angehängte Code soll einen mc "numofimages" mal duplizieren und dann den Bildern in den MCs eine onRelease-Funktion anhängen:

for(i=0; i < numofimages; i++) {
 
    duplicateMovieClip(holder.thumbnail_mc, "thumbnail" + i, i);
    holder["thumbnail"+i].image._x = i * 92 + 37; //37 entspricht dem Abstand vom Rand bis zur Maske
    holder["thumbnail"+i].image._y = 0;
    holder["thumbnail"+i].image.imgnr = i
 
    target = holder["thumbnail"+i].image; 
    trace(holder["thumbnail"+i]);
    
    target.onRelease = function () {
            _global.image = "/media/press/big/" + images_array[i] + ".jpg";
            big.gotoAndPlay(2);
            actualimg.text = int(i) + 1;
                        
            details.onRelease = function () {
                getURL("javascript:window.open('/components/press/more.php?img=" + images_array[i] + "','','width=620,height=620,left=20,top=20,scrollbars=yes'); void(0);");
            }
        }
        
        target._alpha = 80;
        
        target.onRollOver = function () {
            target._alpha = 100;
        }
        
        target.onRollOut = function () {
            target._alpha = 80;
        }   
    loadMovie("/media/press/small/" + images_array[i] + ".jpg",target);
} 

Ist da ein Überlegungsfehler drin, dass ein Klick auf das geladene Bild keine Aktion auslöst?

danke
mcmueh

target.onRelease = function

Das ist ein beliebter Fehler... Der einzelne Schleifenindex ist nach Ablauf der Schleife nicht mehr bekannt. target = holder["thumbnail"+i].image; könnte dann höchstens noch auf den letzten Wert von "i" zeigen.

Besser ist es, einen Festwert dem Objektpfad zuzufügen, bspw.:

PHP-Code:

holder["thumbnail"+i].image.imgnr = i

holder["thumbnail"+i].image.onRelease = function(){
   _global.image = "/media/press/big/" + images_array[this.imgnr] + ".jpg";
   //etc 


[/PHP]

[mcmueh]

Hallo agedoubleju

Danke schon mal für deine Hilfe. Leider funktioniert das ganze noch immer nicht. Der Code sieht jetzt so aus:

for(i=0; i < numofimages; i++) {
 
    duplicateMovieClip(holder.thumbnail_mc, "thumbnail" + i, i);
    holder["thumbnail"+i].image._x = i * 92 + 37; //37 entspricht dem Abstand vom Rand bis zur Maske
    holder["thumbnail"+i].image._y = 0;
    holder["thumbnail"+i].image.imgnr = i
 
    target = holder["thumbnail"+i].image; 
    trace(holder["thumbnail"+i]);
    
    holder["thumbnail"+i].image.onRelease = function () {
            _global.image = "/media/press/big/" + images_array[this.imgnr] + ".jpg";
            big.gotoAndPlay(2);
            actualimg.text = int(this.imgnr) + 1;
                        
            details.onRelease = function () {
                getURL("javascript:window.open('/components/press/more.php?img=" + images_array[this.imgnr] + "','','width=620,height=620,left=20,top=20,scrollbars=yes'); void(0);");
            }
        }
        
        holder["thumbnail"+i].image._alpha = 80;
        
        holder["thumbnail"+i].image.onRollOver = function () {
            target._alpha = 100;
        }
        
        holder["thumbnail"+i].image.onRollOut = function () {
            target._alpha = 80;
        }   
    loadMovie("/media/press/small/" + images_array[i] + ".jpg",target);
} 

Im Anhang habe ich mal die ganze Datei angehängt. Vielleicht hilft dir das...

danke
mcmueh

Setz dir zuerst mal ein paar trace-Befehle in der Schleife und lass dir damit die Variableninhalte im Testmodus ausgeben, z.B.

PHP-Code:

_global.image = "/media/press/big/" + images_array[this.imgnr] + ".jpg";
trace("_global.image="+_global.image); 


Vielleicht findet sich der Bug dann schon...

[Der Frager]

Hi!

Da dürfte doch aber gar nix funktionieren? Du löschst durch den loadMovie-Befehl alle Events, die du auf das Bild (den MC) gelegt hast. Hab da mal was geändert - aber nicht getestet. Aber "Preloader" oder "onRelease dynamisch geladene Bilder" sind bestimmt gute Suchbegriffe.

PHP-Code:

for (i=0; i<numofimages; i++) {
    duplicateMovieClip(holder.thumbnail_mc, "thumbnail"+i, i);
    holder["thumbnail"+i].image._x = i*92+37;
    holder["thumbnail"+i].image._y = 0;
    holder["thumbnail"+i].image.imgnr = i;
    //
    holder["thumbnail"+i].image.createEmptyMovieClip("bild",1);
    target = holder["thumbnail"+i].image.bild;
    //
    trace(holder["thumbnail"+i]);
    holder["thumbnail"+i].image.onRelease = function() {
        _global.image = "/media/press/big/"+images_array[this.imgnr]+".jpg";
        big.gotoAndPlay(2);
        actualimg.text = int(this.imgnr)+1;
        details.onRelease = function() {
            getURL("javascript:window.open('/components/press/more.php?img="+images_array[this.imgnr]+"','','width=620,height=620,left=20,top=20,scrollba  rs=yes'); void(0);");
        };
    };
    holder["thumbnail"+i].image._alpha = 80;
    holder["thumbnail"+i].image.onRollOver = function() {
        this._alpha = 100;
    };
    holder["thumbnail"+i].image.onRollOut = function() {
        this._alpha = 80;
    };
    loadMovie("/media/press/small/"+images_array[i]+".jpg", target);
} 


[mcmueh]

Danke vielmals an euch beide!

Das ganze funzt!

Bin schon fast am verzweifeln gewesen, da mein anderer Lösungsansatz einfach auf dem IE nicht funktionert hat (weiss jetzt noch nicht warum!?)
siehe (Win Exploarer macht da irgendwas anders... )

danke
mcmueh