vor'm mauszeiger zurückweichen?

[ibes]

'n abend allerseits...
jetzt hab ich also mal ein kleines problem: ich hab auf meiner page eine illustrierte blume (vekotrisiert). jetzt möcht ich den kopf, also die blüte so programmieren, dass, sobald man mit dem mauszeiger in deren nähe kommt diese etwas zurückweicht und dann wieder leicht zurückwippt. stellt euch 'ne träge, etwas ruckartige bewegung vor, wie eine blume, die von schwachem wind hin und her getragen wird.
sie darf aber nicht zu weit zurückweichen, da auf eben dieser blüte die gesamte navigation liegt...

zudem hat diese wunderschöne blume noch sowas wie 'n "bauch", dem ich einen zahmen "atmen-effekt" verpassen möchte. ich will dieser blume LEBEN einhauchen!

bin in sachen action-scripting 'n anfänger und hoffe nun doch schwer, irgendwer hier kann mir so schnell wie möglich helfen.
bittebittebitte

[andretti]

aloha!

"hitTest" habe ich eingebaut, um konflikte bei rollover der blume mit onpress mit den blüten zu vermeiden;

PHP-Code:

stop();
wertbelly = 0.1;
wertalles = 0.05;
MC_blume.MC_belly.onEnterFrame = function() {
    this._xscale = this._yscale += wertbelly;
    this._xscale>=105 ? wertbelly=-0.1 : 0;
    this._xscale<=95 ? wertbelly=0.1 : 0;
};
MC_alles.onEnterFrame = function() {
    this._rotation += wertalles;
    this._rotation>=5 ? wertalles=-0.1 : 0;
    this._rotation<=-5 ? wertalles=0.1 : 0;
};
this.onEnterFrame = function() {
    if (MC_alles.MC_blume.hitTest(_xmouse, _ymouse, false)) {
        MC_alles.MC_blume.onEnterFrame = function() {
            this._xscale>=90 ? this._xscale -= 0.2 : 0;
            this._yscale>=90 ? this._yscale -= 0.2 : 0;
        };
    } else {
        MC_alles.MC_blume.onEnterFrame = function() {
            this._xscale<=100 ? this._xscale += 0.2 : 0;
            this._yscale<=100 ? this._yscale += 0.2 : 0;
        };
    }
};
for (i=1; i<=8; i++) {
    _root.MC_alles.MC_blume["MC_"+i].onPress = function() {
        trace(this);
    };
} 


[ibes]

wauwau! dankedanke!
werd mich gleich mal dahintersetzen und des ding anpassen (versuchen)...
meld mich bestimmt noch(einige)mal(e)

supi, danke nochmals!

[ibes]

oke, also...
wie krieg ich jetzt noch hin, dass die blume vor der maus zurückwippt (ausweicht). sozusagen leicht "angeschubst" wird?

[michaelklaehn]

hi. ich hab zwar jetzt keine Zeit, dir den CODE zu schreiben, aber hier ein paar tipps.

verschiedene bewegungen würde ich grundsätzlich in verschiedenen
functionen lagern, wo du sie nach bedarf einsetzen kannst. also das
atmen der blume sollte ein anderes script sein als das zurückweichen.

erstens hast du dann einen besseren überblick und zweitens kannst
du das zurückweichen dann auf andere objekte übertragen, ohne daß
diese dann z.B. atmen usw.

das zurückweichen an sich habe ich noch nicht programmiert, obwohl
ich viel solche sachen mache. ich würde dir folgende herangehensweise
empfehlen:

erstens: der abstand zwischen maus und object muss berechnet werden.
es bietet sich an deine blume in zwei mcs zu haben. "blume_aussen" und darin "blume_innen" (blume_innen liegt in blume_aussen). der vorteil ist, das das koordinatensystem von blume_aussen sich nicht ändert und der abstand von maus zum mc immer unter den selben bedingungen berechnet wird. den abstand berechnest du mit hilfe des pythaguras (richtig geschrieben?) und zwar ausgehend vom nullpunkt von blume_aussen. diese werte überträgst du dann auf blume_innen, die ja im koordinatensystem von blume_aussen liegt.

beispiel (im onEnterFrame):
Xabstand=abstand von xmaus zu 0/0-blume_aussen
Yabstand=abstand von ymaus zu 0/0-blume_aussen
blume_innen._x=(-1/10)*Xabstand
blume_innen._y=(-1/10)*Yabstand

und benutze nicht _root._xmouse, sondern blume_aussen._xmouse

ich hoffe, ich hab dir ein paar anstöße gegeben.
falls nicht, fragen

micha

p.s. den pythaguras brauchst du um z.b. einschränkungen zu machen:
wenn(pythaguras<100){anfangen zu atmen}

[ibes]

he! schreib mal endlich den CoOoDE...!

