unloadMovie() - und nichts geht mehr

[Vampire's Party]

Hallo,

ich habe einen MovieClip aus der Bibliothek auf die Bühne gezogen und mit einem Instanznamen versehen. In einer Klasse soll der Inhalt des MCs (Vektorgrafiken) entfernt und dann neu gezeichnet werden (dynamisch).

Soweit, so gut. Ohne unloadMovie habe ich den Inhalt des MCs und die dynamische Zeichnung. Will ich allerdings den Inhalt vorher entfernen (mit unloadMovie)... dann gibts nichts mehr. Der MC ist zwar vorhanden, allerdings völlig leer, obwohl ja eigentlich etwas gezeichnet wurde...

Wisst ihr, woran das liegen könnte?

Hier mal das Script:

PHP-Code:

    // +++++++++++
    // Konstruktor
    // +++++++++++
    function cmButton (__target:String, __text:String, __this, __data:Object)
    {
        _text         = __text;
        buttonName     = __target;
        for (var i in __data) _data[i] = __data[i];
        
        _data.this_button     = __this;
        _data.this_button[buttonName].unloadMovie();
        
        drawButton();

    }
    
    function drawButton ()
    {
        with (_data.this_button[buttonName])
        {
            w = 50;
            h = 50;
            
            lineStyle (1, 0x000000, 100, true, "none", "round", "round", 1);
            beginFill (0xCCCCCC);
            moveTo (0, 0);
            lineTo (w, 0);
            lineTo (w, h);
            lineTo (0, h);
            lineTo (0, 0);
            endFill ();
        }
    } 


[ingohill]

hi.

hast du es schon einmal mit

PHP-Code:

MovieClip.clear(); 


versucht?

-ingo

[Vampire's Party]

Danke für den Tipp - habs gerade mal versucht, hat aber leider nichts gebracht

[Der Frager]

Hmmm... Kannste mal eine kleine Beispieldatei anhängen? Nur mit den Funktionen erschließt sich mir das alles nicht so ganz...

[Vampire's Party]

Ok, hier ist Sie...

[Der Frager]

Flash8? Kann ich leider nicht öffnen. Geht der Krams nicht auch schon in MX 2004? Falls ja, bitte nochmal runterkonvertieren.

[the binary]

was n das fürn file-format / flash.version ?

[Vampire's Party]

Und nochmal für MX2004

[Der Frager]

Verstehe nicht ganz, was da passieren soll. Der zeichnet ein graues Quadrat unter den blauen Button. Ja, gut... Und was soll da jetzt das unloadMovie() genau machen bzw. was soll diese ganze Funktion machen?

[Vampire's Party]

Das blaue Feld soll entfernt werden, bevor das graue Feld gemalt wird. Soll eine Art KOmponente werden - ich möchte aber bewusst keine machen und es auf diesem Weg realisieren.

[Der Frager]

Aha! Könnte man vielleicht so machen. Momentan istr die Tiefe halt immer 1, aber das kann man ja noch ändern...

PHP-Code:

class cmButton {
    var buttonName:String;
    var _caption:String;
    var _data:Object = {disabled:false, b_height:50, b_width:50, b_x:0, b_y:0, this_button:false};
    // +++++++++++
    // Konstruktor
    // +++++++++++
    function cmButton(__target:String, __caption:String, __this, __data:Object) {
        _caption = __caption;
        buttonName = __target;
        for (var i in __data) {
            _data[i] = __data[i];
        }
        _data.this_button = __this;
        _data.b_x = __this[buttonName]._x;
        _data.b_y = __this[buttonName]._y;
        _data.b_width = __this[buttonName]._width;
        _data.b_height = __this[buttonName]._height;
    _data.this_button[buttonName].swapDepths(1);
        _data.this_button[buttonName].removeMovieClip();
        drawButton();
        _data.this_button[buttonName].createTextField("caption", 3, 0, 0, 0, 0);
        _data.this_button[buttonName]["caption"].autoSize = true;
        _data.this_button[buttonName]["caption"].text = _caption;
        _data.this_button[buttonName]["caption"]._x = (_data.b_width-_data.this_button[buttonName]["caption"]._width)/2;
        _data.this_button[buttonName]["caption"]._y = (_data.b_height-_data.this_button[buttonName]["caption"]._height)/2;
        _data.this_button[buttonName].onRollOver = mx.utils.Delegate.create(this, _rollOver);
        _data.this_button[buttonName].onRollOut = mx.utils.Delegate.create(this, _rollOut);
    }
    function _rollOver() {
        _data.this_button[buttonName]["caption"].html = true;
        _data.this_button[buttonName]["caption"].htmlText = "<b>"+_caption+"</b>";
    }
    function _rollOut() {
        _data.this_button[buttonName]["caption"].html = false;
        _data.this_button[buttonName]["caption"].text = _caption;
    }
    function get disabled() {
        return _data.disabled;
    }
    function set disabled(__disable:Boolean) {
        _data.disabled = __disable;
    }
    function drawButton() {
        var mc = _data.this_button.createEmptyMovieClip(buttonName, 1);
        with (mc) {
            w = 50;
            h = 50;
            lineStyle(1, 0x000000, 100, true, "none", "round", "round", 1);
            beginFill(0xCCCCCC);
            moveTo(0, 0);
            lineTo(w, 0);
            lineTo(w, h);
            lineTo(0, h);
            lineTo(0, 0);
            endFill();
        }
    }
} 


[Vampire's Party]

Danke, so funktioniert es - ist zwar zugegeben nicht die schönste Lösung, aber es reicht aus.

Danke nochmals und guten Rutsch

[Der Frager]

Zitat von Vampire's Party

...ist zwar zugegeben nicht die schönste Lösung...

...von "schön" war nie die Rede

edit: eigentlich kann man sich das Removen auch schenken, wenn man den neuen MC auf der gleichen Tiefe erstellt.