Sleep Funktion zur Verzörgerung von ToolTip funktioniert nicht

[Mayday171]

Hey Leute!

Habe eine ToolTip Funktion gebastelt und diese bereits erfolgreich eingebaut.
Ich bin jetzt nur noch auf der Suche nach einer Funktion, die mir den Tool Tip ausgibt, nachdem man eine gewisse Zeit auf dem mc (in diesen Fall) draufgewesen ist (RollOver).
Wie kann ich das realisieren?
Habs versucht, aber irgendwie klappt es nicht (Codeausschnitt unten)
Kann mir jemand dabei helfen???

mc1.onRollOver = function () {
	font1.color =0x9ACB33;
	// ----- SLEEP FUNKTION -----//
	var count:Number = 1; 
	id1 = setInterval(this, "dannMache", 500); 
	function dannMache() { 
    	this.setToolTip(this._name, 70, 0xFFFFFF); 
    	clearInterval(id1); 
	}
	//------- SLEEP FUNKTION ENDE -
			
			
			
	this.txt.setTextFormat(font1);
}

DANKE

MfG

[_geo_]

versuchs mal mit setInterval(dannMache,500); //<- as1

mfg geo

[Mayday171]

Hab ich auch schon versucht, funktioniert nicht und muss ja auch so sein, weil er ja auf die Funktion im mc zugreifen soll(in diesen Fall "this" in dem er sich befindet).
Gibt es eine andere Möglichkeit eine Verzögerung zu erzwingen oder bekomme ich das ganze mit setInterval noch zum laufen???

MfG

[Mr.Dauerfeuer]

Vielleicht hilf dir meine ToolTip Class weiter, das einzige was Du brauchst is nen MC in der Bib der nen Textfeld und nen Hintergrund hat...
Den ToolTip kannste an jeder beliebigen Stelle im Film verwenden.
Textfeldname = txt
Hintergrundname = bg

Class:

PHP-Code:


import mx.utils.Delegate;

class de.loewensprung.util.ToolTip
{
    
    private var _toolTip_mc : MovieClip;
    
    // ToolTip MovieClip
    private var mouseListener : Object;
    
    private var _target:MovieClip;
    
    // Interval to show and hide
    private var _intervalID : Number;
    
    public function ToolTip (target)
    {
        _target = target;
        mouseListener = new Object ();
        Mouse.addListener (mouseListener);
        init ();
    }
    
    private function init () : Void
    {
        _toolTip_mc = _target.attachMovie ("toolTip", "toolTip_mc", 99999);
        
        mouseListener.onMouseMove = Delegate.create (this, this.mouseIsMoving);
        
        _toolTip_mc._visible = false;
        
    }
    
    public function enableToolTip (tip : String) : Void
    {
        if (tip != _toolTip_mc.txt.text)
        {
            _intervalID = setInterval (this, "showToolTip", 500);
            _toolTip_mc.txt.text = tip;
            _toolTip_mc.txt.autoSize = true;
            _toolTip_mc.txt.wordWrap = true;
            var tf : TextFormat = _toolTip_mc.txt.getTextFormat ();
            var metrics : Object = tf.getTextExtent (tip);
            // Max width for ToolTip
            if (metrics.width > 150)
            {
                _toolTip_mc.txt._width = 150;
            
            } else {
                
            _toolTip_mc.txt._width = metrics.width + 5;
            _toolTip_mc.txt.wordWrap = false;
            
                
            }
            
            _toolTip_mc.bg._width = _toolTip_mc.txt._width + 10;
            _toolTip_mc.bg._height = _toolTip_mc.txt._height + 10;
        }
    }
    
    private function showToolTip () : Void
    {
        clearInterval (_intervalID);
        _toolTip_mc._visible = true;
    }
    
    
    
    public function disableToolTip () : Void
    {
        _toolTip_mc.txt.text = "no toolTip";
        clearInterval (_intervalID);
        _toolTip_mc._visible = false;
    }
    
    
    private function mouseIsMoving ()
    {
    
        if( (_target._ymouse + _toolTip_mc._height + 10) > Stage.height) {
            
            
            _toolTip_mc._y = _target._ymouse + 5 - _toolTip_mc.bg._height;
            
        } else {
        
            _toolTip_mc._y = _target._ymouse + 5;
        
        }
        
        _toolTip_mc._x = _target._xmouse + 15;
        
    }
    
    public function getMC () : MovieClip 
    {
        return _toolTip_mc;
    }
    
    
    
    public function kill () : Void 
    {
        _toolTip_mc.removeMovieClip();
        Mouse.removeListener(mouseListener);
    }
    
} 


Verwenden:

PHP-Code:

import de.loewensprung.util.ToolTip;
_global.toolTip = new ToolTip(this);

irgendeinmc.onRollOver = function() {


_global.toolTip.enableToolTip("mein ToolTip Text");


}

irgendeinmc.onRollOut = irgendeinmc.onReleaseOutside= function() {


_global.toolTip.disableToolTip();


}