Problem mit onPress und for-schleife

[xXx_Magic_xXx]

Hallo Gemeinde

Ich habe folgenden Code:

PHP-Code:

for (var i:Number = 0; i<n; i++) {
        _root.inhalt_mc.inhalt_referenzen.createEmptyMovieClip("mc"+i, _root.inhalt_mc.inhalt_referenzen.getNextHighestDepth()); 
        _root.inhalt_mc.inhalt_referenzen["mc"+i].createTextField("textfeld", this.getNextHighestDepth(), 0, text_y, 200, 20);
        _root.inhalt_mc.inhalt_referenzen["mc"+i].textfeld.text = nme[i];
        ["mc"+i].textfeld.text);
        _root.inhalt_mc.inhalt_referenzen["mc"+i].textfeld.setTextFormat(format_ref_liste);
        _root.inhalt_mc.inhalt_referenzen["mc"+i].textfeld.selectable = false; 
        
        text_y+=17;
        
        _root.inhalt_mc.inhalt_referenzen["mc"+i].onRollOver = function() {
            this.textfeld.setNewTextFormat(format_ref_liste_over);
            this.textfeld.text = this.textfeld.text;
        }
        _root.inhalt_mc.inhalt_referenzen["mc"+i].onRollOut = function() {
            this.textfeld.setNewTextFormat(format_ref_liste);
            this.textfeld.text = this.textfeld.text;
        }
        //
        //Hier wirds spannend
        //
        _root.inhalt_mc.inhalt_referenzen["mc"+i].onPress = function() {
            var anzeige = src[i];
            trace(anzeige);
        }
    } 


Beim Drücken einer der Buttons wird allerding undefined ausgegeben obwohl src[0], src[1], usw. definiert ist. Wo liegt mein Fehler

MfG Magic

[readme.txt]

trace dir mal "i" aus ... dann wirst du von selbst auf den Fehler kommen.

[xXx_Magic_xXx]

Naja ist mir auch schon aufgefallen aber wenn "i" die richtige zahl wäre würds ned gehen es würd Source3, Source3, Source3 ausgeben statt Source1, Source2, Source3

EDIT: "i" wurde jetzt als globale-Variabel definiert und bei diesem Script:

PHP-Code:

_root.inhalt_mc.inhalt_referenzen["mc"+i].onPress = function() {
            trace(i);
            var anzeige = src[i];
            trace(anzeige);
        } 


erhalte ich folgende ausgabe:
3
undefined

i ist eins zu hoch aber mal abgesehen davon wie ichs jetzt habe erreiche ich mein Ziel ned. Ich will das jeder MovieClip names mc1, mc2, ... die verlinkung auf die jeweilige source hat also mc1 -> source:1 mc2 => source:2 usw. wie krieg ich das hin?

[readme.txt]

du kannst i so nicht nutzen. Nachdem eine for-Schleife durchgelaufen ist hat i immer den letzten Wert der gesetzt wurde, in deinem Fall scheinbar 3.

Wenn du nun diese i in einem onPress nutzt wird dort auch immer der letzte für i gestzte Wert genutzt.

