[TUTORIAL] MP3-Player mit XML-Fütterungszeit ;-)

[pape]

Hallo!

MP3-Player mit XML-Fütterungszeit


Inhalt

0. Einleitung
1. First Steps
2. Die XML-file
3. XML-Datei in Flash einlesen
4. Die Playerfunktion
5. Der Preloader
6. Der erste Test
7. Die automatische Wiedergabeliste
8. Die Buttons
9. Das fertige ActionScript
10. Ausleitung

0. Einleitung:

Da wieder mal die Frage aufkam, wie man in Flash einen Mp3Player baut und ihn mit XML-daten füttert und mein XML-Tutorial + weitere Threadangaben nicht so richtig halfen, dachte ich es wäre vielleicht sinnvoll, das ganze mal zusammen zu tragen.

Es mag sein, dass Ähnliches schon da gewesen ist, aber eine Anleitung, wie man genau dieses Problem behandelt habe ich nicht gefunden!

Ich habe das Problemchen noch etwas erweitert und einen Preloader eingebaut.
Im nächsten Schritt (Part II... den es wahscheinlich eh nie geben wird...^^....mal schaun) könnte man ein Lauftext für die Anzeige, eine Liste mit vorhandenen Dateien, Regler für die Lautstärke usw.. einbinden!

Lasst euch nicht abschrecken von der Länge des Tutorials!
es wird zwar lang, aber dasheißt nur Arbeit für mich!
Ihr könnt es (hoffentlich) sehr schnell lesen, da ich versucht habe es möglichst genau und dennoch leicht verständlich zu erklären!
Ob das geklappt hat könnt ihr mir sehr gerne mitteilen, damit ich für die Zukunft bescheid weiß! Danke!


Also viel Spaß & Erfolg!!!

(ich werde unten nicht mehr jeden kleinen Schritt bezüglich der XML einlesung genaustens erklären! vorwissen wäre hier gut.. es reicht mein Tutoriasls über das Laden und verarbeiten von XML datein in Flash zu lesen.
Dieses kann dort: [TUTORIAL] laden und verarbeiten von XML Dateien (basics)
gefunden werden!)


1. First Steps:

Als erstes benötigen wir einen neuen Flashfilm!
Datei>neu

Nun wollen wir uns zunächst kurz um die graphische Oberfläche kümmern, um uns dann an die Scripts zu geben!

wir benötigen 4 Buttons:

1. "btn_play"
2. "btn_stop"
3. "btn_prev"
4. "btn_next"

play spielt eine Soundfile ab, wenn schon eine am spielen ist, soll sie von vorne beginnen.
stop stoppt die wiedergabe.
prev soll die vorangehende Datei abspielen und next dementsprechend die folgende Datei!

für den Play Button habe ich einen simplen dreieckspfeil gemalt, für stop ein viereck und für prev bzw. next doppelpfeile.

dann benötigen wir noch ein dynamisches Textfeld, in welchem wir später den Songtitel anzeigen lassen!
Wir nennen es "anz"

Nun erstellen wir eine neue Ebene, nennen sie "AS" und schreiben folgendes:

stop(); 

um den film direkt hier auf frame 1 anzuhalten.



2. Die XML-file:

Als nächstes brauchen wir erst einmal eine XML datei und ein Script, welches uns die Dateien einliest!

Also öffnet den edtior oder ein anderes Textprogramm und schreibt dort das als Grundstruktur rein:

<?xml version='1.0' encoding='utf-8'?>
<songs>
  <song />
</songs>

songs ist der erste ChildNode und song ist dann einer unserer später einzuladenen Songs!
..so wie es jetzt da steht genügt das natürlich nicht, da wir verscheidene Informationen über den Song benötigen:
Wir brauchen den später anzuzeigenden Namen und die dazugehörige datei.
Also geben wir jedem unserer Songs 2 attribute, sodass die XML datei z.b. so aussieht:

<?xml version='1.0' encoding='utf-8'?>
<songs>
  <song name="Lied1" file="songs/lied1.mp3" />
  <song name="Lied2" file="songs/lied2.mp3" />
</songs>

