schriftgröße ändern

[andretti]

wie kann ich, da jungunternehmer ein sehr langes wort ist, die schriftgröße via parameter ändern?
irgendwie schaff ich es nicht

PHP-Code:

MovieClip.prototype.link = function(pagename, fontSize) {
    this.T_linkname.background = true;
    this.T_linkname._height = "20";
    this.T_linkname.text = pagename;
    this.T_linkname.backgroundColor = "0xFFFFFF";
    this.T_linkname.textColor = "0xFF3300";
    this.T_linkname.textHeight=[fontSize];
    this.onRollOver = function() {
        this.T_linkname.backgroundColor = "0xCCFF99";
    };
    this.onRollOut = function() {
        this.T_linkname.textColor = "0xFF3300";
        this.T_linkname.backgroundColor = "0xFFFFFF";
    };
    this.onPress = function() {
        this.T_linkname.textColor = "0xFF3300";
        this.T_linkname.backgroundColor = "0xC0C0C0";
        getURL(pagename+".htm", "_self");
        //gotoAndPlay(3); 
    };
};
MC_home.link("Home",11);
MC_kanzlei.link("Kanzlei",11);
MC_aktuell.link("Aktuell",11);
MC_service.link("Service",11);
MC_jung.link("Jungunternehmer",9);
MC_formulare.link("Formulare",11);
MC_newsletter.link("Newsletter",11);
MC_kontakt.link("Kontakt",11); 


[echo5-7]

versuchs mal über das textformat objekt.

[andretti]

wie meinen?

versteh nicht ganz was ich nun machen soll, sorry

[thebiz]

Hi.

Mit textHeight kann man die Höhe nur auslesen,
aber nicht setzen.
Hier ein Beispiel:

//------------------------------- ohne formatzuweisung ---
_root.createTextField("mein_txt", 1, 100, 100, 0, 0);
_root.mein_txt.autoSize = true;
_root.mein_txt.text = "geht doch";
trace(_root.mein_txt.textHeight); // nur zum auslesen der texthöhe. nicht zum setzen der höhe
//------------------------------- mit formatzuweisung ----
meinF = new TextFormat(); // über neues textformat können neue eigenschaften zugewiesen werden
meinF.size = 30;
_root.mein_txt.setTextFormat(meinF);
trace(_root.mein_txt.textHeight); 

[andretti]

oki, danke, das habe ich nun verstanden;
aber wie kann ich das bei meinem prototype anwenden?

[TigerFox]

Hallo,

Probiers mal so

PHP-Code:

 MovieClip.prototype.link = function(pagename, fontSize) {
//mit dem TextFormat-Object kannst du einige Parameter für Textfelder setzen: zB:size
    var myTF=new TextFormat();
    myTF.size=fontSize;
    //
    this.T_linkname.background = true;
    this.T_linkname._height = "20"; //was willst du hier machen -> denk dran, dass "20" sein String ist, du veränderst hier die Höhe des Textfeldes auf 20, willst du das?
    this.T_linkname.text = pagename;
    this.T_linkname.backgroundColor = "0xFFFFFF";
    this.T_linkname.textColor = "0xFF3300";
   //!!!!  hier weist du dann dem Textfeld dein TextFormat zu !!!!
    this.T_linkname.setTextFormat(myTF);
    this.onRollOver = function() {
        this.T_linkname.backgroundColor = "0xCCFF99";
    };
    this.onRollOut = function() {
        this.T_linkname.textColor = "0xFF3300";
        this.T_linkname.backgroundColor = "0xFFFFFF";
    };
    this.onPress = function() {
        this.T_linkname.textColor = "0xFF3300";
        this.T_linkname.backgroundColor = "0xC0C0C0";
        getURL(pagename+".htm", "_self");
        //gotoAndPlay(3);
    };
};
MC_home.link("Home",11);
MC_kanzlei.link("Kanzlei",11);
MC_aktuell.link("Aktuell",11);
MC_service.link("Service",11);
MC_jung.link("Jungunternehmer",9);
MC_formulare.link("Formulare",11);
MC_newsletter.link("Newsletter",11);
MC_kontakt.link("Kontakt",11); 


Schau dir in der Hilfe die TextFormat-functions an, damit bekommt man sehr viel Möglichkeiten!

lg TF

[andretti]

wow, das nenn ich mal eine erklärung!

thx!