Flashforum - Die Community zu Adobe Flash, Flex AIR. Web Design und Inspiration.

firmaxy · 14-08-2005, 20:08

Ich suche für den Kalender (MX Standartkalender o.ä.) ein Actionscript, welches mir die Möglichkeit gibt über das entsprechend angeklickte Datum in einer xml Datei Daten abzurufen. Für Hilfe wäre ich sehr dankbar

cybermad · 14-08-2005, 23:36

Hi,

habe vor kurzem im Web folgendes Beispiel gefunden.
Kann man relativ einfach verändern.
Ich hoffe das hilft dir weiter.

ActionScript:

// begin date initialization
now=new Date();
today=now.getDate(); // get today's date
month=now.getMonth(); // get the month
year=now.getYear(); // get the year
// use another Date object to find the lastdate
lastdate=new Date(year, month+1, 0);
lastday=lastdate.getDate(); // get the lastdate
daycount=1; // variable to keep track of days
weekcount=0; // variable to keep track of weeks
// end date initialization
 
// loop through the month's days and create calendar
while(daycount<=lastday){
        now.setDate(daycount); // set the date object to current date
        weekday=now.getDay(); // find the day of the week
        
        // create the date movie clip
        _root.createEmptyMovieClip(daycount,daycount+10);
        with(_root[daycount]){
                // create the date textfield with position based upon weekday and week counts
                createTextField('thisDate',daycount+100,weekday*20  ,weekcount*30,17,20);
                with(thisDate){
                        selectable=false;
                        if(_root.today==daycount){ // if the current day is today, change it's color
                                format=getTextFormat();
                                format.color=0xff0000;
                                setNewTextFormat(format);
                        }
                        text=daycount;
                }
        }
        if(weekday==6){weekcount++;} // increment the weekcount
        _root.daycount++; // increment the daycount
}
// end day creation loop

Gruß

cybermad

firmaxy · 15-08-2005, 10:29

Hallo, danke. Ich werde berichten wenn ich fertig bin.
gruß

astaroth · 15-08-2005, 11:39

Probier mal das mit copy & paste

ActionScript:

DateHolder = new Object();
Date.prototype.getMonthDays = function(pJahr,pMonat) {
    return (new Date(pJahr,pMonat+1,0).getDate());
};
Date.prototype.getDayName   = function(pTag) { 
    return ["Sonntag","Montag","Dienstag","Mittwoch","Donnerstag","Freitag","Samstag"][pTag] 
} 
Date.prototype.getMonthName = function(pMonat) { 
    return  ["Januar","Februar","März","April","Mai","Juni","Juli","August","September","Oktober","November","Dezember"][pMonat] 
} 
DateHolder.datum       = new Date();
DateHolder.jahr         = DateHolder.datum.getFullYear();
DateHolder.monat       = DateHolder.datum.getMonth();
DateHolder.aktTag     = DateHolder.datum.getDate();
DateHolder.aktWochentag = DateHolder.datum.getDay();
DateHolder.aktMonat     = DateHolder.datum.getMonth();
DateHolder.aktJahr   = DateHolder.datum.getFullYear();
DateHolder.ersterTag    = new Date(DateHolder.jahr,DateHolder.monat,0).getDay();
DateHolder.tage         = DateHolder.datum.getMonthDays(DateHolder.jahr,DateHolder.monat);
DateHolder.Kuerzel   = ["Mo","Di","Mi","Do","Fr","Sa","So"];
DateHolder.aktMonatName = DateHolder.datum.getMonthName(DateHolder.aktMonat);
DateHolder.aktTagName   = DateHolder.datum.getDayName(DateHolder.aktWochentag);
DateHolder.datumtxt  = DateHolder.aktTagName + ", " + DateHolder.aktTag + "." + DateHolder.aktMonatName + " " + DateHolder.aktJahr
MovieClip.prototype.makeTriangle = function (tposx,tposy){
    this.moveTo(tposx,tposy);
    this.beginFill(0xE0E0E0,100);
    this.lineStyle(1,0x606060,100);
    this.lineTo(tposx,tposy+10);
    this.lineTo(tposx+15,tposy+5);
    this.lineTo(tposx,tposy);
    this.endFill();
    this.moveTo(tposx+1,tposy-1);
    this.lineStyle(1,0xFFFFFF,100);
    this.lineTo(tposx+1,tposy+9);
    this.lineTo(tposx+14,tposy+4);
    this.lineTo(tposx+1,tposy-1);
}
MovieClip.prototype.makeTriangle2 = function (tposx,tposy){
    this.moveTo(tposx+15,tposy);
    this.beginFill(0xE0E0E0,100);
    this.lineStyle(1,0x606060,100);
    this.lineTo(tposx+15,tposy+10);
    this.lineTo(tposx,tposy+5);
    this.lineTo(tposx+15,tposy+1);
    this.endFill();
    this.moveTo(tposx+14,tposy+1);
    this.lineStyle(1,0xFFFFFF,100);
    this.lineTo(tposx+14,tposy+9);
    this.lineTo(tposx,tposy+4);
    this.lineTo(tposx+14,tposy);
}
MovieClip.prototype.makeCalendar = function (pPosX,pPosY,tiefe) {
    var t = 0;
    var spalten = 0;
    var reihen = 0;
    this.CalendarMC.removeMovieClip();
    this.createEmptyMovieClip("CalendarMC",tiefe);
    this.CalendarMC.createEmptyMovieClip("Backgr1",105);
    this.CalendarMC.createEmptyMovieClip("Backgr2",106);
    with (this.CalendarMC["Backgr1"]){
        moveTo(0,0);
        beginFill(0xD0D0D0,100);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,18);
        lineStyle(2,0x808080,100);
        lineTo(154,18);
        lineTo(154,0);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,0);
        endFill();
    }
    with (this.CalendarMC["Backgr2"]){
        moveTo(0,0);
        beginFill(0xD0D0D0,100);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,18);
        lineStyle(2,0x808080,100);
        lineTo(154,18);
        lineTo(154,0);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,0);
        endFill();
    }
    this.CalendarMC["Backgr1"]._x = pPosX-2;
    this.CalendarMC["Backgr1"]._Y = pPosY+166;
    this.CalendarMC["Backgr2"]._x = pPosX-2;
    this.CalendarMC["Backgr2"]._Y = pPosY+196;
    this.CalendarMC.createEmptyMovieClip("monButvor",110); //
    with (this.CalendarMC["monButvor"]){//
        makeTriangle(0,1);//
    }
    this.CalendarMC["monButvor"]._x = pPosX+135; //
    this.CalendarMC["monButvor"]._y = pPosY+170;//
    this.CalendarMC["monButvor"].onPress = function (){//
        if (_root.DateHolder.monat<11){
        _root.DateHolder.monat++;
        setCal();
        }
    }
    this.CalendarMC.createEmptyMovieClip("monButzur",111);
    with (this.CalendarMC["monButzur"]){
        makeTriangle2(0,0);
    }
    this.CalendarMC["monButzur"]._x = pPosX;
    this.CalendarMC["monButzur"]._y = pPosY+170;
    this.CalendarMC["monButzur"].onPress = function (){
        if (_root.DateHolder.monat>0){
        _root.DateHolder.monat--;
        setCal();
        }
    }
    this.CalendarMC.createTextField("MTF",120,pPosX+30,pPosY+165,100,20);
    this.CalendarMC["MTF"].text = _root.DateHolder.datum.getMonthName(_root.DateHolder.monat);
    this.CalendarMC["MTF"].selectable = false;
    this.CalendarMC["MTF"].setTextFormat (_root.newFormTF2);    
    this.CalendarMC.createEmptyMovieClip("jahrButvor",112);
    with (this.CalendarMC["jahrButvor"]){
        makeTriangle(0,1);
    }
    this.CalendarMC["jahrButvor"]._x = pPosX+135; //135
    this.CalendarMC["jahrButvor"]._y = pPosY+200;
    this.CalendarMC["jahrButvor"].onPress = function (){
        _root.DateHolder.jahr++;
        setCal();
    }
    this.CalendarMC.createEmptyMovieClip("jahrButzur",113);
    with (this.CalendarMC["jahrButzur"]){
        makeTriangle2(0,0);
    }
    this.CalendarMC["jahrButzur"]._x = pPosX;
    this.CalendarMC["jahrButzur"]._y = pPosY+200;
    this.CalendarMC["jahrButzur"].onPress = function (){
        _root.DateHolder.jahr--;
        setCal();
    }
    this.CalendarMC.createTextField("JTF",121,pPosX+30,pPosY+195,100,20);
    this.CalendarMC["JTF"].text = _root.DateHolder.jahr;
    this.CalendarMC["JTF"].selectable = false;
    this.CalendarMC["JTF"].setTextFormat (_root.newFormTF2);        
    this.CalendarMC.createEmptyMovieClip("Leiste",100); 
    with(this.CalendarMC["Leiste"]){
        moveTo(0,0);
        beginFill(0xD0D0D0,100);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,20);
        lineStyle(1,0x808080,100);
        lineTo(152,20);
        lineTo(152,0);
        lineStyle(1,0xFFFFFF,100);
        lineTo(0,0);
        endFill();
    }
    this.CalendarMC["Leiste"]._x =pPosX;
    this.CalendarMC["Leiste"]._y =pPosY;
    for (o=0;o<7;o++){
        this.CalendarMC["Leiste"].createTextField("TF"+o,201+o,(o*22),0,23,20);
        with(this.CalendarMC["Leiste"]["TF"+o]){
            this.CalendarMC["Leiste"]["TF"+o].text = _root.DateHolder.Kuerzel[o];
            this.CalendarMC["Leiste"]["TF"+o].selectable = false;
            this.CalendarMC["Leiste"]["TF"+o].setTextFormat(_root.newFormTF2);
        }
    }
    for (var i = 0; i < 40; i++) {
        this.CalendarMC["Tag" + i].removeMovieClip();
    }
    for (var i = 0; i < _root.DateHolder.tage+_root.DateHolder.ersterTag; i++) {        
        if (i >= _root.DateHolder.ersterTag) {
            t++;
            this.CalendarMC.createEmptyMovieClip("Tag" + i, i);
            with(this.CalendarMC["Tag" + i]){
                moveTo (0, 0);
                beginFill(0xE0E0E0,100);
                lineStyle(1,0xFFFFFF,100);
                lineTo(0,20);
                lineStyle(1,0x808080,100);
                lineTo(20,20);
                lineTo(20,0);
                lineStyle(1,0xFFFFFF,100);
                lineTo(0,0);
                endFill();
            }
            this.CalendarMC["Tag" + i].createTextField("TF",i,1,2,20,20);
            this.CalendarMC["Tag" + i]["TF"].text = t;
            this.CalendarMC["Tag" + i]["TF"].setTextFormat(_root.newFormTF2);
            this.CalendarMC["Tag" + i].dtag = t;
            this.CalendarMC["Tag" + i].dmonat = _root.DateHolder.monat;
            this.CalendarMC["Tag" + i].djahr = _root.DateHolder.jahr;
            this.CalendarMC["Tag" + i].ddatum = t + ". " + _root.DateHolder.datum.getMonthName(_root.DateHolder.monat) + " " + _root.DateHolder.jahr;
            this.CalendarMC["Tag" + i]._x = pPosX + spalten * this.CalendarMC["Tag" + i]._width;
            this.CalendarMC["Tag" + i]._y = (pPosY+23) + reihen * this.CalendarMC["Tag" + i]._height;         
            this.CalendarMC["Tag" + i].onRollOver = function() {
                this.clear();
                this.moveTo (0, 0);
                this.beginFill(0xC0C0C0,100);
                this.lineStyle(1,0x808080,100);
                this.lineTo(0,20);
                this.lineStyle(1,0xFFFFFF,100);
                this.lineTo(20,20);
                this.lineTo(20,0);
                this.lineStyle(1,0x808080,100);
                this.lineTo(0,0);
                this.endFill();
            }
            this.CalendarMC["Tag" + i].onRollOut = this.CalendarMC["Tag" + i].onReleaseOutside = function() {
                this.clear();
                this.moveTo (0, 0);
                this.beginFill(0xE0E0E0,100);
                this.lineStyle(1,0xFFFFFF,100);
                this.lineTo(0,20);
                this.lineStyle(1,0x808080,100);
                this.lineTo(20,20);
                this.lineTo(20,0);
                this.lineStyle(1,0xFFFFFF,100);
                this.lineTo(0,0);
                this.endFill();
            }
            this.CalendarMC["Tag" + i].onPress = function() {
                trace (this.ddatum);
                this.clear();
                this.moveTo (0, 0);
                this.beginFill(0xFFA0A0,100);
                this.lineStyle(1,0x808080,100);
                this.lineTo(0,20);
                this.lineStyle(1,0xFFFFFF,100);
                this.lineTo(20,20);
                this.lineTo(20,0);
                this.lineStyle(1,0x808080,100);
                this.lineTo(0,0);
                this.endFill();
            }
        } 
        if (t == _root.DateHolder.aktTag &&
            _root.DateHolder.aktMonat == 
            _root.DateHolder.monat && 
            _root.DateHolder.aktJahr == _root.DateHolder.jahr) {
            this.CalendarMC["Tag" + i].fillMeCal();
            this.CalendarMC["Tag" + i].onRollOver = function (){};
            this.CalendarMC["Tag" + i].onRollOut = function (){};
        }
        spalten++;
        if (spalten == 7) {
            spalten = 0;
            reihen++;
        }      
    }   
}
MovieClip.prototype.fillMeCal = function (){
    this.clear();
    this.moveTo (0, 0);
    this.beginFill(0xBEB0FF,100);
    this.lineStyle(1,0xFFFFFF,100);
    this.lineTo(0,20);
    this.lineStyle(1,0x808080,100);
    this.lineTo(20,20);
    this.lineTo(20,0);
    this.lineStyle(1,0xFFFFFF,100);
    this.lineTo(0,0);
    this.endFill();
}
setCal = function (){
    _root.DateHolder.ersterTag = new Date(_root.DateHolder.jahr,_root.DateHolder.monat,0).getDay();
    _root.DateHolder.tage =_root.DateHolder.datum.getMonthDays(_root.DateHolder.jahr,_root.DateHolder.monat);
    makeCalendar(605,60,505);
}
setCal();

