sound fertig, dann nächstes bild

[Denjo132]

hi
ich hab ein problem ich weiß nich wie ich es machen soll das wenn ein sound fertig abgespielt ist das nächste bild in der zeitleiste kommt... geht das überhaupt?
danke schonma

greetz denjo

[janoshnosh]

Sound.onSoundComplete
Availability
Flash Player 6.

Usage
my_sound.onSoundComplete = function(){
// your statements here
}

Parameters
None.

Returns
Nothing.

Description
Event handler; invoked automatically when a sound finishes playing. You can use this handler to trigger events in a SWF file when a sound finishes playing.

You must create a function that executes when this handler is invoked. You can use either an anonymous function or a named function.

Example
Usage 1: The following example uses an anonymous function:

var my_sound:Sound = new Sound();
my_sound.attachSound("mySoundID");
my_sound.onSoundComplete = function() {
  trace("mySoundID completed");
};
my_sound.start(); 

Usage 2: The following example uses a named function:

function callback1() {
  trace("mySoundID completed");
}
var my_sound:Sound = new Sound();
my_sound.attachSound("mySoundID");
my_sound.onSoundComplete = callback1;
my_sound.start(); 

See also
Sound.onLoad

[Denjo132]

danke

kann ich auch irgendwie anzeigen lassen
a) wie lang der sound ist?
und
b) wie lange er schon spielt?

[janoshnosh]

ich mach mal weiter mit dem strgC+strgV spiel

Sound.position
Availability
Flash Player 6.

Usage
my_sound.position:Number

Description
Read-only property; the number of milliseconds a sound has been playing. If the sound is looped, the position is reset to 0 at the beginning of each loop.

Example
See Sound.duration for a sample usage of this property.

See Also
Sound.duration

Sound.duration
Availability
Flash Player 6.

Usage
my_sound.duration:Number

Description
Read-only property; the duration of a sound, in milliseconds.

Example
The following example loads a sound and displays the duration of the sound file in the Output panel. Add the following ActionScript to your FLA or AS file.

var my_sound:Sound = new Sound();
my_sound.onLoad = function(success:Boolean) {
  var totalSeconds:Number = this.duration/1000;
  trace(this.duration+" ms ("+Math.round(totalSeconds)+" seconds)");
  var minutes:Number = Math.floor(totalSeconds/60);
  var seconds = Math.floor(totalSeconds)%60;
  if (seconds<10) {
    seconds = "0"+seconds;
  }
  trace(minutes+":"+seconds);
};
my_sound.loadSound("song1.mp3", true); 

The following example loads several songs into a SWF file. A progress bar, created using the Drawing API, displays the loading progress. When the music starts and completes loading, information displays in the Output panel. Add the following ActionScript to your FLA or AS file.

var pb_height:Number = 10;
var pb_width:Number = 100;
var pb:MovieClip = this.createEmptyMovieClip("progressBar_mc", this.getNextHighestDepth());
pb.createEmptyMovieClip("bar_mc", pb.getNextHighestDepth());
pb.createEmptyMovieClip("vBar_mc", pb.getNextHighestDepth());
pb.createEmptyMovieClip("stroke_mc", pb.getNextHighestDepth());
pb.createTextField("pos_txt", pb.getNextHighestDepth(), 0, pb_height, pb_width, 22);
 
pb._x = 100;
pb._y = 100;
 
with (pb.bar_mc) {
  beginFill(0x00FF00);
  moveTo(0, 0);
  lineTo(pb_width, 0);
  lineTo(pb_width, pb_height);
  lineTo(0, pb_height);
  lineTo(0, 0);
  endFill();
  _xscale = 0;
}
with (pb.vBar_mc) {
  lineStyle(1, 0x000000);
  moveTo(0, 0);
  lineTo(0, pb_height);
}
with (pb.stroke_mc) {
  lineStyle(3, 0x000000);
  moveTo(0, 0);
  lineTo(pb_width, 0);
  lineTo(pb_width, pb_height);
  lineTo(0, pb_height);
  lineTo(0, 0);
}
 
