Schweif hinter einem bewegten Objekt?

[Josef Müller]

Hi,

es geht um den Lichtpunkt in dem Oszillator auf der Seite:

www.modular-planet.de/_aspekte/oszillator.html

Der Lichtpunkt soll einen Schweif hinter sich herziehen. Das 'Mausschweifbeispiel' funktioniert hier anscheinend nicht. Der Lichtpunkt bewegt sich mit Hilfe einer x-/y-Positionierung und der Flashfilm besteht aus nur einem Bild. Ich habe schon Verschiedenes ausprobiert, aber den Schweif noch nicht hinbekommen :-((

[johanness]

Wie soll denn der Schweif aussehen? Der selbe 'MC' der langsam transperent wird?

[Josef Müller]

Ja, eigentlich mit duplicateMovieClip. Aber wenn ich eine Schleife konstruiere, passiert nicht viel...

Die Schleife sieht so aus:

if (i<10) {
duplicateMovieClip("Leuchtpunkt", Leuchtpunkt+i, i);
i++;
} else {
i = 0;
}

Die Schleife steht in einer - onClipEvent (enterFrame) {...} - Anweisung.

[johanness]

Zeig doch einfach mal deinen Ansatz!

[Josef Müller]

Mit duplicateMovieClip und der 'onClipEvent (enterFrame)'-Schleife (s.o.) sollte bei jedem Frame (hier 24/Sek) ein Duplikat erzeugt werden. Da sich der Leuchtpunkt bewegt, sollte er doch die Duplikate hinter sich herziehen... Das eben klappt aber nicht!

__________________

[leif]

Hab Dir mal was gebastelt... nicht zuletzt weil ich Oszillatoren mag. :-)
Angucken kannste das hier: www.khm.de/~leif/klimbim/glowchain.swf.

Das Listing ist hoffentlich recht durchschaubar und so angelegt, dass es wurscht ist, wie der MovieClip "point0" bewegt wird; die anderen folgen ihm dann. Deshalb auch Click&Drag als Bewegungsalternative. Damit das Listing läuft, brauchst Du noch irgendeinen GrafikClip in der Bibliothek, der als "point" für ActionScript verknüpft ist.

/*** PREFS ***/ 
_quality = "low";
screenwidth = screenheight = 600;
speed = 0.2;
tailSegs =60;
 
/*** INIT ***/
screenwidth_half = screenwidth/2;
screenheight_half = screenheight/2;
 
/*** FUNCTIONS ***/
startPoint = function () {
// ersten point erzeugen und lostreten
    attachMovie ("point", "point0", 1);
    point0.mamacount = 0;
    point0.onEnterFrame = moveMe;
}
 
moveMe = function () {
// point0 irgendwie bewegen
    this.mamacount+=speed;
    this._x = Math.sin (this.mamacount/25)*screenwidth_half+screenwidth_half;
    this._y = Math.cos (this.mamacount/9)*screenheight_half+screenheight_half;
// egal, wie Du point0 bewegst, diese beiden Zeilen sind notwendig und müssen 
// onEnterFrame ausgeführt werden, damit die anderen points folgen können!
    this.x_before = this._x;
    this.y_before = this._y;
}
 
startTail = function () {
// baut den Schweif und tritt ihn los
    var i = tailSegs; while (--i>0) {
        attachMovie ("point", "point" add i, 10+tailSegs-i);
        this["point" add i].id = i;
        this["point" add i]._alpha = 100-100/tailSegs*i;
        this["point" add i].onEnterFrame = followPoint;
    }
}
 
followPoint = function () {
// durch diese Funktion bewegt sich der Schweif: die "veralteten" Koordinaten werden von Clip zu Clip durchgereicht
    this.x_before = this._x;
    this.y_before = this._y;
    var parentClip = _root["point" add (this.id-1)];
    this._x= parentClip.x_before;
    this._y= parentClip.y_before;
}
 
dragMe = function () {
// Notwendige Datenerzeugung bei Dragging von point0
    this.x_before = this._x+random(6)-3;
    this.y_before = this._y+random(6)-3;;
}
 
/*** MOUSELISTENER ***/
mouseInput = {};
mouseInput.onMouseDown = function () {
    point0.startDrag(true);
    point0.onEnterFrame = dragMe;
}
mouseInput.onMouseUp = function () {
    point0.stopDrag();
    point0.onEnterFrame = moveMe;
}
 
/*** PROGRAM ***/
Mouse.addListener(mouseInput);
startPoint();
startTail();
stop(); 

[cyberboy]

Bei den Script wird beim Start in der oberen Ecke nochmal das Objekt erzeugt...wie geht das weg? So dass also nur noch der eigentliche Effekt zu sehen ist...
habda eben schon rumprobiert, aber hat nicht geklappt...

[leif]

Ok, dafür braucht's noch ne Detailänderung. Beispiel wie gehabt auf www.khm.de/~leif/klimbim/glowchain.swf.

Listing:

/*** PREFS ***/ 
_quality = "low";
screenwidth = screenheight = 600;
speed = 0.2;
tailSegs = 60;
 
/*** INIT ***/
screenwidth_half = screenwidth/2;
screenheight_half = screenheight/2;
 
/*** FUNCTIONS ***/
startPoint = function () {
    attachMovie ("point", "point0", 1);
    point0.mamacount = 0;
    point0.x_before = point0._x = Math.sin (0)*screenwidth_half+screenwidth_half;
    point0.y_before = point0._y = Math.cos (0)*screenheight_half+screenheight_half;
    point0.onEnterFrame = moveMe;
    
}
 
moveMe = function () {
    this.mamacount+=speed;
    this._x = Math.sin (this.mamacount/25)*screenwidth_half+screenwidth_half;
    this._y = Math.cos (this.mamacount/9)*screenheight_half+screenheight_half;
    this.x_before = this._x;
    this.y_before = this._y;
}
 
dragMe = function () {
    this.x_before = this._x+random(6)-3;
    this.y_before = this._y+random(6)-3;;
}
 
startTail = function () {
    var i = tailSegs; while (--i>0) {
        attachMovie ("point", "point" add i, 10+tailSegs-i);
        var tmpClip = this["point" add i];
        tmpClip.id = i;
        tmpClip._alpha = 100-100/tailSegs*i;
        tmpClip._x= tmpClip._x_before = _root.point0._x
        tmpClip._y= tmpClip._y_before = _root.point0._y
        tmpClip.onEnterFrame = followPoint;
    
    }
}
 
followPoint = function () {
    this.x_before = this._x;
    this.y_before = this._y;
    var parentClip = _root["point" add (this.id-1)];
    this._x= parentClip.x_before;
    this._y= parentClip.y_before;
}
 
mouseInput = {};
mouseInput.onMouseDown = function () {
    point0.startDrag(true);
    point0.onEnterFrame = dragMe;
}
mouseInput.onMouseUp = function () {
    point0.stopDrag();
    point0.onEnterFrame = moveMe;
}
 
/*** PROGRAM ***/
Mouse.addListener(mouseInput);
startPoint();
startTail();
stop(); 

[cyberboy]

Super!!! Danke ;-)

