setinterval() mehrmals zeitversetzt abspielen

[Till]

hi,
habe folgendes problem:
ich will diesen Script mehrmals nebeneinander wiederholen lassen, indem i durchgezählt wird:

PHP-Code:

i=0;
sy=1;
sx=1;

duplicateMovieClip("ring", "ring" add i, i);
//start
setProperty("ring" add i, _x, 512);
setProperty("ring" add i, _y, 0);
setProperty("ring" add i, _xscale, getProperty("ring" add i, _xscale)/sx);
setProperty("ring" add i, _yscale, getProperty("ring" add i, _yscale)/sy);
setProperty("ring" add i, _alpha, 0);

//tweening zur mitte
setInterval(function ()
{
    if (getProperty("ring" add i, _x)<512) {
        setProperty("ring" add i, _x, getProperty("ring" add i, _x)+20);
    }
    if (getProperty("ring" add i, _y)<384) {
        setProperty("ring" add i, _y, getProperty("ring" add i, _y)+20);
    }
    if (getProperty("ring" add i, _xscale)<1048) {
        setProperty("ring" add i, _xscale, getProperty("ring" add i, _xscale)+20);
        setProperty("ring" add i, _yscale, getProperty("ring" add i, _yscale)+20);
        setProperty("ring" add i, _alpha, getProperty("ring" add i, _alpha)+20);
    } else {
        removeMovieClip("ring" add i);
    }
}, 50); 


eine forschleife geht leider nicht.

die datei ist angehängt.

insgesamt soll dies nachher einen tunnel effekt darstellen...

wisst ihr eine gute alternative dazu?

danke und gruß, Till

[madflanderz]

mach doch lieber anstatt setInterval ein

_root.onEnterFrame = function () {
// dein code

}

ist für dein vorhaben viel besser. und setProperty is echt schon sehr veraltet und sollte nciht mehr benutzt werden. welche flash vwersion nutzt du denn?

mach es lieber so:
_root["ring" add i]._yscale = _root["ring" add i]._yscale)/sy;

[Till]

danke

ich verwende Flash MX.

bei onEnterFrame tut sich leider nix...
wie muss ich dies denn einbauen, bzw. wo und in welchem zusammenhang?

gruß,
Till

[Decrone]

Hier mal die kurz Version. Ist halt ein Ansatz:

i=0;
anzahl = 50;
sy=1;
sx=1;
function starten(){
    this.onEnterFrame = function() {
        if (i < anzahl) {
            duplicateMovieClip("ring", "ring"+i, i);
            this["ring"+i]._x = 512;
            this["ring"+i]._y = 0;
            this["ring"+i]._xscale /= sx;
            this["ring"+i]._yscale /= sy;
            this["ring"+i]._alpha = 0;
            this["ring"+i].rings();
            i++;
        }else{
            delete this.onEnterFrame;
        }
    }
}
MovieClip.prototype.rings = function(){
    this.onEnterFrame = function(){
        if (this._x<512) {
            this._x +=20;
        }
        if (this._y<384) {
            this._y += 20;
        }
        if (this._xscale<1048) {
            this._xscale += 20;
            this._yscale += 20;
            this._alpha += 20;
        } else {
            trace (this._name+" gelöscht");
            removeMovieClip(this);
        }
    }
}
starten(); 

bye

[Decrone]

und hier das ganze mit setInterval

i=0;
sy=1;
sx=1;
 
setInterval(function () {
            duplicateMovieClip("ring", "ring"+i, i);
            _root["ring"+i]._x = 512;
            _root["ring"+i]._y = 0;
            _root["ring"+i]._xscale /= sx;
            _root["ring"+i]._yscale /= sy;
            _root["ring"+i]._alpha = 0;
            _root["ring"+i].rings();
            i++;
}, 500);
MovieClip.prototype.rings = function(){
    this.onEnterFrame = function(){
        if (this._x<512) {
            this._x +=20;
        }
        if (this._y<384) {
            this._y += 20;
        }
        if (this._xscale<1048) {
            this._xscale += 20;
            this._yscale += 20;
            this._alpha += 20;
        } else {
            trace (this._name+" gelöscht");
            removeMovieClip(this);
        }
    }
} 

bye

[EDIT]
und außerdem solltest Du unter "Einstellungen für Veröffentlichungen" Dein Flashplayer auf 6 stellen, dann geht bei Dir auch die function "onEnterFrame", bzw. dann wird auch Flash MX-Code unterstützt!

[Till]

Hi Decrone,
vieeeelen dank! hat mir sehr weitergeholfen.

eigentlich ein klarer ansatz, bin aber echt nicht drauf gekommen.



Gruß, Till

[Decrone]

np...gern geschehen