ne, s**eiss...
deine ansätze entsprechen doch schon sehr meinen vorstellungen. ich wollt das atmen und das "wippen" eh trennen, sind zwei teilbereiche der blume, der bauch atmet, der kopf wippt.
das mit dem pythagoras (so schreibt man's ) klingt ja mal spannend, wird ja was werden. das muss ich zuerstmal in ruhe nachvollziehen.

...
supergeil! vielen dank, dass ihr euch die zeit nehmt... des nenn ich mal 'n forum.
werd dies alles jetzt erstmal verdauen (müssen). muss eh noch vorgängig meine blume vektorisieren...

ich komm dann wieder...

falls zwischenzeitlich jemand noch mehr denkanstösse und solche sachen hat, nur raus damit!

dankedankedankeundsoweiter

[Alphanimal]

Hab mal ein Script, also besser gesagt einen Ansatz für ein Script um die Bewegung zu steuern.

Hier wird zuerst ein Kreis-MC erstellt. Ich hab das nur eingefügt, damit der code leicht ausprobiert werden kann. Normalerweise muss der MC nicht übers script erstellt werden, sondern du nimmst deine Blume die schon auf der Bühne ist.

PHP-Code:

/*
    Scene initialisieren.... (normal wird der Vorhandene MC verwendet)
*/
        //Zeichnet einen Kreis
        MovieClip.prototype.drawCircle = function(x:Number, y:Number, r:Number){
            var TAN_PI8 = Math.tan(Math.PI/8);
            var SIN_PI4 = Math.sin(Math.PI/4);
            this.moveTo(x+r, y);
            this.curveTo(r+x, TAN_PI8*r+y, SIN_PI4*r+x, SIN_PI4*r+y);
            this.curveTo(TAN_PI8*r+x, r+y, x, r+y);
            this.curveTo(-TAN_PI8*r+x, r+y, -SIN_PI4*r+x, SIN_PI4*r+y);
            this.curveTo(-r+x, TAN_PI8*r+y, -r+x, y);
            this.curveTo(-r+x, -TAN_PI8*r+y, -SIN_PI4*r+x, -SIN_PI4*r+y);
            this.curveTo(-TAN_PI8*r+x, -r+y, x, -r+y);
            this.curveTo(TAN_PI8*r+x, -r+y, SIN_PI4*r+x, -SIN_PI4*r+y);
            this.curveTo(r+x, -TAN_PI8*r+y, r+x, y);
        }
        
        //Versuchsobjekt erstellen:
        mc = this.createEmptyMovieClip("mc", 1);
        
        mc.lineStyle(0, 0x000000); //blauen Kreis zeichnen
        mc.beginFill(0x8080E0,100);
        mc.drawCircle(0, 0, 10);
        mc.endFill();
        
        //Positionieren
        mc._x = Stage.width/2;
        mc._y = Stage.height/2;

/*
    Ab hier wirds interessant!
*/

//Init
x0 = mc._x;
y0 = mc._y;

wf = 20; //Exponentialfaktor
r = 50; //max. Radius

//Animation
this.onEnterFrame = function(){
    dx = x0 - this._xmouse; //Abstand zur Maus
    dy = y0 - this._ymouse;
    da = Math.sqrt(dx*dx+dy*dy); //Pythagoras ;)
    if(da!=0){
        //MC positionieren
        var w = Math.pow(2, -da/wf);
        mc._x = x0 + dx/da*r*w;
        mc._y = y0 + dy/da*r*w;
    }
} 


Über dx/da*r bzw. dy/da*r wird der abstand normalisiert. (der abstand ist immer r, aber der winkel ist der selbe wie der winkel von der maus...)
über ...*w wird die "Auslenkung" angepasst. diese verhält sich exponentiell (--> Math.pow) also über "r" passt du den maximalen Abstand an, über "wf" stellst du ein wie "häftig" oder apprupt die blume ausweicht. (je höher dieser wert desto weicher ist die bewegung...

Das script einfach in den ersten Frame einer blanken .fla kopieren und ausprobieren... und etwas damit rumspielen!
Ich werd auch noch ein bisschen was machen um das "dynamischer" aussehen zu lassen

[Alphanimal]

Etwas dynamik dazu:

PHP-Code:

//Init
x0 = mc._x;
y0 = mc._y;
mc.tx = mc._x;
mc.ty = mc._y;
mc.vx = mc.vy = 0;


wf = 20; //Exponentialfaktor
r = 30; //max. Radius
kf = 0.03; //Federstärke
af = 0.95; //Luftreigungs faktor
//Animation
this.onEnterFrame = function(){
    dx = mc.tx - this._xmouse; //Abstand zur Maus
    dy = mc.ty - this._ymouse;
    da = Math.sqrt(dx*dx+dy*dy); //Pythagoras ;)
    if(da!=0){
        //MC positionieren
        var w = Math.pow(2, -da/wf);
        mc.tx = x0 + dx/da*r*w;
        mc.ty = y0 + dy/da*r*w;
    }
    //Dynamik:
    mc.vx += (mc.tx - mc._x)*kf;
    mc.vy += (mc.ty - mc._y)*kf;
    mc.vx *= af;
    mc.vy *= af;
    mc._x += mc.vx;
    mc._y += mc.vy;
} 


[ibes]

...

[ibes]

*schluck*

[ibes]

ich seh schon...
mit eurer hilfe wird das was!

[nullidee]

@ibes: solltest vielleicht mal hier anhängen, was du schon hast, wird ja nicht jeder für dich was neu machen wollen, sondern auf deinem vorhandenen aufsetzen.

[ibes]

schon klar, schon klar... keine angst.
aber lass mir 'n bisschen zeit, ja? ich werd bestimmt meine resultate hier publizieren, wenn ich dann mal welche hab.

wie gesagt, ich muss mich erst hineinarbeiten und das dauert bei mir halt noch 'n stückchen...

...gut ding will weile haben...
...steter tropfen höhlt den stein...
...mit babyschrittchen zum erfolg...