swfs per xml in container laden

[Randy]

Hallo, hab mal wieder ein kleines XML Problem. Hier mein Script:

function xmlgallery() {
        for (p=0; p<_global.total; p++) {
                _root.thumb_container.createEmptyMovieClip("thumbmc"+p, p+1);
            
              
                _root.thumb_container["thumbmc"+p]._x = 0;
                _root.thumb_container["thumbmc"+p]._y = ypos;
                _root.thumb_container["thumbmc"+p].loadMovie(thumb[p], p+1);
                ypos =ypos + 80;
                trace (ypos);
 
            }
   
} 

Damit lade ich jpegs links in einem Scroll Menü untereinander. Funktioniert auch super.

Dann hab ich noch folgendes Skript:

for(p=0; p<_global.total; p++) {
_root.thumb_container["thumbmc"+p].onRelease = function() {
       _root.content_mc.loadMovie(image[p], p+1);
}
} 

Mit diesem Script will ich nun die einzelnen Bilder in dem Scroll Menü klickbar machen.
So dass zum Beispiel wenn ich auf "thumbmc0" klicke, die image[0] (="1.swf") in den conten_mc geladen wird. Jedoch tut sich da nix. Das scrollmenü ist nicht einmal klickbar. Kann da jemand helfen ?

Dangeschööön

[Der Frager]

Hi!
Dein unteres Script würde dann (bedingt) funzen, wenn die Filme alle geladen sind. Mach das mal so:

function xmlgallery() {
    for (p=0; p<_global.total; p++) {
        mc = _root.thumb_container.createEmptyMovieClip("thumbmc"+p, p+1);
        mc1 = mc.createEmptyMovieClip("bild", 1);
        mc._x = 0;
        mc._y = ypos;
        mc1.loadMovie(thumb[p], p+1);
        ypos += 80;
        mc.id = p;
        mc.onRelease = function() {
            _root.content_mc.loadMovie(image[this.id], this.id+1);
        };
    }
} 

edit: this vergessen (this.id)

[Randy]

Ja, danke funktioniert jetzt

Kannste mir mal erklären (nur wennste Zeit hast) warum ich in meinen MC noch einen mc machen muss ?
Kann es vielleicht sein, dass dieser 2te mc erst geladen wird wenn der erste fertig geladen ist ? Somit als schleife dient, oder wie oder wat oder wer ?

Und danke nochmal

[Der Frager]

...das mit dem mc im mc macht man, da erst ein Event auf den Clip gelegt werden kann, wenn der Inhalt komplett geladen ist. Da hier nicht mc sondern mc1 den Inhalt läd, geht's halt gleich. Verstanden?

[Randy]

Respekt Gar nicht blöd. Vielen Dank.

Werd ich mir merken.

[Randy]

Zitat von Der Frager

mc.onRelease = function() {
            _root.content_mc.loadMovie(image[this.id], this.id+1);
        }; 

Noch ne Verständnisfrage: Wenn ich jetzt ohne id arbeite(sondern mit p), bekomme ich immer ein undefined (was ja auch klar ist, da die Schleife durchlaufen wir, und somit p nicht fest ist.)
Was macht jetzt das id ? Eigentlich speichert es ja nur den Wert von p. Warum gibt es dann kein undefined mehr ?

[Der Frager]

Hallo!
Weil die id jeweils an den mc weitergegeben (angehangen) wird und somit als "this.id" verfügbar ist. id hat dann logischerweise immer den Wert, den "p" zum Zeitpunkt der Erstellung hatte und jeder mc seine eigene id...