url für dynamische Buttons aus xml verknüpfen...?

[beenline]

Hallo,
ich hab ein wahrscheinlich sehr leicht zu lösendes problem:

Ich habe vor eine dynamische linkliste zu erstellen, die mit einer xml datei gefüttert wird. Jeder Link besteht aus drei dynamischen textfeldern, und einen unsichtbaren MC der als Button über die texte gelegt wird.
die variable link_[i] beinhaltet die url auf die gelinkt werden soll.
ich hab jetzt schwierigkeiten diese variable in eine onPress Funktion einzubauen.

Vielleicht schaut sich das mal jemand an.....

ich hab ne leichte Ladehemmung..
hier der Code:

PHP-Code:

var XMLdaten = new XML(); 
XMLdaten.ignoreWhite=true; 
XMLdaten.load("data/links.xml?reload="+rn); 
XMLdaten.onLoad = function(success) { 
    if(success){
        var anzahl = XMLdaten.firstChild.childNodes.length; //liest die anzahl der elemente aus!
          
        _global.scrollcount = anzahl*60-400;
        if(anzahl < 5){_global.scrollcount = -240};
        
        var link_name = []; //neues array 
        var link_text = [];
        var link_ = [];
        
        //
        for (var i=0; i<anzahl; i++) { 
            link_name[i] = XMLdaten.firstChild.childNodes[i].attributes.linkname;//auslesen 
            loader.createTextField("txt_linkname"+i, i, 0, (1+(i*60)), 0, 0); 
            loader["txt_linkname"+i].setNewTextFormat(headline);
            loader["txt_linkname"+i].embedFonts = true;
            loader["txt_linkname"+i].autoSize = true; 
            loader["txt_linkname"+i].selectable = false;
            loader["txt_linkname"+i].text = link_name[i];

           //
           link_text[i] = XMLdaten.firstChild.childNodes[i].attributes.linktext;//auslesen 
           loader.createTextField("txt_linktext"+i,(i+500), 0, (32+(i*60)), 0, 0); 
           loader["txt_linktext"+i].setNewTextFormat(fliesstext);
           loader["txt_linktext"+i].embedFonts = true;
           loader["txt_linktext"+i].autoSize = true; 
           loader["txt_linktext"+i].selectable = false;
           loader["txt_linktext"+i].text = link_text[i];
           //
           link_[i] = XMLdaten.firstChild.childNodes[i].attributes.link;//auslesen 
            loader.createTextField("txt_link"+i,(i+550), 0, (46+(i*60)), 0, 0); 
            loader["txt_link"+i].setNewTextFormat(fliesstext);
            loader["txt_link"+i].embedFonts = true;
            loader["txt_link"+i].autoSize = true; 
            loader["txt_link"+i].selectable = true;
            loader["txt_link"+i].text = link_[i];
            
            linkbutton[i] = loader.attachMovie("linkbutton", "link_mc"+i, (i+400), { _y: i*60});
            loader["link_mc"+i].onPress = function(){getURL(link_[i], "_blank");};
           //
             
        
        }
    }
} 


auf dem Textfeld loader["txt_link"+i].text = link_[i]; wird die URL korrekt ausgegeben, aber ich krieg sie nicht in die onPress funktion.

DANKE VORRAB

[Der Frager]

Hallo!

Geht z.B. so:

PHP-Code:

loader["link_mc"+i].link = link_[i]
loader["link_mc"+i].onPress = function(){getURL(this.link, "_blank");}; 


[beenline]

klappt bestens!

dangeschön!