Änderungen dürften leicht zu machen sein.

....Gruß

Patrick

andretti · 15-08-2005, 12:03

wow!

wahnsinnsteil!

14-08-2005, 20:08	#1 (permalink)
firmaxy Neuer User Registriert seit: Aug 2005 Beiträge: 3	Suche Hilfe (Actionscript für Kalender) Ich suche für den Kalender (MX Standartkalender o.ä.) ein Actionscript, welches mir die Möglichkeit gibt über das entsprechend angeklickte Datum in einer xml Datei Daten abzurufen. Für Hilfe wäre ich sehr dankbar

15-08-2005, 10:29	#3 (permalink)
firmaxy Neuer User Registriert seit: Aug 2005 Beiträge: 3	danke Hallo, danke. Ich werde berichten wenn ich fertig bin. gruß

15-08-2005, 12:03	#5 (permalink)
andretti tracer Registriert seit: Jun 2004 Beiträge: 4.415	wow! wow! wow! wahnsinnsteil! __________________ Viola per Sempre Alle Angaben ohne Gewehr! trace your open mind in variables ! andretti ActionScript Dictionary

Themen-Optionen
Druckbare Version zeigen Jemanden per E-Mail auf dieses Thema hinweisen
Ansicht
Linear-Darstellung Zur Hybrid-Darstellung wechseln Zur Baum-Darstellung wechseln