Tasteneingabe beschränken

[hoferisch]

hi zusammen.
ich befasse mich zum ersten mal mit tastensteuerung in einer flash-animation. das prinzip ist einfach, ich habe einen film, der an einigen stellen durch stop(); angehalten wird. ein allgegenwärtiges MC mit folgendem script ermöglicht das resume per enter-taste:

onClipEvent (enterFrame) {
    if (Key.isDown(Key.ENTER)) {
        _root.play();
        trace("YO!");
    }
} 

bisher hatte ich immer ein paar bilder zwischen den stops. aber nun hatte ich mal ein stop direkt nach dem anderen und hier überspringt er, da er (durch das trace ersichtlich) mehrmals enter zählt.

wie kann ich das unterbinden?
ich dachte daran, dass ich an jeder dieser stellen den mc einsetze und beim rest halt nicht, aber das würde beim aktuellen problem keine abhilfe schaffen und wäre insgesamt auch zu aufwendig

hat jemand abhilfe?


(sorry, falls ich damit eine extrem banale/stupide frage stelle, aber in der suche hab ich nix gefunden )

[hoferisch]

ich muss nochmal "stören" :/
ich habs mal folgendermassen probiert:

onClipEvent (enterFrame) {
    Key.addListener(this);
    this.onKeyUp = function(Key.ENTER) {
        trace("YO!");
        play();
        
    }
} 

in der ausgabe erhalte ich die meldung:
Szene=W, Ebene=C ACTIONS, Bild=1: Zeile 3: )' oder ',' erwartet
this.onKeyUp = function(Key.ENTER) {

Szene=W, Ebene=C ACTIONS, Bild=1: Zeile 6: Unerwartetes Auftreten von '}'
}

allerdings funktioniert es.
das trace wird jedoch NICHT ausgeführt...
kann mir jemand erklären, woran sich flash nun stösst?


im voraus VIELEN DANK!!

[hoferisch]

so wriklich eine antwort hat keiner für mich, oder?
oder stell ich mich zu blöd an ... helft mir doch bitte auf die sprünge...

Dein erstes Script würde schon funktionieren, wenn Du innerhalb der if-Bedingung den enterFrame löschst.

anyway.

Ups, hab nicht beachtet, das Du ein ClipEvent benutzt, machs mal lieber so:

deinMC.onEnterFrame = function ()  {
 if (Key.isDown(Key.ENTER)) {
 
                _root.play();
                trace("YO!");
delete this.onEnterFrame;
        }
} 

...dann dürfte es nur noch einmal auslösen.

anyway.

[hoferisch]

das funktioniert tatsächlich, jedoch sagt die ausgabe nun, dass sie an der stelle einen bezeichner erwartet und mein trace funktioniert auch nicht.

onclipevent () ohne bezeichner scheint ihm also nich zu schmecken?!

Mh, bezeichner erwartet, mh?
Das Script ist keine Clip-Aktion mehr - gehört also auf ein Schlüsselbild - das hast Du gemacht, oder?

trace wird nicht mehr ausgeführt, weil Flash alle Aktionen jenseits eines Scriptfehlers übergeht und nicht mehr ausführt.

anyway.

[hoferisch]

das war auf deinen ersten eintrag bezogen

onClipEvent (enterFrame) {
C_CONTROL.onEnterFrame = function ()  {
        if (Key.isDown(Key.ENTER)) {
                _root.play();
                trace("YO!");
                delete this.onEnterFrame;
        }
}
} 

ich weiss nich, ob ich das jetzt sehr umständlich gemacht habe, aber ich hab nicht viel ahnung von der funktionsweise der AS-syntax. so funktioniert es auf jeden fall. so wie du meinst, müsste ich das schlüsselbild mit dem script immer wieder einfügen, oder?

+++ edit:

andererseits funktioniert es eigentlich trotzdem nicht wirklich, denn mein trace wird wieder nicht angezeigt (obwohl kein fehler ausgegeben wird)

+++ edit:

"probieren geht über fragen"
danke vielmals!!!

Ähhm - nur mal so als Anmerkung am Rande:

das:

// diese Aktion steht als Bildaktion in dem Frame, in dem sich
// auch der  MC C_CONTROL befindet
C_CONTROL.onEnterFrame = function () {blabla} 

...ersetzt das:

// diese Aktion steht als Objektaktion auf dem MC C_CONTROL
onClipEvent(enterFrame) {blabla} 

anyway.

[hoferisch]

jaaaaaaaa, das hab ich mir dann später auch gedacht!
wie gesagt, VIELMALS danke

[hoferisch]

hallo nochmal,
ich habe eben herausgefunden, dass der vorschau-player in der flash-umgebung, die taste ENTER standardmässig zum stoppen und wieder starten eines filmes verwendet.

wenn ich den film exportiere und für sich selbst abspiele, funktioniert das script nicht bzw. nur einmal