var my_interval:Number;
var my_sound:Sound = new Sound();
my_sound.onLoad = function(success:Boolean) {
  if (success) {
    trace("sound loaded");
  }
};
my_sound.onSoundComplete = function() {
  clearInterval(my_interval);
  trace("Cleared interval");
}
my_sound.loadSound("song3.mp3", true);
my_interval = setInterval(updateProgressBar, 100, my_sound);
 
function updateProgressBar(the_sound:Sound):Void {
  var pos:Number = Math.round(the_sound.position/the_sound.duration*100);
  pb.bar_mc._xscale = pos;
  pb.vBar_mc._x = pb.bar_mc._width;
  pb.pos_txt.text = pos+"%";
} 

See Also
Sound.position

darfst auch gerne mal selber F1 in flash drücken und dir die sound-methoden anschauen.
gruß janosch

[Denjo132]

hehe... ich wusste nich das das duration heißt aber ich hab vorher ja gesucht

war auch meine letzte frage (für heute)

danke nochma

[Denjo132]

oder auch nich... ich hab kein plan wie ich das jetzt in ein dynamisches textfeld schreiben lasse... also das das textfeld anzeigt wie viele sekunden schon vorbei sind

[janoshnosh]

umn, ok

also mit der Sound.position eigenschaft ist es ja so, dass sie je nachdem, wann man sie aufruft, einen anderen wert liefert. logisch, da der sound ja abspielt und sich die eigenschaft dadurch verändert. wenn du nun in deinem textfeld die zeit anzeigen willst, musst du also ständig diese eigenschaft von deinem sound-objekt abfragen.

am besten du hast einen MC (dein_mc) in dem sich das textfeld (position_txt) befindet. diesem MC gibst du einen onEnterFrame handler, der bei jedem frameaufruf (also bei 20fps 20 mal pro sekunde) die eigenschaft deines sound-objekts (laerm_sound) abfragt und an das textfeld gibt.

dein_mc.onEnterFrame = function () {
this.position_txt.text = laerm_sound.position;
} 

nun solltest du aber, wenn kein sound gespielt wird, den onEnterFrame handler löschen (delete dein_mc.onEnterFrame), damit das ding nicht ewig weiter läuft, selbst wenn nix passiert. im obigen beispiel wird nun auch nur die restzeit in millisekunden angezeigt, aber so ungefähr kannst du das auf jeden fall machen.

gruß janosch

[Denjo132]

ok.. ich probiers ma aus...
danke

[Denjo132]

es funzt... danke danke
kann man die zeit auch in sekunden anzeign lassn?
oder geht das nich?

[janoshnosh]

es sind ja millisekunden, wenn du sie also durch tausen teilst, hast du sekunden, wenn du sie dann noch rundest hast du echte sekunden. minuten:sekunden (mm:ss) anzeige ist da ein bisschen more tricky.

sonst halt einfach:
position_txt.text = Math.round(laerm_sound.position/1000);

gruß janosch

[Denjo132]

es funzt schon wieder
super naja danke nochma

wüsstest du denn wies geht die minuten und sekunden anzeigen zu lassen?

[janoshnosh]

oh sorry ist mir entgangen, dass es hier schon weiter ging
ja hier eine kleine funktion mit beispielaufruf:

function hhmmss (ms) {
    var t = ms/1000;
    var hh = '0';
    var mm = Math.floor(t/60) + '';
    var ss = Math.round(t - mm*60) + '';
    if (ss.length==1) ss = '0' + ss;
    if (mm.length >2) {
        hh = Math.floor(mm/60) + '';
        mm = Math.round(mm - hh*60) + '';
    }
    if (mm.length==1) mm = '0' + mm;
    return hh+':'+mm+':'+ss;
}
 
trace(hhmmss(3000));        //traces 0:00:03
trace(hhmmss(36453456));    //traces 10:07:33 
 

also die sound.position dann in deinem fall als hhmmss(sound.position) ausgeben lassen - alles was als millisekunde reinkommt, kommt im hh:mm:ss format raus.
bzw. so, um nur mm:ss zu erhalten:

function mmss (ms) {
    var t = ms/1000;
    var mm = Math.floor(t/60) + '';
    var ss = Math.round(t - mm*60) + '';
    if (ss.length==1) ss = '0' + ss;
    return mm+':'+ss;
} 

noch was?
gruß janosch

[Denjo132]

ne danke das war erstma das was ich wissn will
danke schön