überschriebene mc.onPress methode

[neo-labz]

hallo allerseits,

gibt es eine möglichkeit die onPress Methode eines mc so zu überschreiben, daß ich in dieser methode selber angebe, wann (bei welchen coordinaten im mc) sich der cursor bei mouseover zu einer hand formen soll und wann nicht?

bsp:

myclass = function(){}
 
var mC = myclass.prototype = new MovieClip();
Object.registerClass("mc",myclass);
 
mC.onPress = function(){
    trace("mouse pressed");
}
 
_root.attachMovie("mc","mcI",0);
stop(); 

bis jetzt sieht es so aus, daß sich sobald sich die maus über den movieclip "mcI" bewegt, der cursor sich in eine hand verformt...

ich hätte aber gerne, daß sich der cursor nur bei mouseover eines bestimmten teils des movieclips "mcI" in eine hand verformt...
...ohne in diesem mc einen neuen mc anzulegen!

kann man also beeinflussen, wann bei der methode mc.onPress die hand angezeigt wird, und wann der normale cursor???


danke,

__benjamin

[HAY]

hi
mit useHandCursor

[neo-labz]

huch, ja stimmt...
*api durchlesen hätte wohl auch geholfen*

danke!


ich hätte vielleicht an eine etwas nativere beeinflussung dieses "useHandCursor" gedacht.

mit dieser function, muss ich ständig die koordinaten der _xmouse und _ymouse ausrechnen, in lokale werte umwandeln und dann entsprechend "usehandcursor" auf true oder false setzen................

[Janoscharlipp]

vielleicht mit hitArea? Aber das kommt dem Unter-MC nahe

[neo-labz]

ja, aber hitArea ist auch wieder so eine highlevel api funktion, die an der performance zieht.

vielleicht denkt ihr euch, was das soll, aber für das spiel welches ich entwickel muss ich so ressourcenschonend wie möglich programmieren, und das fängt bei solchen "kleinigkeiten" an....

[HAY]

geschrieben von neo-labz

ich hätte aber gerne, daß sich der cursor nur bei mouseover eines bestimmten teils des movieclips "mcI" in eine hand verformt...

wenn du das so willst dann must du diesen teil halt prüfen.
wie soll flash wissen was du testen willst.

[neo-labz]

klar

da war ich dann doch schon drauf gekommen...

myclass = function(){}
 
var mC = myclass.prototype = new MovieClip();
Object.registerClass("mc",myclass);
 
mC.onPress = function(){
      trace(_xmouse+"    "+_ymouse);  
};
mC.onEnterFrame = function(){
        
        point = new object();
        point.x = _root._xmouse;
        point.y = _root._ymouse;
        this.globalToLocal(point);
 
        if( (point.x > (this._width/2)) && (point.y > (this._height/2)) ){
            this.useHandCursor = true;  
        }else{
            this.useHandCursor = false;
        }
};
 
_root.attachMovie("mc","mcI",0);
mcI._x = 300;
mcI._y = 230;
stop(); 

jetzt wird nur im unteren rechten viertel des mcs (quadratischer natur) die hand angezeigt........

problem ist halt, daß jetzt bei jedem onenterframe gecheckt werden muss und das der performance nicht sonderlich zuträglich ist.

ich hätte da an eine einmalige änderung gedacht, die nicht immer wieder überprüft werden muss....

[HAY]

hi
vieleicht wäre ein onMouseMove besser und so wenig wie möglich variablen anlegen.(performence)

myclass = function(){}
var mC = myclass.prototype = new MovieClip();
Object.registerClass("mc",myclass);
 
mC.onPress = function(){
        trace(this._xmouse+"    "+this._ymouse);
};
mC.onMouseMove = function(){
        if( ( this._xmouse > (this._width/2)) && (this._ymouse > (this._height/2)) ){
                this.useHandCursor = true;
        }else{
                this.useHandCursor = false;
        }
};
_root.attachMovie("mc","mcI",0);
mcI._x = 100;
mcI._y = 100;
stop(); 

[neo-labz]

yeah, danke....

das kommt meiner vorstellung schon näher...

wusste garnicht, daß aus einem mc heraus this._xmouse die x coord im mc anzeigt. interessant

[HAY]

hi
du könntest noch das der onMouseMove erst ausgelöst wird
bei einem onRollOver den gleich wieder löschen und bei einem onRollOut wieder den onRollOver einschalten.
must halt testen was besser ist.

[neo-labz]

wie schalt ich denn den on mousemove bei rollover an bzw. aus?

_kleine gedankenanstöße bewirken wunder ;)

[HAY]

hi
bin mir nicht sicher ob das was bringt.

mC.onRollOver = function() {
        this.onMouseMove = function(){
            if( ( this._xmouse > (this._width/2)) && (this._ymouse > (this._height/2)) ){
                this.useHandCursor = true;
            }else{
                this.useHandCursor = false;
            }
            }
            this.onRollOut=function() {
            delete this.onMouseMove
            delete this.onRollOut
            }
} 

[edit]bischen geändert

[neo-labz]

ja hervorragend,

vielen dank nocheinmal!