Sound FadeIn 'n Out

[sakn]

Hi Leute

Nun wiedereinmal seh ich nicht ganz durch bei MX 2004...Thematik Sound
Ich hab mich hier quer durch alle Sound Beiträge durch gelesen, und versteh ehrlich gasagt immernoch BAHNHOOOOFFF!

Ihr werdet mich fürn Dummy halten, aber bei der Thematik Sound bei Flash dürft ihr das auch... ..aber ich hoffe trozdem auf eure gut gemeinte Unterstützung!

Ich versuch schon seit geraumer Zeit einen einzigen Sound Loop ein und auch wieder auszufaden...per release-action...leider ohne erfolg...
...und so sieht mein jetziges roh Konstrukt aus...

bgSound = new Sound(this);
bgSound.attachSound("sound1");
bgSound.setVolume(100);
bgSound.start(0, 999);
soundST.playB.enabled=false;

soundST.playB.onRelease = function()
{
bgSound.start(0, 999);
soundST.playB.enabled=false;
soundST.stopB.enabled=true;
};

soundST.stopB.onRelease = function()
{
bgSound.stop();
soundST.playB.enabled=true;
soundST.stopB.enabled=false;
};
stop();

...nun, ich hab verschiedenste Ansätze hier recherchiert, und auch versucht hier einzubauen, aber wie schon gesagt ohne Erfolg. Ich wäre Dir, Ihm oder Euch sehr dankbar, wenn ihr mir hierzu die optimale und gerne auch einfachste Lösung geben könntet.

Cheers im voraus
SAKN

[harego]

hi,

was verstehst du unter "faden" ?

Meinst du die Lautstärke ?

[shorty]

downloadlink, hängt hinten drann

du kannst die funktion natürlich beliebig umschreiben, in dem hier getippeltem beispiel, wird der sound in der fader funktion gestartet, bzw. gestopPpt.

• fade in
• fade out
• fader speed
• max volume für fade in
• position merken
• beim nächsten fade in von letzter fade out position starten
• u.s.w. .....

ich denk das script erklärt sich von alleine: in SB1

PHP-Code:

// sound object -----------------------------------------
var sndMySound:Sound = new Sound();
sndMySound.attachSound('myMp3');
sndMySound.setVolume(0);
sndMySound.stop();
// fader function 2in1 ----------------------------------
var fncSoundFader:Function;
function fncSoundFader(fade:Boolean) {
    var maxVol:Number = 100;
    var speed:Number = 5;
    var curVol:Number = sndMySound.getVolume();
    var curPos:Number = sndMySound.position/1000;
    _root.createEmptyMovieClip('gen_mcDummy', 14590);
    if (fade) {
        sndMySound.start(curPos);
        _root.gen_mcDummy.onEnterFrame = function() {
            curVol += speed;
            sndMySound.setVolume(curVol);
            if (curVol>=maxVol) {
                sndMySound.setVolume(maxVol);
                removeMovieClip(this);
            }
        };
    } else {
        _root.gen_mcDummy.onEnterFrame = function() {
            curVol -= speed;
            sndMySound.setVolume(curVol);
            if (curVol<=0) {
                sndMySound.setVolume(0);
                sndMySound.stop();
                removeMovieClip(this);
            }
        };
    }
}
/*  so gehts ...

--> starten mit: fncSoundFader(true)
--> stoppen mit: fncSoundFader(false)

mfg shorty
*/ 


http://www.shorty-bmc.com/temp/flash...soundFader.zip

ok, dat wars
peace & fette beute

[benny-l]

genial! aber was wenn ich meherer buttons hab und dort jeweils der entsprechende sound ein bzw. ausfaden soll... wie schreibt mann das dann?

[mike.nottebrock]

wäre toll, wenn der link auch funktionieren würde

[public]

machste das einfach so...is zwar anders gelöst geht aber auch...

PHP-Code:

Sound.prototype.fadeIn = function($targetVol:Number, $steps:Number) {
    var vol:Number = this.getVolume();
    function interval($obj) {
        vol += $steps;
        $obj.setVolume(vol);
        updateAfterEvent();
        if (vol == $targetVol) {
            $obj.setVolume($targetVol);
            $obj.onFadeComplete();
            clearInterval(id);
        }
    }
    var id = setInterval(interval, 20, this);
};
// 
// fadeOut(targetVol, steps)
//
Sound.prototype.fadeOut = function($targetVol:Number, $steps:Number) {
    var vol:Number = this.getVolume();
    function interval($obj) {
        vol -= $steps;
        $obj.setVolume(vol);
        updateAfterEvent();
        if (vol == $targetVol) {
            $obj.setVolume($targetVol);
            $obj.onFadeComplete();
            clearInterval(id);
        }
    }
    var id = setInterval(interval, 20, this);
};
//
// fadeVolume(targetVolume,steps)
//
Sound.prototype.fadeVolume = function($targetVol:Number, $steps:Number) {
    if ($targetVol>this.getVolume()) {
        this.fadeIn($targetVol, $steps);
    } else if ($targetVol<this.getVolume()) {
        this.fadeOut($targetVol, $steps);
    }
};
//
// bsp aufruf
//
var snd = new Sound(this);
snd.loadSound("deineMusic.mp3", true);
fadeIn_mc.onRelease = function() {
    snd.fadeVolume(100, 1);
};
fadeOut_mc.onRelease = function() {
    snd.fadeVolume(0, 1);
};