problem mit dynamischem yugop-slider

[Trumpfass]

hi,

ich habe ein problem mit meinem dyamischem yugop-slider. das ding läd brav bilder aus einem verzeichnis in sich rein und slided auch schön und so, aber bei click auf ein bild, läd er immer nur das letzte. egal auf welchen button ich klicke.

der code des sliders sieht so aus:

onClipEvent (load) {
	pfad_klein = "screens_klein/";
	pfad_gross = "screens_gross/";
	template._visible = 0;
	button_count = _root.anzahl;
	button_width = template._width;
	menu_width = button_width*button_count;
	half_stage_width = Stage.width/2;
	function create_buttons() {
		for (i=0; i<button_count; i++) {
			new_button = "button"+i;
			template.duplicateMovieClip(new_button, i);
			this[new_button]._x = (this[new_button]._x+button_width*i)-half_stage_width;
			filename = i+'.jpg';
			this[new_button].pics.loadMovie(pfad_klein+filename, 0);
			this[new_button].button.onPress = function() {
				getURL(pfad_gross+filename, "_blank");
			};
		}
	}
	create_buttons();
}
onClipEvent (enterFrame) {
	speed = -_xmouse/15;
	for (i=0; i<button_count; i++) {
		cur_button = "button"+i;
		this[cur_button]._x = this[cur_button]._x+speed;
		if (this[cur_button]._x>half_stage_width+100) {
			this[cur_button]._x = this[cur_button]._x-menu_width;
		} else if (this[cur_button]._x<-half_stage_width-100) {
			this[cur_button]._x = this[cur_button]._x+menu_width;
		}
	}
}

tja, und dieser part funzt nicht:

this[new_button].button.onPress = function() {
				getURL(pfad_gross+filename, "_blank");
			};

meine anzahl (also der button_count) ist momentan 16 pics lang und bei jedem klick ruft er das bild 15.jpg auf...any hints?

aufgebaut ist mein template so:
auf der hauptbühne liegt der movieclip yugop_slider darin der mc_template (der wird immer dupliziert) darin der button und hinter dem button der movieclip pics

bin für jede hilfe dankbar.

cheers,
alex

[atothek]

versuch es mal so

PHP-Code:

function create_buttons() {
        for (i=0; i<button_count; i++) {
            new_button = "button"+i;
            template.duplicateMovieClip(new_button, i);
            this[new_button]._x = (this[new_button]._x+button_width*i)-half_stage_width;
            this[new_button].filename = filename = i+'.jpg';
            this[new_button].pics.loadMovie(pfad_klein+filename, 0);
            this[new_button].button.onPress = function() {
                getURL(pfad_gross+this.filename, "_blank");
            };
        }
    } 


[Trumpfass]

ha
so gings nicht. aber so gehts:
getURL(pfad_gross+this._parent.filename, "_blank");

*freu*

thx