[Josef Müller]

Hallo leif,

> Hab Dir mal was gebastelt...
>nicht zuletzt weil ich Oszillatoren mag. :-)

:-)))

danke für das Script, es funktioniert! Zwei Probleme gibt es allerdings noch: Ich kann den Schweif nicht hinter einer Maske ablaufen lassen und bei den Schwingungsformen Saw und Pulse macht er die Sprünge nicht mit. Letzteres werde ich wohl beheben können, indem ich aus den Sprüngen Bewegungen mache (mal sehn...). Aber der Schweif legt sich immer vor die Maske... :-((

PS
Bei mir dauert die Umsetzung noch etwas: Ich bin erst seit einigen Monaten mit Flash zugange und 'Der Oszillator' ist meine erste Animation mit Action Script...
Deinen Studiengang finde ich übrigens sehr interessant!

[leif]

Hallo Josef,

um das Scriptergebnis zu maskieren, musst Du es noch in einen weiteren Clip verschachteln. Dann kannst Du mit dem Befehl "movieClip.setMask(maskenClip);" einen Clip ausmaskieren. Beispiel: www.khm.de/~leif/klimbim/glowchain_masked.swf.

Wenn Du auf der Bühne einen Clip mit dem Instanznamen "myMask" anlegst, braucht das Script nur minimale Modifizierung:

/*** PREFS ***/ 
_quality = "low";
screenwidth = screenheight = 600;
speed = 0.2;
tailSegs = 60;
containerLayer = 1;
 
/*** INIT ***/
screenwidth_half = screenwidth/2;
screenheight_half = screenheight/2;
 
/*** FUNCTIONS ***/
startPoint = function () {
    createEmptyMovieClip("myContainer", containerLayer);
    var p = myContainer.attachMovie ("point", "point0", 1);
    p.mamacount = 0;
    p.x_before = p._x = Math.sin (0)*screenwidth_half+screenwidth_half;
    p.y_before = p._y = Math.cos (0)*screenheight_half+screenheight_half;
    p.onEnterFrame = moveMe;
    myContainer.setMask(myMask);
    
}
 
moveMe = function () {
    this.mamacount+=speed;
    this._x = Math.sin (this.mamacount/25)*screenwidth_half+screenwidth_half;
    this._y = Math.cos (this.mamacount/9)*screenheight_half+screenheight_half;
    this.x_before = this._x;
    this.y_before = this._y;
}
 
dragMe = function () {
    this.x_before = this._x+random(6)-3;
    this.y_before = this._y+random(6)-3;;
}
 
startTail = function () {
    var i = tailSegs; while (--i>0) {
        var tmpClip = myContainer.attachMovie ("point", "point" add i, 10+tailSegs-i);
        tmpClip.id = i;
        tmpClip._alpha = 100-100/tailSegs*i;
        tmpClip._x= tmpClip._x_before = myContainer.point0._x
        tmpClip._y= tmpClip._y_before = myContainer.point0._y
        tmpClip.onEnterFrame = followPoint;
    }
}
 
followPoint = function () {
    this.x_before = this._x;
    this.y_before = this._y;
    var parentClip = myContainer["point" add (this.id-1)];
    this._x= parentClip.x_before;
    this._y= parentClip.y_before;
}
 
mouseInput = {};
mouseInput.onMouseDown = function () {
    myContainer.point0.startDrag(true);
    myContainer.point0.onEnterFrame = dragMe;
}
mouseInput.onMouseUp = function () {
    myContainer.point0.stopDrag();
    myContainer.point0.onEnterFrame = moveMe;
}
 
/*** PROGRAM ***/
Mouse.addListener(mouseInput);
startPoint();
startTail();
stop(); 

PS: Den Studiengang kann ich soweit auch nur empfehlen... dafür find ich Deinen Ansatz mit dem Oszillator sehr interessant! :-)

[Josef Müller]

Hallo Leif,

der Schweif ist hinter der Maske!!! :-))