Erweitert die datei um ein paar songs und speichert sie im selben Verzeichnis wo auch die fla liegt unter "songlist.xml" ab.



3. XML-Datei in Flash einlesen:

Nun wenden wir uns dem Script in FLash wieder zu.

wir benötigen ein XML Objekt:

songliste = new XML(); 

dort müssen wir angeben, dass wir die Spaces und Breaks ignorieren wollen;

songliste.ignoreWhite=true; 

Wir wollen 2 Arrays (global, um von überall auf sie zugreifen zu können ohne die pfadsorgen!) erstellen, in denen wir unsere Daten aus der XML file speichern.
Diese erstellen wir direkt in der onLoad funktion des XML objektes und füllen sie direkt(für weitere Erklärungen s. Tutorial einladen und verarbeiten von XML-dateien):

songliste.onLoad = function (success) {
    _global.songnamen = [];
    _global.songfiles = [];
    if(success) {
        for (var i=0; i<songliste.firstChild.childNodes.length; i++) {
            _global.songnamen[i] = songliste.firstChild.childNodes[i].attributes.name;
            _global.songfiles[i] = songliste.firstChild.childNodes[i].attributes.file;
        }
    } else {anz.text="Fehler beim Laden der XML datei"}
} 

danach laden wir die Datei:

songliste.load("songlist.xml"); 

so, um nun zu überprüfen, ob die Daten wirklich übergeben wurde, könnt ihr nun den Film starten!
wenn keine Fehleranzeige in dem textfeld zusehen ist, dann hats geklappt... wirklich?..
... naja.. zumindest sind keine Fehler aufgetreten beim laden, ob die daten jedoch wirklich reingeladen wurden und in den arrays gespeichert wurden, könnt ihr einfach mit einem Trace in der for schleife probieren, sodass der gesamte code bis hier in Flash so aussieht:

stop();//film anhalten
songliste = new XML();//neues XML Objekt
songliste.ignoreWhite=true;//Leerzeichen ignorieren
songliste.onLoad = function (success) {//onLoad function (wird ausgeführt, wenn die daten geladen werden)
    if(success) {//wenn das laden erfolgreich war
        //arrays erstellen
        _global.songnamen = [];
        _global.songfiles = [];
        for (var i=0; i<songliste.firstChild.childNodes.length; i++) {//für alle Elemente in der XMLfile
            //Die attribute auslesen und in die Arrays packen
            _global.songnamen[i] = songliste.firstChild.childNodes[i].attributes.name;
            _global.songfiles[i] = songliste.firstChild.childNodes[i].attributes.file;
            trace(songnamen[i]+"  "+songfiles[i]);//überprüfen, ob wirklich die Daten richtig übergeben wurden
            //Die Ausgabe sollte z.b. so aussehen:
            //Lied1  songs/lied1.mp3
            //Lied2  songs/lied2.mp3
        }
    } else {anz.text="Fehler beim Laden der XML datei"}//falls ein Fehler auftritt beim Laden
}
songliste.load("songlist.xml");//Liste laden 
 

[pape]

4. Die Playerfunktion:

Da wir nun unsere Daten in Flash haben, können wir unsere Functions bezüglich des Mp3 Player "bauen".

Zunächst einmal erstellen wir einen MovieClip, in dem wir unseren Sound legen werden:
(das script kommt direkt hinter die for schleife.. ersetzt quasi jetzt das tarcen der Arrays)

_root.createEmptyMovieClip("sound_mc",1); 

Es sei gesagt, dass es nicht zwangsläufig notwendig ist den Sound nochmal in einen extra Mc zu packen, aber ich mache das mal aus strukturellen Übersichtlichkeits-gründen. Zudem wird es uns später für den Preloader dienen.

Nun benötigen wir ein Sound Objekt, welches wir dem MovieClip unterordnen:

_root.sound_mc.sound_obj = new Sound(); 

jetzt schreiben wir die function, die uns in unser Soundobjekt Die gewollte Datei lädt:
Wir wollen der function 2 Parameter mitgeben:
1. die zuladene File
2. den Titel des Songs

in ActionScript umgesetzt:

function (file, name) {
  //...
} 