Du musst deine MovieClips dazu bringen sie den i-Wert zu merken:
(btw.: Sowas wie "_root.inhalt_mc.inhalt_referenzen["mc"+i]" würde ich mir in einer Variablen speichern, damit sparst du dir jede Menge tipparbeit.

PHP-Code:

for (var i:Number = 0; i<n; i++) { 
  // ...
  var mc = _root.inhalt_mc.inhalt_referenzen["mc"+i]

  mc.i = i;

  mc.onPress = function() { 
    trace(this.i);
    trace(src[this.i]);
  }
  // ...
} 


[xXx_Magic_xXx]

Danke so wirds funktionieren.

Hm ne irgendwas an der variabel ist flasch wenn ich die variabel benutze so wie dus geschrieben hast, dann werden mir die movieclips ned mehr erstellt.

[readme.txt]

wie? das geht nicht?

PHP-Code:

var mc = _root.inhalt_mc.inhalt_referenzen.createEmptyMovieClip("mc"+i, _root.inhalt_mc.inhalt_referenzen.getNextHighestDepth());

mc.i = i;

mc.onPress = function() {
  trace(this.i);
} 


[xXx_Magic_xXx]

Also du hast da jetzt ein ducheinander mit den variabeln(Du hast zwei verschiedene vars gepostet). Ich habe jetzt folgenden code und damit werden die Moviceclips nicht mehr erstellt:

PHP-Code:

function referenzenliste(anzahl) {
    var n:Number = anzahl; 
    var text_y:Number = 20;
    var mc = _root.inhalt_mc.inhalt_referenzen["mc"+i];
    var format_ref_liste:TextFormat = new TextFormat();
    format_ref_liste.font = "Verdana";
    format_ref_liste.size = 11;
    format_ref_liste.color = 0x000000;
    var format_ref_liste_over:TextFormat = new TextFormat();
    format_ref_liste_over.font = "Verdana";
    format_ref_liste_over.size = 11;
    format_ref_liste_over.color = 0x0084ff;
    _global.i = 0;
    for (i:Number = 0; i<n; i++) {
        mc.i = i;
        _root.inhalt_mc.inhalt_referenzen.createEmptyMovieClip("mc"+i, _root.inhalt_mc.inhalt_referenzen.getNextHighestDepth()); 
        mc.createTextField("textfeld", this.getNextHighestDepth(), 0, text_y, 200, 20);
        mc.textfeld.text = nme[i];
        //trace(mc.textfeld.text);
        mc.textfeld.setTextFormat(format_ref_liste);
        mc.textfeld.selectable = false; 
        //trace(text_y);
        text_y+=17;
        //onpress etc
        mc.onRollOver = function() {
            this.textfeld.setNewTextFormat(format_ref_liste_over);
            this.textfeld.text = this.textfeld.text;
        }
        mc.onRollOut = function() {
            this.textfeld.setNewTextFormat(format_ref_liste);
            this.textfeld.text = this.textfeld.text;
        }
        mc.onPress = function() {
            trace(this.i); 
            trace(src[this.i]);
        }
    }
} 


[readme.txt]

naja, ich poste dir ja keine copy&paste lösungen, ich geb nur Hinweise ... auf dein Script übertragen musst du das schon selbst, und da gehört auch ein bisschen Nachdenken mit dazu ... was du da gemacht hast ist halt falsch (da hätte man aber auch selbst drauf kommen können).

PHP-Code:

function referenzenliste(anzahl) {
    var n:Number = anzahl; 
    var text_y:Number = 20;
    var format_ref_liste:TextFormat = new TextFormat();
    format_ref_liste.font = "Verdana";
    format_ref_liste.size = 11;
    format_ref_liste.color = 0x000000;
    var format_ref_liste_over:TextFormat = new TextFormat();
    format_ref_liste_over.font = "Verdana";
    format_ref_liste_over.size = 11;
    format_ref_liste_over.color = 0x0084ff;
    _global.i = 0;
    for (i:Number = 0; i<n; i++) {
        var mc = _root.inhalt_mc.inhalt_referenzen.createEmptyMovieClip("mc"+i, _root.inhalt_mc.inhalt_referenzen.getNextHighestDepth()); 
        mc.createTextField("textfeld", this.getNextHighestDepth(), 0, text_y, 200, 20);
        mc.textfeld.text = nme[i];
        //trace(mc.textfeld.text);
        mc.textfeld.setTextFormat(format_ref_liste);
        mc.textfeld.selectable = false; 
        //trace(text_y);
        text_y+=17;
        //onpress etc

        mc.i = i;

        mc.onRollOver = function() {
            this.textfeld.setNewTextFormat(format_ref_liste_over);
            this.textfeld.text = this.textfeld.text;
        }
        mc.onRollOut = function() {
            this.textfeld.setNewTextFormat(format_ref_liste);
            this.textfeld.text = this.textfeld.text;
        }
        mc.onPress = function() {
            trace(this.i); 
            trace(src[this.i]);
        }
    }
}