setInterval übergabe von this

[destroy90210]

hiho

habe da ein kleines prob ich rufe eine funktion auf wo sich ein setInterval drinnen befindet leider kann ich nur ein this übergeben beim zweiten bekomme ich nicht mal ein undefined er schrebt beim tracen einfach gar nix hin...

hier mal das script

der aufruf

PHP-Code:

_root.dummyGegenstaendeMC.fadeOut(1,3);
_root.bg1.fadeOut(2,3); 


die function

PHP-Code:

MovieClip.prototype.fadeOut = function(ID,key) {
    var mc = this;
    mc["fadeout"+ID] = setInterval(function () {
                trace("ID: "+ID);
                trace("mc: " + mc);
        if (mc._alpha>0) {
            mc._alpha -= 5;
        } else {
            clearInterval(mc["fadeout"+ID]);
            trace("----------");
            k++;
            mc.removeMovieClip();
            gotoAndStop(key);
        }
        // hier updaten 

    },20,key);
}; 


beim trcen kommt dann folegndes raus das erste setInerval wird gelöscht aber das zweite gar ned da erkennt er das mc ned oder so kein plan genau was da passiert...

----------
ID: 1
mc: _level0.dummyGegenstaendeMC
ID: 2
mc:
----------
ID: 1
mc: _level0.dummyGegenstaendeMC
---------- // ab da wir ID 1 auch super gelöscht aber 2 gar ned und der traced ja nicht mal den mc also den pfad
ID: 2
mc:
----------
ID: 2
mc:
----------
ID: 2
mc:
----------

mfg,
destroy90210

[atothek]

bei mir loofts einwandfrei ! beide werden gelöscht

PHP-Code:

MovieClip.prototype.fadeOut = function(ID, key) {
    var mc = this;
    mc["fadeout"+ID] = setInterval(function () {
        trace("ID: "+ID);
        trace("mc: "+mc);
        if (mc._alpha>0) {
            mc._alpha -= 5;
        } else {
            clearInterval(mc["fadeout"+ID]);
            trace("----------");
            k++;
            mc.removeMovieClip();
            gotoAndStop(key);
        }
        // hier updaten
    }, 20, key);
};
this.mcA.fadeOut(1, 3);
this.mcB.fadeOut(2, 3); 


vielleicht ist der pfad nicht richtig ??? ich würde dir auch dazu raten kein root mehr zu benutzen ist verdammt gefährlich meiner erfahrung nach!

[atothek]

und warum this nicht geht liegt an einer eigenart vom setInterval und hat mit dem scope zu tun um ein this verwenden zu können muß man das handlerObject mit übergeben das sähe dann so aus

PHP-Code:

this.interval=setInterval(this, "functionNameAlsString", 20, parameter); 


dann kann man auch ein this inerhalb der aufgerufenen methode verwenden

guckste hier

PHP-Code:

// public methode 
MovieClip.prototype.fadeOut = function(key) {
    this.interval = setInterval(this, "__internFadeOut", 20, key);
};
// interne private methode
MovieClip.prototype.__internFadeOut = function(key) {
    trace("mc: "+this);
    if (this._alpha>0) {
        this._alpha -= 5;
    } else {
        clearInterval(this.interval);
        trace("----------");
        k++;
        this.removeMovieClip();
        gotoAndStop(key);
    }
    updateAfterEvent();
};
this.mcA.fadeOut(3);
this.mcB.fadeOut(3);