was muss diese function nun genau machen?
zunächst lädt sie in unser Spundobjekt die datei;
diese soll gestreamt werden:

sound_obj.loadSound(file,true)//true steht hier für streaming=an 
 

das war es eigentlich schon. der erste Song wird abgespielt, sobald wir die function mit den entsprechenden Parametern aus dem Array aufrufen!



5. Der Preloader:

Wir wollen aber noch weiter gehen und einen Preloader für den sound bauen und natürlich eine automatische Abarbeitung unserer XML liste.
Zudem soll auch noch der Name der datei angezeigt werden...

Der Preloader ist kein wirklicher Preloader...wir streamen die Datei ja schließlich.
Das heißt, dass ein gewisser Teil in den Buffer geladen wird und dann wärend der Rest der Datei geladen wird, die Wiedergabe schon startet!
Wieviel vorgeladen wird steht in der _soundbufftime.
Diese ist standardgemäß auf 5 sekunden eingestellt und kann verändert werden (s. Flash-Referenzen).
Wir belassen es einfach bei 5 sec.

Wie nun aber können wir abfragen wann diese Bufftime geladen wurde?
mit getBytesLoaded() und getBytesTotal(); können wir hier nichts wirklich anfangen...

Nein, das ist viel einfacher als man denken mag:
Jedes Soundobjekt besitzt die Eigenschaft "position".
Sie gibt die aktuelle Abspielposition des Soundobjektes in Millisec. an.
Wenn diese also größer als 0 ist, hat der Sound angefangen abzuspeieln!

if(sound_obj.position>0) { ...} 

Diese Abfrage müssen wir natürlich ähnlich wie bei einem "normalen" Preloader mehrmals ausführen.. und zwar solange, bis der Sound angefangen hat zu spieln!

Was eignet sich da besser als ein onEnterFrame Ereignis..

SOOO... an dieser Stelle müssen wir etwas ändern! (wir müssen nicht, aber es wird hilfreich!)
Wir erinnern uns, dass wir unser Soundobjekt in einen extra Mc gelegt haben... genau... der dient jetzt für das onEnterFrame Ereignis!

Um das ganze noch einfacher zu gestalten und nicht noch einen weiteren Parameter "sound_mc" für die function zu benötigen machen wir aus unserer function einen prototypen!

Nach der Umwandlung sähe unsere derzeitige "function" so aus:
(das sound objekt liegt in diesem mc, daher von nun an this.sound_obj, da "this" sich auf den Mc bezieht)

MovieClip.prototype.song_starten = function (file, name) {
    this.sound_obj.loadSound(file,true)//true steht hier für streaming=an
    //...
    if(this.sound_obj.position>0) { ...}
    //...
} 

Nun können wir wie gesagt innerhalb des Prototypens mit "this" unseren Movieclip ansprechen und ihm so mit this.onEnterFrame = function () {...} ein onEnterFrame Ereignis zuweisen, in welchem wir abfragen ob der Sound schon gestartet ist!
Sollte das der Fall sein, so können wir das onEnterFrame mit delete this.onEnterFrame wieder löschen.
Das alles sieht dann bis jetzt so aus:

MovieClip.prototype.song_starten = function (file, name) {
    this.sound_obj.loadSound(file,true)//true steht hier für streaming=an
    this.onEnterFrame = function () {//das onEnterFrame Ereignis 
        if(this.sound_obj.position>0) {
            delete this.onEnterFrame; // das onEnterFrame Ereignis löschen
            trace("Der Song ist gestartet");
        }
    }
} 

während die Datei noch geladen wird, könnten wir in unser Textfeld ein "loading..." schreiben.
Also ergänzen wir die if-Abfrage im onEnterFrame mit einem else part:

if(this.sound_obj.position>0) {
    delete this.onEnterFrame; // das onEnterFrame Ereignis löschen
    trace("Der Song ist gestartet");
} else {
    this._parent.anz.text="loading..." //this._parent heißt soviel wie: dieser_mc_hier.die_übergeordnete_instanz dort liegt nämlich das textfeld.
} 

wenn der Song nun gestartet ist können wir in das Textfeld den Songnamen schreiben.
Das machen wir in dem wir unser trace("Der Song ist gestartet"); durch das ersetzen:

this._parent.anz.text=name; //name wurde als parameter übergeben 
 

6. Der erste Test:

Wenn ihr bis hierhin gekommen seid, habt ihr es verdient das ganze nun mal zu testen ob man überhaupt etwas hört!
Sorgt dafür, dass die Pfad angaben in der XML-Datei wirklich stimmen!
(oben im beispiel müsste ein Ordner namens "songs" existieren in dem die dateien "lied1.mp3" und "lied2.mp3" liegen.
Der Ordner müsste im selben Verzeichniss wie die xml und die fla sein!)

Aufgerufen wird der Prototype nun zum testen einfach mit dem ersten Song und zwar in der onLoad function (nachdem die Arrays in der for-Schleife gefüllt wurden, der sound_mc erstellt wurde und das sound Objekt erstellt wurde).
Die nötigen Parameter stehen in unseren Arrays, sodass der Aufruf so aussieht:

_root.sound_mc.song_starten(songfiles[0],songnamen[0]); 

und das komplette bisherige Script so:

songliste = new XML();//neues XML Objekt
songliste.ignoreWhite=true;//Leerzeichen ignorieren
songliste.onLoad = function (success) {//onLoad function (wird ausgeführt, wenn die daten geladen werden)
    if(success) {//wenn das laden erfolgreich war
        //arrays erstellen
        _global.songnamen = [];
        _global.songfiles = [];
        for (var i=0; i<songliste.firstChild.childNodes.length; i++) {//für alle Elemente in der XMLfile
            //Die attribute auslesen und in die Arrays packen
            _global.songnamen[i] = songliste.firstChild.childNodes[i].attributes.name;
            _global.songfiles[i] = songliste.firstChild.childNodes[i].attributes.file;
            trace(songnamen[i]+"  "+songfiles[i]);//überprüfen, ob wirklich die Daten richtig übergeben wurden
            //Die Ausgabe sollte so aussehen:
            //Lied1  songs/lied1.mp3
            //Lied2  songs/lied2.mp3
        }
        _root.createEmptyMovieClip("sound_mc",1);//sound_mc erstellen
        _root.sound_mc.sound_obj = new Sound();//Sound objekt erstellen
        _root.sound_mc.song_starten(songfiles[0],songnamen[0]);//sound laden und starten
    } else {anz.text="Fehler beim Laden der XML datei"}//falls ein Fehler auftritt beim Laden
}
 
MovieClip.prototype.song_starten = function (file, name) {
    this.sound_obj.loadSound(file,true)//true steht hier für streaming=an
    this.onEnterFrame = function () {//das onEnterFrame Ereignis 
        if(this.sound_obj.position>0) {
            delete this.onEnterFrame; // das onEnterFrame Ereignis löschen
            this._parent.anz.text=name; //name wurde als parameter it übergeben
        } else {
            this._parent.anz.text="loading..." //this._parent heißt soviel wie: dieser_mc_hier.die_übergeordnete_instanz dort liegt nämlich das textfeld.
        }
    }
}
 
songliste.load("songlist.xml");//Liste laden 
 

Es sollte die Datei, auf die der erste XML-knoten verweist, abgespielt werden, wenn ihr den Film testet!

[pape]

7. Die automatische Wiedergabeliste:

Wie können wir jetzt eine automatische Wiedergabe der nächsten Knoten auch noch realisieren?

das Soundobjekt hat eine Methode namens "onSoundComplete".
Dieser Methode können wir eine function zuweisen, die ausgeführt werden soll, wenn der aktuelle Sound abgespielt wurde!
Wir sollten zunächst aber überlegen was wir machen wollen, wenn der Sound abgespielt wird...

Wir möchten den nächsten Sound abspielen!

Dafür brauchen wir also eine Variable, die uns sagt, welche Song-Nummer momentan abgespielt wird.
Ich nenne sie mal "song_nr"
Wir deklarieren sie sobald die Arrays gefüllt wurden und das SoundObjekt erstellt wurde.. und zwar als globale Variable, sodass wir von überall auf sie zugreifen können.
Wenn man sie auf 0 setzt, fängt man immer beim ersten Song an, man kann natürlich auch per random einen Zufalls wert nehmen:

