Punkt auf Kugel-Oberfläche

[Alphanimal]

Hallo!
Ich möchte per AS den Effekt erzielen, dass sich eine Kugel dreht, in alle Richtungen.
Dazu möchte ich einige Punkte auf der Oberfläche bewegen lassen.
Das Aufteilen dieser Punkte, dass sie an der Oberfläche sind, hab ich schon geschafft.

Ich habe jetzt x,y,z Koordinaten.
Angezeigt werden natürlich nur x und y (_y=y und _x=x).
Jetzt muss ich diese Punkte um eine Achse drehen, die nur in der XY Ebene liegt.
Das ist der Punkt an dem ich nicht weiter komme.
Ich habe schon Erfahrung in der Erstellung von 3D-Systemen, aber bis jetzt hab ich immer nur in einer der Grund-Achsen gedreht...

Kurz gesagt: Wie drehe ich einen Punkt(X,Y,Z) um eine Achse in der XY-Ebene?

danke! mfg

[hgseib]

x = r sin a cos b
y = r sin a sin b
z = r cos a

wenn du genau in z richtung siehst, dann siehst du z nicht ;-)

[Alphanimal]

sorry, das ist nicht so ganz was ich wollte...
hab jetzt statt zufälliger position einen zufälligen winkel genommen, und deine formel eingebaut...

die punkte sind jetzt irgendwie parabelförmig angeordnet...

ich habs vorher schon gehabt, mit einen code aus einem 3D beispiel
Hier!

das problem war, das der radius immer kleiner geworden ist, also hab ich einfach auf 50 normalisiert

is aber eine unschöne lösung... ich versuchs nochmal mit deiner formel... vl. liegts an was anderem

danke!!

[Alphanimal]

so...
hab deinen code nochmal in ein neues, schönes file eingebaut...

funktioniert nicht so ganz...
irgend eine idee?

hier noch der code für die die zu faul sind sich das runterzuladen

r = 50; //Radius
n = 50; //Anzahl
//Punkte erstellen
for(i=0;i<n;i++){
this.attachMovie("punkt","p"+i,i);
p = this["p"+i];
//Zufällige Winkel festlegen
p.ax = Math.random()*2*Math.PI;
p.ay = Math.random()*2*Math.PI;
}
this.onEnterFrame = function(){
ax = _xmouse/200;
ay = _ymouse/200;
for(i=0;i<n;i++){
p = this["p"+i];
//Position berechnen
sinx = Math.sin(p.ax+ax);
siny = Math.sin(p.ay+ay);
cosx = Math.cos(p.ax+ax);
cosy = Math.cos(p.ay+ay);
p.x = r*sinx*cosy;
p.y = r*sinx*siny;
p.z = r*cosx;
 
p._x = p.x;
p._y = p.y;
p._alpha = (p.z>0)? 100:30;
}
} 

[Alphanimal]

Wow... es funktioniert!
Dadurch dass ich jetzt für euch eine neue .fla angelegt hab, hab ich das ganze etwas sauberer gemacht.

Jetzt hab ich nochmal den Code von meinem 3D-Beispiel verwendet, und jetzt geht er. Weiss nicht warum er vorher nicht so ganz funktioniert hat...
Da sieht man wieder wie wichtig Ordnung ist.

Hier die Formel:

tz = p.z * cosy - p.x * siny;
p.x = p.z * siny + p.x * cosy;
p.z = p.y * sinx + tz * cosx;
p.y = p.y * cosx - tz * sinx; 

So werden aber blöderweise die Ausgangskoordinaten überschrieben.

Ich kann es jetzt anwenden aber verstehen tue ich es noch immer nicht

Ich kann auch nur inkrementell drehen.
Darum auch das "pmx" und "pmy" in meinem neuen Code:

r = 50; //Radius
n = 150; //Anzahl
focus = 250; //Focus-Abstand für Perspektive
//Punkte erstellen
for(i=0;i<n;i++){
this.attachMovie("punkt","p"+i,i);
p = this["p"+i];
 
//Zufällige Position festlegen
p.x = random(2*r)-r;
p.y = random(2*r)-r;
p.z = random(2*r)-r;
//Normalisieren (Radius bestimmen)
pa = Math.sqrt(p.x*p.x+p.y*p.y+p.z*p.z);
p.x = p.x/pa*r;
p.y = p.y/pa*r;
p.z = p.z/pa*r;
}
//Maus-Position im vorigen Frame
pmx = _parent._xmouse;
pmy = _parent._ymouse;
 
this.onEnterFrame = function(){
//mouse-pm: Um wieviel wurde die Maus bewegt
ay = (_parent._xmouse-pmx)*Math.PI/r/2;
ax = -(_parent._ymouse-pmy)*Math.PI/r/2;
pmx = _parent._xmouse;
pmy = _parent._ymouse;
for(i=0;i<n;i++){
p = this["p"+i];
//Position berechnen
sinx = Math.sin(ax);
siny = Math.sin(ay);
cosx = Math.cos(ax);
cosy = Math.cos(ay);
 
tz = p.z * cosy - p.x * siny;
p.x = p.z * siny + p.x * cosy;
p.z = p.y * sinx + tz * cosx;
p.y = p.y * cosx - tz * sinx;
 
scale = (p.z+focus)/focus;
p._x = p.x*scale;
p._y = p.y*scale;
p._xscale = p._yscale = scale*100;
p._alpha = (p.z>0)? 100:30;
}
} 

Hier brauche ich außerdem noch eine zufällige AnfangsPOSITION, nicht den Winkel. Hab ich hier mit zufälligen, normalisierten XYZ-Koordinaten gemacht.
Hab auch noch Perspektive hinzugefügt.

Der Effekt sieht ganz gut aus, und es ist auch nicht sehr Ressourcen-raubend!
Mit 150 Partikeln ist meine CPU nur zur hälfte ausgelastet.

Vl. kann das noch der eine oder andere brauchen!

Jetzt hab ich diesen Thread eigentlich fast alleine geschrieben *g*
aber wenn ich nicht gepostet hätte hätte ich es wahrscheinlich aufgegeben.

Danke hgseib für deinen Ansatz!
mfg

[hgseib]

"..und deine formel eingebaut.."
das ist nicht MEINE formel. sondern DIE formel, zum berechnen einer kugelkoordinate ;-)
z.b.

r = 50;
n = 50;
speed = 2;
for (i=0; i<n; i++) {
    p = this.attachMovie("punkt", "p"+i, i);
    p.ax = Math.random()*2*Math.PI;
    p.ay = Math.random()*2*Math.PI;
    p.rs = r*Math.sin(p.ax);
    p._y = r*Math.cos(p.ax);
}
this.onEnterFrame = function() {
    w = Math.atan2(_ymouse, _xmouse);
    this._rotation += w*speed;
    for (i=0; i<n; i++) {
        p = this["p"+i];
        p._x = p.rs*Math.cos(p.ay+w);
        p._z = p.rs*Math.sin(p.ay+w);
        p._alpha = (p._z>0) ? 100 : 30;
    }
}; 

-----
da komm ich wohl zu spät ;-)

[Alphanimal]

Das sieht schon besser aus!
Aber ist auch nicht das was ich eigentlich wollte.
und das Ganze mit _rotation ist auch etwas schwammig.
du rotierst nur um eine Achse, bzw. um Y und Z (Z eben per _rotation)

ich bleibe bei der Variante die ich leider selbst nicht verstehe, sieht "räumlicher" aus.
Und ich kann sie dafür verwenden, wofür ich das eigentlich gebraucht habe:
schau mal im Anhang, sieht geil aus!