Probleme mit Variablen-scope in einer Klasse

[PyroMarkus]

Hallo zusammen,

ich stehe vor einem neuen "fundamentalen" Problem. Anbei der Beispielcode meiner Klasse "Shape":

1.) Im AS des entsprechenden Bildes laufe ich über ein Array und instanziere für jedes Element des Arrays ein Objekt der Klasse Shape und übergebe dabei ein paar Werte, die sich jedes Objekt in seinen Member-Variablen merken soll.

2.) Nach dem Instanziieren rufe ich für jedes Objekt die draw()-Methode meiner Klasse auf, in der das übergebende MovieClip (z.B. ein Kreis) dupliziert und die Kopie auf einem höheren Level positioniert wird:

class anni.Shape {
    static var aant;
    static var azuw;
    static var avol;
        
    static var level = 0;   
        
    var monat;
    var jahr;
    var praeparat;
    var mktant;
    var mktvol;
    var mktzuw;
    var code;
    var gebiet;
    
    function Shape( monat, jahr, praeparat, mktant, mktvol, mktzuw, code, gebiet ) {
        this.monat = monat;
        this.jahr = jahr;
        this.praeparat = praeparat;
        this.mktant = mktant;
        this.mktvol = mktvol;
        this.mktzuw = mktzuw;
        this.code = code;
        this.gebiet = gebiet;
 
    }
    
    function draw( basisFigur_mc ) {
 
        // Annahmen zur Berechnung
                var w = 300;
        var h = 300;
    
    // neues Level
                level++;
        
        // duplicate
        var f_mc = basisFigur_mc.duplicateMovieClip("f_mc"+level, level);
 
                // hier positioniere ich die Kopien wild rum
        f_mc._x = (w/2) + ((mktant/aant - 1) * (w/2) * (2/3));
        f_mc._y = (h/2) - ((mktzuw/azuw - 1) * (h/2) * (2/3));
        f_mc._width = mktvol/avol * (((w+h)/2)/10);
        f_mc._height = mktvol/avol  * (((w+h)/2)/10);
 
        _root["f_mc"+level]._visible = true;
        
        _root["f_mc"+level].onRollOver = function() {
            trace("inst: "+this+" | x: "+f_mc._x+" | y: "+_mc._y+" | code: "+this.code+" | gebiet: "+this.gebiet);
        }
    }
} 

Und jetzt zum Problem:
Ich hab's anscheinend nicht verstanden, wie ich die erzeugten Instanzen jetzt anspreche. Mit root["f_mc"+level] kann ich zwar einen Eventhandler an die Instanzen packen und mit f_mc kann ich _x und _y Eigenschaften tracen. Aber an meine Member code und gebiet komme ich partut nicht dran und erhalte immer ein undefined. Egal ob ich es mit this, f_mc, root["f_mc"+level], _level10.f_mc01 oder sonstwas versuche. Ich habe kein gültiges Handle auf die Instanzen in der Hand.

Was mache ich falsch, wo liegt mein Problem bitte?
Kann evtl. jemand mit einsteigen und helfen?

Lieben Dank
Pyro

[bokel]

Der MovieClip und die Instanz deiner Klasse sind völlig unabhängig voneinander. Wenn du vom einen auf das andere zugreifen möchtest, musst du jeweils eine Referenz auf das Ziel anlegen.

mfg r.

[PyroMarkus]

Besten Dank für den Input.

Nur leider komme ich mit der Info nicht ganz weiter - hast Du evtl. ein Beispiel für mich?

Besten Dank,
Pyro

[bokel]

Dein Script sähe dann z.B. so aus:

function draw( basisFigur_mc ) {
 
        // Annahmen zur Berechnung
        var w = 300;
        var h = 300;
    
    // neues Level
        level++;
        
        // duplicate
        var f_mc = basisFigur_mc.duplicateMovieClip("f_mc"+level, level);
 
                // hier positioniere ich die Kopien wild rum
        f_mc._x = (w/2) + ((mktant/aant  - 1) * (w/2) * (2/3));
        f_mc._y = (h/2) - ((mktzuw/azuw - 1) * (h/2) * (2/3));
        f_mc._width = mktvol/avol * (((w+h)/2)/10);
        f_mc._height = mktvol/avol  * (((w+h)/2)/10);
 
        f_mc._visible = true;
 
        // referenz auf instanz in mc speichern
        f_mc.inst = this;
 
        f_mc.onRollOver = function() {
            trace("inst: "+this.inst+" | x: "+this._x+" | y: "+this._y+" | code: "+this.inst.code+" | gebiet: "+this.inst.gebiet);
        }
    } 

mfg r.

[PyroMarkus]

Der Hammer - funktioniert!

Das

f_mc.inst = this; 

kannte ich noch nicht - herzlichen Dank, hat sehr geholfen!

Grüße
Pyro

[PyroMarkus]

Hallo,

ich habe ein neues Problem, was ganz gut zum o.G. passt:

import anni.Container;
 
class anni.SelectionContainer extends Container {
    
    var instName;
        
    function SelectionContainer() {
        // super();
        this.instName = this._name;
        trace(this.instName);
        init();
    }
    
    function init() {
                 ...
    }
} 

Hintergrund: Die Klasse Container extends MovieClip.
Frage: Warum kann ich mit this._name nicht auf die Eigenshaften des MovieClips zugreifen? Ich bekomme in der Syntax immer ein undefined im trace.
In der Basisklasse Container kann über diese Syntax auf die Eigenschaften zugegriffen werden, allerdings nur im Konstruktor - danach ist die Membervariable wieder undefined.

Besten Dank im voraus!