//...
_global.song_nr = random(songfiles.length);
//... 
 

wenn nun ein Song fertig abgespielt wurde, brauchen wir nur zu überprüfen, ob noch weitere Songs vorhanden sind oder ob wir von vorne anfangen müssen und ansonten brauchen wir die Variable nur immer eins hochzuzählen:
wir erweitern demenstprechend den Prototypen:

this.sound_obj.onSoundComplete = function () {
    if (song_nr==songnamen.length-1) {//wenn die letzte Datei abgespielt wurde (-1 da song_nr bei 0 anfängt und der counter für die length bei 1)
        song_nr=0 // wieder von vorne Anfangen
    } else {
        _global.song_nr++ //sonst einfach den nächsten Song abspielen
    }
} 

Das ganze in der Kurzschreibweise:

this.sound_obj.onSoundComplete = function () {
    (song_nr==songfiles.length-1)? _global.song_nr=0 : _global.song_nr++;
} 

jetzt noch den nächsten Song starten mit

_root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]); 

der Prototyp sieht also fertig so aus:

MovieClip.prototype.song_starten = function (file, name) {
    this.sound_obj.loadSound(file,true)//true steht hier für streaming=an
    this.onEnterFrame = function () {//das onEnterFrame Ereignis 
        if(this.sound_obj.position>0) {//wenn der Sound startet
            delete this.onEnterFrame; // das onEnterFrame Ereignis löschen
            this._parent.anz.text=name; //name wurde als parameter it übergeben
        } else {
            this._parent.anz.text="loading..." //this._parent heißt soviel wie: dieser_mc_hier.die_übergeordnete_instanz dort liegt nämlich das textfeld.
        }
    }
    this.sound_obj.onSoundComplete = function () {//wenn der sound fertig abgespielt wurde
        (song_nr==songfiles.length-1)? _global.song_nr=0 : _global.song_nr++;//nächsten Song auswählen (-1 da song_nr bei 0 anfäng)
        _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//nächsten Song starten
    }
} 

8. Die Buttons:

Jetzt fehlen nur noch die Buttons!

button play macht nichts weiter, als den Song der grade ausgewählt ist, also der song_nr entsprechend zu starten:

btn_play.onRelease = function () {
    this._parent.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//aktuell ausgewählten Song starten
} 

btn_stop stoppt die Wiedergabe:

btn_stop.onRelease = function() {
    this._parent.sound_mc.sound_obj.stop(); //Wiedergabe stoppen
} 

Die function für btn_next ist mit der automatischen "nächster Song" function: onSoundComplete zu vergleichen:

btn_next.onRelease = function () {
    (song_nr==songfiles.length-1)? _global.song_nr=0 : _global.song_nr++;//nächsten Song auswählen (-1 da song_nr bei 0 anfäng)
    _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//nächsten Song starten
} 

btn_prev funktioniert genauso nur anders herum:

btn_prev.onRelease = function () {
    (song_nr==0)? _global.song_nr=songfiles.length-1 : _global.song_nr--;//vorherigen Song auswählen(song_nr--) es seiden der erste wurde grade abgespielt.. dann wieder hinten anfangen
    _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//vorherigen Song starten
} 

Anmerkung:
Es sei bemerkt, dass wenn die Wiedergabe gestoppt wurde und man auf next oder prev klickt die Wiedergabe beginnt!
das ist aber nicht schilmm und braucht nicht verhindert zu werden.
wer klickt auf next, wenn er nicht die Soundwiedergabe aktivieren möchte?... (jaja.. es gibt auch solche... :rolleyes)

Wie ihr seht, sind die Buttons das kleinste Problem, wenn man sich vorher ordentlich Gedanken gemacht hat!!!
Das sollte man grundsätzlich versuchen zu erziehelen: erst denken, dann scripten/umsetzen!



9. Das fertige ActionScript:

Das gesamte fertige ActionScript sollte nun so aussehen:

stop();//film anhalten
songliste = new XML();//neues XML Objekt
songliste.ignoreWhite=true;//Leerzeichen ignorieren
songliste.onLoad = function (success) {//onLoad function (wird ausgeführt, wenn die daten geladen werden)
    if(success) {//wenn das laden erfolgreich war
        //arrays erstellen
        _global.songnamen = [];
        _global.songfiles = [];
        for (var i=0; i<songliste.firstChild.childNodes.length; i++) {//für alle Elemente in der XMLfile
            //Die attribute auslesen und in die Arrays packen
            _global.songnamen[i] = songliste.firstChild.childNodes[i].attributes.name;
            _global.songfiles[i] = songliste.firstChild.childNodes[i].attributes.file;
            trace(songnamen[i]+"  "+songfiles[i]);//überprüfen, ob wirklich die Daten richtig übergeben wurden
        }
        _root.createEmptyMovieClip("sound_mc",1);
        _root.sound_mc.sound_obj = new Sound();
        _global.song_nr = random(songfiles.length); // per Zufall einen Song auswählen
        _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]); // song, der grade per Zufall ausgewählt wurde starten
    } else {anz.text="Fehler beim Laden der XML datei"}//falls ein Fehler auftritt beim Laden
}
 
MovieClip.prototype.song_starten = function (file, name) {
    this.sound_obj.loadSound(file,true)//true steht hier für streaming=an
    this.onEnterFrame = function () {//das onEnterFrame Ereignis 
        if(this.sound_obj.position>0) {//wenn der Sound startet
            delete this.onEnterFrame; // das onEnterFrame Ereignis löschen
            this._parent.anz.text=name; //name wurde als parameter it übergeben
        } else {
            this._parent.anz.text="loading..." //this._parent heißt soviel wie: dieser_mc_hier.die_übergeordnete_instanz dort liegt nämlich das textfeld.
        }
    }
    this.sound_obj.onSoundComplete = function () {//wenn der sound fertig abgespielt wurde
        (song_nr==songfiles.length-1)? _global.song_nr=0 : _global.song_nr++;//nächsten Song auswählen (-1 da song_nr bei 0 anfäng)
        _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//nächsten Song starten
    }
}
 
btn_play.onRelease = function () {
    this._parent.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//aktuell ausgewählten Song starten
}
btn_stop.onRelease = function() {
    this._parent.sound_mc.sound_obj.stop(); //Wiedergabe stoppen
}
btn_next.onRelease = function () {
    (song_nr==songfiles.length-1)? _global.song_nr=0 : _global.song_nr++;//nächsten Song auswählen (-1 da song_nr bei 0 anfäng)
    _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//nächsten Song starten
}
btn_prev.onRelease = function () {
    (song_nr==0)? _global.song_nr=songfiles.length-1 : _global.song_nr--;//vorherigen Song auswählen(song_nr--) es seidenn der erste wurde grade abgespielt.. dann wieder hinten anfangen
    _root.sound_mc.song_starten(songfiles[song_nr],songnamen[song_nr]);//vorherigen Song starten
}
 
songliste.load("songlist.xml");//Liste laden 
 

10. Ausleitung:

So das wars auch schon!
Wenn ihr alles richtig gemacht habt, dann solltet ihr jetzt, wie verpsrochen, einen funktionsfähigen Mp3Player haben, den ihr mit Xmldaten füttern könnt!

Anmerkungen:
Wenn ihr dieses script für eure Filme benutzen wollt, dann könnt ihr einfach eine datei anlegen, in der ihr den Player schreibt!
Passt dann aber auf nur relative Pfade zu benutzen (ich habe oben mit _root gearbeitet.. dass solltet ihr dann vermeiden, wenn ihr die Datei in einen Movieclip eures Hauptfilmes laden wollt!).

Im Anhang sind noch die zum Tutorial gehörigen Dateien!
Damit Sie auch wirklich funktionieren, müsst ihr Die Xml-Datei so anpassen, dass die Pfade zu euren Mp3-Datein stimmen.

noch was in eigener Sache: Ich hoffe, dass nirgendwo etwas unsinniges steht.. aber bei so langen Tutorials kann das leider schon mal vorkommen, dass man unten was ändert und es oben vergisst.. falls ihr so etwas entdeckt, so schreibt es bitte. danke!



