Scrolltext ohne externen .txt

[dergerd]

Ich quäle mich gerade mit einem Script für einen Scrolltext in Flash 5.
Nachdem ich ein schönes Script für einen externen Text gefunden habe, muss ich es nun für einen internen Text ummodeln.
Im Script des Textfeldes ist folgende Zeile die das .txt-File läd:

this.loadVariables("text.txt");

was muss ich ändern wenn ich ein bestehendes Textobjekt aus dem Film scrollen will?

Habe schon rumprobiert, aber das Teil nicht zum Laufen gebracht.

Danke für die Hilfe

Claus

[fraggle two]

hi,

wie stellst du denn den internen text zu verfügung?

wenn die daten aus ner externen txt kommen stehen sie ja auch nur in einer variablen.

dann werden die daten über die variable in den textfeldern verteilt.

in deinem fall kannst du grundsätzlich folgendes machen.

eine variable für den text: textVariable="bla"

ein dynamisches textfeld erzeugen(auf der bühne aufziehen).
einen namen vergeben : meinTextfeld
eine variable zuweisen( im eigenschaftenfenster des textfeldes ---> variable):meineTextfeldVariable

1. Möglichkeit(flash mx):

meinTextfeld.text="bla"

2.Möglichkeit(flash mx):

meinTextfeld.text=textVariable

3.Möglichkeit(flash 5):

meineTextfeldVariable=textVariable

in allen 3 beispielen muß sich alles auf der hauptzeitleiste abspielen.

hoffe das hilft

gruß
mike

[dergerd]

Bin glaube ich etwas überfordert. Das Script das ich habe beinhaltet gleich die komplette Steuerung und dann noch die Länge des scrollbalkens. Da ich es für Flash 5 benötige kann ich den Balken aus MX leider nicht benutzen.

Ich habe das .fla mal angehängt dann ist mein Problem glaube ich einfacher zu erkennen. Der Text liiegt auf der Hauptbühne.

Gruß

Claus

[fraggle two]

hi,

hab dir den code mal modifiziert das er funzt(einfach copy and paste):

PHP-Code:

onClipEvent (load) {
    textVariable = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat. Ut wisi enim ad minim veniam, quis nostrud exerci tation ullamcorper suscipit lobortis nisl ut aliquip ex ea commodo consequat. Duis autem vel eum iriure dolor in hendrerit in vulputate velit esse molestie consequat, vel illum dolore eu feugiat nulla facilisis at vero et accumsan et iusto odio dignissim qui blandit praesent luptatum zzril delenit augue duis dolore te feugait nulla facilisi. Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed"; // da belegst du die variable "textVariable" mit deinem text
    daTextBox = textVariable;// hier weist du der variablen die mit dem textfeld verbunden ist den text deiner textVariable zu
    scrolling = 0;
    frameCounter = 1;
    speedFactor = 3;
    numLines = 7;
    origHeight = scrollbar._height;
    origX = scrollbar._x;
    needInit = true;// das muß auf true sein da der text sofort da ist und der scrollbar angepasst werden muß
    function initScrollbar() {
        var totalLines = numLines+daTextBox.maxscroll-1;
        scrollbar._yscale = 100*(numLines)/totalLines;
        deltaHeight = origHeight-scrollbar._height;
        lineHeight = deltaHeight/(daTextBox.maxScroll-1);
    }
    function updateScrollBarPos() {
        scrollbar._y = lineHeight*(daTextBox.scroll-1);
    }
}
onClipEvent (enterFrame) {
    if (needInit) {
        if (daTextBox.maxscroll>1) {
            initScrollbar();
            needInit = false;
        }
    }
    if (frameCounter%speedFactor == 0) {
        if (scrolling == "up" && daTextBox.scroll>1) {
            daTextBox.scroll--;
            updateScrollBarPos();
        } else if (scrolling == "down" && daTextBox.scroll<daTextBox.maxscroll) {
            daTextBox.scroll++;
            updateScrollBarPos();
        }
        frameCounter = 0;
    }
    frameCounter++;
}
onClipEvent (mouseDown) {
    if (up.hitTest(_root._xmouse, _root._ymouse)) {
        scrolling = "up";
        frameCounter = speedFactor;
        up.gotoAndStop(2);
    }
    if (down.hitTest(_root._xmouse, _root._ymouse)) {
        scrolling = "down";
        frameCounter = speedFactor;
        down.gotoAndStop(2);
    }
    if (scrollbar.hitTest(_root._xmouse, _root._ymouse)) {
        scrollbar.startDrag(0, origX, deltaHeight, origX);
        scrolling = "scrollbar";
    }
    updateAfterEvent();
}
onClipEvent (mouseUp) {
    scrolling = 0;
    up.gotoAndStop(1);
    down.gotoAndStop(1);
    stopDrag();
    updateAfterEvent();
}
onClipEvent (mouseMove) {
    if (scrolling == "scrollbar") {
        daTextBox.scroll = Math.round((scrollbar._y)/lineHeight+1);
    }
    updateAfterEvent();
}
onClipEvent (data) {
    needInit = true;
} 


viel spaß
mike

[dergerd]

schon mal vielen Dank, werde es ausprobieren.

Claus