vielleicht einwenig kompliziert :(

[knuddel_muddel]

Hallo Leute,


folgendes problem. Ich erzeuge mehrere MC`s und weise diesen einen eigenen Actionscript hinzu.

jetzt soll jedes einzelne MC "figurcontainer+i" zu seinem eigenem Target auf dem bildschirm fahren. (targetx+i und targety+i)

es gibt nur diesen einen actionscript auf der zeitleiste

for (var i=0; i<count; i++) {//count -> anzahl der figuren
        var mc = createEmptyMovieClip("figurcontainer"+i,i);// mc kriegt den erzeugten MovieClip / [i]-> nummer der figur
        mc.createEmptyMovieClip("kopf",3).loadMovie("kopf.swf");
        mc.createEmptyMovieClip("haende",4).loadMovie("haende.swf");
        mc.createEmptyMovieClip("koerper",1).loadMovie("koerper.swf");
        mc.createEmptyMovieClip("unter",2).loadMovie("unter.swf");
        
        mc._x = 30*i;//figurcontainer positionierung
        mc._y = 30*i;//figurcontainer positionierung
        
        mc.kopf._x = 0;//kopf_x positionierung
        mc.kopf._y = 0;//kopf_y positionierung
        mc.koerper._x = 20;//koerper_x positionierung
        mc.koerper._y = 60;//koerper_y positionierung
        mc.haende._x = -30;//haende_x positionierung
        mc.haende._y = 75;//haende_y positionierung
        mc.unter._x = -42;//unter_x positionierung
        mc.unter._y = 120;//unter_y positionierung
        
        setProperty("mc", _xscale, 40);//skallierung der figur
        setProperty("mc", _yscale, 40);//skallierung der figur
        
    
    _root["targetx"+i] = eval("x"+i);
    _root["targety"+i] = eval("y"+i);
    delay = 10; //geschwindigkeit der figuren bestimmen
    
mc.onEnterFrame=function(){//erzeuge onEnterFrame function auf mc
    difx = _root["targetx"+i] - this._x;
    dify = _root["targety"+i] - this._y;
    this._x += difx / delay;
    this._y += dify / delay;
}
mc.onMouseDown=function(){//erzeuge onMouseDown function auf mc
    _root["targetx"+i] = _root._xmouse;
    _root["targety"+i] = _root._ymouse;
}
    
}//end of for schleife - für die dynamische erzeugung der figuren
 
stop(); 

---->
_root["targetx"+i] = eval("x"+i);
_root["targety"+i] = eval("y"+i);

dazu muss ich noch sagen dass x1, x2, x3 variablen aus der datenbank eingelesen werden und unterschiedliche werte haben

Das problem ist jetzt dass jedes einzelne erzeugte MC muss in seinem eigenem Actionscript einen eigenen target besitzen damit die figruen unabhänig von einnander auf dem bildschirm gesteuert werden können.

ich weiß dass es kompliziert zu verstehen ist, wenn ihr fragen habt, stellt sie.

[Alois]

ah ja kurz überlegt...ja da hast Du einen Denkfehler:

...
 _root["targetx"+i] = eval("x"+i);
        _root["targety"+i] = eval("y"+i);
        delay = 10; //geschwindigkeit der figuren bestimmen
        
        mc.onEnterFrame=function(){//erzeuge onEnterFrame function auf mc
                difx = _root["targetx"+i] - this._x;
                dify = _root["targety"+i] - this._y;
                this._x += difx / delay;
                this._y += dify / delay;
        }
        mc.onMouseDown=function(){//erzeuge onMouseDown function auf mc
                _root["targetx"+i] = _root._xmouse;
                _root["targety"+i] = _root._ymouse;
        }... 

...bei den ClipEvents kannst Du natürlich nicht so mit i arbeiten, mach es folgendermassen:

mc.targetx= eval("x"+i);
        mc.targety = eval("y"+i);
        delay = 10; //geschwindigkeit der figuren bestimmen
        
        mc.onEnterFrame=function(){//erzeuge onEnterFrame function auf mc
                difx = this.targetx - this._x;
                dify = this.targety - this._y;
                this._x += difx / delay;
                this._y += dify / delay;
        }
        mc.onMouseDown=function(){//erzeuge onMouseDown function auf mc
                this.targetx = _root._xmouse;
                this.targety= _root._ymouse;
        } 

...wobei ich nicht verstehe, warum Du Du die Datenbankwerte nicht in ein array packst und mit mc.targetx=x[i]; übergibtst..

...und das setProperty ist unnötig mc._xscale=40; geht auch...

Gruß

Alois

[knuddel_muddel]

Boh danke @Alois mal wieder hast du mir geholfen! Ich glaub ich muß dir bald einen ausgeben.

dass mit setProperty hab ich einfach aus einem anderem script übernommen da ich nicht so ein flashxperte bin