SoundManager Klasse

[cmike]

Hi All

Ich poste an dieser stelle eine Soundmanager Klasse mit erweitertem Soundobjekt zur vereinfachten handhabung verschiedenster sounds und - jetzt kommts - SOUNDQUEUES!

Ich habe eine Weile nach einer solchen Klasse im Forum und im Internet gesucht, jedoch leider nichts brauchbares gefunden. Ich hoffe, dass auch andere diese Klasse verwenden können, um einfacher Sounds in ihren Flash-Projekten zu implementieren und zu verwalten.

Denkbare Anwendungsbereiche sind z.B. Player mit Playlisten (Erstellung der gesamten Playlist mit einem Befehl), Spiele mit Hintergrund- und Ereignissounds, vertonte Websites, usw.

Funktionsübersicht:

- Sounds und Soundqueues mit einem Befehl erstellbar
- Sounds werden automatisch im zentralen Soundmanager registriert
- Zugriff auf einzelne aber auch alle Sounds zusammen möglich
- Fadein und -out funktionen als methoden des Soundobjekts

Die Soundklasse ist noch etwas unausgereift, falls ihr demnach Anregungen oder Verbesserungen habt, lasst es mich wissen. Gerne investiere ich noch etwas Zeit, um den Code zu optimieren. Wenn jemand anderes lust hat, mir dabei zu helfen, wäre ich natürlich auch sehr dankbar

cheers

mike

[cmike]

anschliessend noch den code der beiden klassen zum screenen:

class SoundManager {
    
    // Variable declaration
    
    var intFadeTime:Number;
    var arrSoundObjects:Array;
    var intIDcount:Number;
    var strName:String;
    
    // FUNCTION: SoundObject
    // constructor method -> setting default Values
    
    function SoundManager(strName) {
        if (strName == null) { strName = random(99999) + getTimer(); }
        this.strName = strName;
        this.intIDcount = -1;
        this.intFadeTime = 2000;
        this.arrSoundObjects = new Array();
    }
    
    // FUNCTION: addSound
    // adds single sounds and sound queues to the library
    
    function addSound(objFiles) {
        if (objFiles != null) {
            this.intIDcount++;
            _root.createEmptyMovieClip("_SOUND_" + this.strName + "_" + this.intIDcount, 100 + this.intIDcount);
            this.arrSoundObjects[this.intIDcount]          = eval("_root._SOUND_" + this.strName + "_" + this.intIDcount);
            this.arrSoundObjects[this.intIDcount].objSound = new SoundObject(this.arrSoundObjects[this.intIDcount]);
            this.arrSoundObjects[this.intIDcount].objSound.newSound(objFiles);
            this.arrSoundObjects[this.intIDcount].objSound.regID(this.intIDcount);
            return this.arrSoundObjects[this.intIDcount].objSound;
        } else {
            trace("SOUND ERROR: parameter ojbFiles is undefined in SoundManager->addSound();");
        }
    }
    
    // FUNCTION: delSound
    // delete sounds according to their ID
    
    function delSound(intID:Number) {
        this.arrSoundObjects[intID].objSound.stop();
        this.arrSoundObjects[intID].removeMovieClip();
        delete this.arrSoundObjects[intID];
        return true;
    }
    
    // FUNCTION: fadeIn
    // fade in all sounds registered in sound manager
    
    function fadeIn() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.fade(true, false);
        }
    }
    
    // FUNCTION: fadeOut
    // fade out all sounds registered in sound manager
    
    function fadeOut() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.fade(false, true);
        }
    }
    
    // FUNCTION: stop
    // stops all sounds
    
    function stop() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.stop();
        }
    }
    
    // FUNCTION: play
    // starts all sounds
    
    function play() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.start();
        }
    }
    
    // FUNCTION: pause
    // pause all sounds
    
    function pause() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.pause();
        }
    }
    
    // FUNCTION: mute
    // mute or demute all sounds registered in sound manager
    // depending on current status
    
    function mute() {
        var i;
        for(i=0;i<this.arrSoundObjects.length;i++) {
            this.arrSoundObjects[i].objSound.mute();
        }
    }
} 

und

class SoundObject extends Sound {
    
    // Variable declaration
    
    private var intVolumeMax:Number;
    private var intVolumeMin:Number;
    private var intFadeTime:Number;
    private var intFadeID:Number;
    private var intQueueID:Number;
    private var intQueueTrack:Number;
    private var intID:Number;
    
    private var bolFX:Boolean;
    private var bolMute:Boolean;
    private var bolFadeOngoing:Boolean;
    
    private var arrQueue:Array;
    
    public function onFadeComplete():Void { }
    
    // FUNCTION: SoundObject
    // constructor method -> setting default Values
    
    function SoundObject() {
        this.bolFX          = true;
        this.arrQueue       = new Array();
        this.intQueueTrack  = 1;
        this.intVolumeMax   = 100;
        this.intVolumeMin   = 0;
        this.intFadeTime    = 3000;
        this.bolFadeOngoing = false;
        this.bolMute        = false;
    }
    
    // FUNCTION: regID
    // register SoundID in SoundObject for Access over Soundmanager
    
    function regID(ID) {
        this.intID = ID;
    }
    
    // FUNCTION: getID
    // get SoundID for Access over Soundmanager
    
    function getID() {
        return this.intID;
    }
    
    // FUNCTION: setFX
    // turn soundFX on or off
    
    function setFX(FX) {
        this.bolFX = FX;
    }
    
    // FUNCTION: getFX
    // get soundFX status
    
    function getFX() {
        return this.bolFX;
    }
    