muss ich das schlüsselbild mit dem script vielleicht auf jeden stopp legen? gibts da keine sinnige alternative?
oder muss ich den mc vielleicht an den stop-stellen irgendwie wieder initiieren? (keinen ahnung wie das geht, sorry )

Du kannst übrigens, wenn es Dir zu sehr auf den Nerv geht, den Film aufgrund genannten Problems in der Entwicklungsumgebung nicht testen zu können, einfach hergehen und in Flash das Shortcut ändern: Bearbeiten>Tastenkombinationen> und dann den Unterpunkt steuerung das Shortcut für 'abspielen' ändern...easy..

Nun zum Film: Ein stop auf jedem Bild ist unnötig, und am besten wäre es hier tatsächlich mit einem Listener zu arbeiten.

Habe Dir mal ein Bsp. angehangen.

anyway.

[hoferisch]

erstmal danke für deine antwort.
du arbeitest da nicht mehr mit play(); sondern mit frame+1, wie ich gesehen habe. da ich allerdings mit verschiedenen "bruchstellen" arbeite (nicht regelmässig das nächste bild) dachte ich an numerisch durchbezeichnete bilder, die ich dann mit ner laufvariable ansteuern könnte.

aber mein problem bei der ganzen sache ist was anderes:
der film ist eine art präsentation mit mehreren szenen. diese szenen werde ich später aus einem steuerfilm heraus mit tasten ansprechen.
der listener verwendet alle tasten bzw. reagiert auf einen beliebigen tastendruck. ist blöd, denn es sollte (wg der anderen aktionen) eigentlich nur enter sein.
also kann ich den listener aus deinem beispiel irgendwie auf bestimmte tastenaktionen beschränken?
oder wäre es vielleicht einfacher, die aktion mit dem "alten" script über den steuerfilm zentral laufen zu lassen? geht das dann irgendwie besser?

(im steuerframe wird es auch noch movieclips geben, die sich bewegen etc. aber das is alles zentral und fast unabhängig von den szenen im eigentlichen film)

boah, ich schwafel immer so viel... falls irgendwas nicht verständlich ist - i'm sorry ... sehr schwer zu erklären ... wenn dann bitte einfach nochmal fragen

DANKE!

Huch Sry, stimmt..so wie der Key Listener jetzt arbeitet reagiert der natürlich auf jede Taste...

Änder den Code einfach wie folgt:

stop();
kl = new Object();
kl.onKeyDown = function () {
    if (Key.isDown(Key.ENTER)) _root.gotoAndStop(_root._currentframe+1);
    };
Key.addListener(kl); 

Natürlich könntest Du hier statt der Anweisung _root.gotoAndStop(_root._currentframe+1) natürlich auch _root.play() schreiben (insofern sich dann an geeigneter Stelle ein stop() als Frameaktion befindet - ansonsten würde der Film bis zum Ende durchrasseln)...

Das mit den Szenen könnte sich vielleicht problematisch auswirken, da ich nicht weiß, ob der listener szenenübergreifend durchgeschliffen wird...
Probiers einfach mal aus, und experimentier ein wenig rum. Wenns weitere Probs gibt, weißt Du ja, was zu tun ist..

anyway.

[hoferisch]

ich hab mich noch ein wenig umgesehen und verwende nun folgendes script auf dem mc

onClipEvent (load) {
    _parent.waitforAnyKey = function() {
        _parent.onEnterFrame = function() {
 
// steuerung nach rechts
            if (Key.isDown(Key.RIGHT)) {
                if (_parent.NEXT == true) {
                    _parent.play();
                    trace("TASTE VOR gedrueckt");
                    delete _parent.onEnterFrame;
                    _parent.DIRECTION = "right";
                }
            }
 
// steuerung nach links
            if (Key.isDown(Key.LEFT)) {
                if (_parent.BACK == true) {
                    trace(_parent.G_frame);
                    var goal = _parent.G_frame - 1;
                    _parent.gotoAndStop("G"+goal);
                    _parent.DIRECTION = "left";
                    
                    trace("TASTE ZURUECK gedrueckt");
                    delete _parent.onEnterFrame;
                }
            }
 
 
// steuerung weiter
            if (Key.isDown(Key.SPACE)) {
                _parent.play();
                trace("TASTE SPACE gedrueckt!");
                delete _parent.onEnterFrame;
                _parent.DIRECTION = "right";
            }
        };
    };
    _parent.waitforAnyKey();
}
onClipEvent (keyUp) {
    if (Key.getCode() == 39) {
        trace("TASTE VOR losgelassen");
        _parent.waitforAnyKey();
    }
    if (Key.getCode() == 37) {
        trace("TASTE ZURUECK losgelassen");
        _parent.waitforAnyKey();
    }
    if (Key.getCode() == 32) {
        trace("TASTE SPACE losgelassen");
        _parent.waitforAnyKey();
    }
}