Aber eine letzte Frage habe ich noch...
Welche Farbe bzw. Farbnummer verwendest du bei dem MovieClip in dem Script oben?

Die Sprünge bei den Schwingungsformen Saw und Pulse krieg ich doch nicht weg, jedenfalls nicht mit dem bisherigen ActionScript-Ansatz. Die Sprünge werde zuerst einmal so lassen...
Wenn ich noch einige Kleinigkeiten geändert habe, uploade ich die (vorläufig letzte) Version.

PS:
>Den Studiengang kann ich soweit auch nur empfehlen
Leider bin ich (zumindest künstlerisch) kein besonders kreativer Mensch :-(

[bobweb]

Hallo Leif!

Schöner Effekt!
Auch auf die Gefahr hin, mich nun als Vollblut-Anfänger zu outen, hab ich da doch mal eine Frage: Wo muss man das Script denn einsetzen, damit das funktioniert? Ich hab die beiden Symbole erstellt (point0 und point) und das Skript auf einer eigenen Ebene in den ersten Frame der Szene gelegt, sowie point0 in eine Ebene gesetzt, aber da passiert leider gar nichts, wenn ich den Film teste. Ich hab auch noch ein paar andere Varianten ausprobiert ohne Ergebnis (abgesehen von einigen Fehlermeldungen...)

Könntest Du evtl. die .fla-Datei hier posten, das wär super!

Vielen Dank und schönen Gruß!

[23012]

Hallo @ bobweb,
falls Leif dies nicht liest, ein Tip von mir. Den MC point erstellen,
dannin der Bibliothek mit der rechten Maustaste draufklicken
und unter Eigenschaften > Export für Actionscript anhaken,
dort auch den Bezeichner "point" geben, dann sollte es klappen.
Gruss
23012

[bobweb]

Danke, nun funktioniert es! Im Rechtsklickmenü steht ja dann auch das mit der Verknüpfung... Tja, ich hab da wohl doch noch ein paar grundlegende Sachen zu lernen...