    // FUNCTION: observeQueue
    // observe playing sound and fadeout before track ends
    
    function observeQueue() {
        if (this.arrQueue.length > 1) {
            if (this.position > this.duration - this.intFadeTime - 500 && this.position != this.duration) {
                clearInterval(this.intQueueID);
                this.fade(false);
            }
        } else {
            clearInterval(this.intQueueID);
        }
    }
 
    // FUNCTION: setVolumeMax
    // set the max Volume (default 100)
    
    function setVolumeMax(intVolume) {
        this.intVolumeMax = intVolume;
    }
    
    // FUNCTION: setVolumeMin
    // set the min volume (default 0)
    
    function setVolumeMin(intVolume) {
        this.intVolumeMin = intVolume;
    }
    
    // FUNCTION: getVolumeMax()
    // returns intVolumeMax
    
    function getVolumeMax() {
        return this.intVolumeMax;
    }
    
    // FUNCTION: getVolumeMin()
    // returns intVolumeMin
    
    function getVolumeMin() {
        return this.intVolumeMin;
    }
    
    // FUNCTION: newSound
    // adds a new sound or soundqueue (depending
    // on input tpye) to the soundobject
    // WARNING: overwrites old sounds in same
    // object!
    
    function newSound(objFiles) {
        this.arrQueue      = new Array();
        this.intQueueTrack = 1;
        if (objFiles instanceof Array) {
            this.arrQueue        = objFiles;
            this.onSoundComplete = function() {
                this.nextSound();
            }
        } else {
            this.arrQueue[0]     = objFiles;
            this.onSoundComplete = function() { }
        }
    }
    
    // FUNCTION: prevSound
    // toggle previous soundtrack in queue
    
    function prevSound() {
        if (0 < this.intQueueTrack) {
            this.intQueueTrack--;
        } else {
            this.intQueueTrack = this.arrQueue.length;
        }
        this.play();
        if (this.bolFX == true) {
            this.setVolume(0);
            this.fade(true);
        }
    }
    
    // FUNCTION: nextSound
    // toggle next soundtrack in queue
    
    function nextSound() {
        if (this.arrQueue.length > this.intQueueTrack) {
            this.intQueueTrack++;
        } else {
            this.intQueueTrack = 1;
        }
        this.play();
        if (this.bolFX == true) {
            this.setVolume(0);
            this.fade(true);
        }
    }
    
    // FUNCTION: play
    // extended sound playing function
    
    function play(intOffset:Number, intRepeat:Number) {
        if (intOffset == null) { intOffset = 0; }
        if (intRepeat == null) { intRepeat = 1; }
        this.start(0);
        this.stop();
        clearInterval(this.intQueueID);
        this.intQueueID = setInterval(this, "observeQueue", 500);
        this.loadSound(this.arrQueue[intQueueTrack-1], true);
        this.start(intOffset, intRepeat);
    }
    
    // FUNCTION: mute
    // mute soundobject
    
    function mute(bolMute:Boolean) {
        if (bolMute == null) {
            if (this.bolMute == true && bolFadeOngoing != true) {
                this.bolMute = false;
                this.setVolume(this.intVolumeMax);
            } else {
                this.bolMute = true;
                this.setVolume(0);
            }
        } else {
            this.bolMute = bolMute;
            if (this.bolFadeOngoing != true) {
                if (bolMute == true) {
                    this.setVolume(0);
                } else {
                    this.setVolume(this.intVolumeMax);
                }
            }
        }
    }
    
    // FUNCTION: fadeIn
    // fade in sound dynamically from zero
    
    function fadeIn() {
        this.setVolume(0);
        this.fade(true);
    }
    
    // FUNCTION: fadeOut
    // fade out sound dynamically from intVolumeMax
    
    function fadeOut() {
        this.setVolume(this.intVolumeMax);
        this.fade(false);
    }
    
    // FUNCTION: setFadeTime
    // set fading time
    
    function setFadeTime(intFadeTime:Number) {
        this.intFadeTime = intFadeTime;
    }
    
    // FUNCTION: getFadeTime
    // get fading time back
    
    function getFadeTime() {
        return this.intFadeTime;
    }
    
    // FUNCTION: fade
    // initialise fading process
    
    function fade(bolMode:Boolean, bolMute:Boolean, intTime:Number) {
        if (this.bolMute != true || bolMute == false) {
            this.bolFadeOngoing = true;
            if (bolMute != null) {
                this.mute(bolMute);
            }
            if (intTime == null) { 
                intTime = this.intFadeTime; 
            }
            var intSteps   = Math.round(intTime / 50);
            clearInterval(this.intFadeID);
            this.intFadeID = setInterval(this, "aniFade", intSteps, bolMode);
        }
    }
    
    // FUNCTION: aniFade
    // animates fading process by drawing seperate steps to output channel
    
    function aniFade(bolMode) {
        if (this == null) {
            clearInterval(this.intFadeID);
        } else if (bolMode == true && this.bolMute != true) {
            this.setVolume(this.getVolume() + 2);
            if (this.getVolume() >= this.intVolumeMax) {
                this.setVolume(this.intVolumeMax);
                clearInterval(this.intFadeID);
                this.bolFadeOngoing = false;
                this.onFadeComplete();
            }
        } else {
            this.setVolume(this.getVolume() - 2);
            if (this.getVolume() <= this.intVolumeMin) {
                this.setVolume(this.intVolumeMin);
                clearInterval(this.intFadeID);
                this.bolFadeOngoing = false;
                this.onFadeComplete();
            }
        }
    }
} 

[bobo_k1]

das DIng such ich eigentlich - leider funktioniert die KLasse nicht