Mit freundlichen Grüßen,
Robert


P.s.: Ich freue mich immer über Feedback!


mod edit: hier entlang gehts zu Part II:
MP3-Player mit XML-Fütterungszeit - Part II

[jonny-noob]

HAMMER!!! Vielen dank, werde es mir morgen mal genauer anschauen und versuchen einen mp3 player damit zu bauen

Achja, in deinem "noch was in eigener Sache" steht statt "dass" , "adss" und bisle dadrüber "erpsrochen", nene scherz, will net alles aufzählen, passt ja so, versteht man schon...

mfg jonny

[pape]

jo, bitte!

Hab noch so ca. 20 Reschtchraibpfela korrigiert!
grz
pape

[psyk]

Respekt.
Werd mir mal ne Woche freinehme und das durch ackern.

[tayfunde]

ohhh..fett ich fang gleich an...mach dein tut und optimiere dann meinen player! fett fett ..danke danke!

[tayfunde]

ja fett! bni fertig! und es hat alles geklappt! DANKE pape!
jetzt znur noch so oft reinzerren bis ich den code auswendig kann und dasnn ist gut!

[pape]

Zitat von tayfunde

jetzt znur noch so oft reinzerren bis ich den code auswendig kann und dasnn ist gut!

^^ ich empfehl eher zu versuchen den code zu verstehen als ihnm auswendig zu lernen!
wenn du ihn verstehst, kannst du ihn auf andere Dinge anwenden!
...

naja, danke für die Lobe

grz
pape

[Mindprint]

hi pape!

schönes, tutorial, gut kommentiert, leicht verständlich, man sieht dass du verstehst wovon du schreibst.
ich hab das ganze durchgearbeitet und funzt soweit, mit den buttons hab ich noch probleme aber das liegt wohl an der referenzierung, sollte kein problem sein.
hm, mache mir noch gedanken über den einbau der zeitanzeige.


wie gesagt, feine sache, danke für deine mühe, hat mir sehr geholfen

chears
mindprint

[pape]

Zitat von Mindprint

hm, mache mir noch gedanken über den einbau der zeitanzeige.

die Aktuelle position ist in der deinSound.position in Millisekunden gespeichert.
das würde sie dir dann ausgeben:

deineAnzeige.text=Math.round(deinSound.position/1000); 

mit der Länge wirds nen bisl schwieriger, weil die sounds gestreamt werden...
Die deinSound.duration gibt nämlich nur die Länge des schon geladenen sounds zurück!
man kann zwar die Länge berechnen, aber dafür muss man die Bitrate der Mp3 kennen.
Wenn du das vorhaben solltest, dann such mal im Forum; Die dazugehörige Rechnung hab ich hier irgendwann mal gefunden.
//edit: mp3 player streaming und ladestatus //edit end
Man kann auch die Bitrate per PHP auslesen.. das wird aber recht "kompliziert"... dazu habe ich mal was bei tutorials.de im Flashbereich irgendwo gesehen.. einfach mal suchen.

grz
pape

[Mindprint]

ok! thx!

werde das hier dann mal niederschreiben wenn ich weitergekommen bin
chears
mindprint

[bestboy]

super dieses tutorial! alles funktioniert!

probleme bereitet mir jetzt noch die zeitanzeige. genauer gesagt, wieß ich nicht, wie ich an "deinsound" komme. ich bin mir zudem auch nicht sicher, wo ich das script positionieren soll.

[salazar]

super! da haste dir aber viel mühe gegeben mit! respekt.
cya, sal

[pape]

schon mal eine Sache, die ich in dem Tutorial leider nicht beachtet habe :

man muss das Sound-Objekt löschen, sobald man einen neuen Sound starten will, wenn man eine Zeitanzeige umsetzen möchte.
Wenn man dies nicht tut, so läuft die Anzeige immer weiter und wird nicht wieder auf 00:00 gesetzt...

das erkläre ich aber in Teil 2 des Tutorials, den es bald geben wird (...wenn ich genügend Zeit finde den zuende zu schreiben... angefangen habe ich schon!)

bis dann,
grz
pape

@salazar: hallo & thx!