problem beim erstelln von einem menü

[Denjo132]

hallo erstma, wie ihr seht bin ich noch net lange hier und ich hab auch vorher noch nie was mit flash gemacht...
hab vor n paar tagen mal angefangen ein menü für eine homepage zu erstellen...
also ich möchte das die buttons ihre farbe ändern wenn man drüber geht, aber die flächen die sich verändern solln sind ein movieclip der am anfang in das menü gefahren kommt und über den buttons (die ja noch keine sind) is eine unsichtbare schaltfläche die die URL aufruft... nur wie mache ich das sich die farbe der buttons verändert wenn man mit der maus über die buttons geht???

wär nett wenn mir jemand helfen könnte

[andretti]

aloha!

Du musst schon deine .fla hochladen, da wir ja nicht wissen können, wie Du das aufgebaut hast;

[Denjo132]

ok...
so da is mein menü...

[andretti]

aloha!

hardcore_Lösung:
ich versuche immer pure actionscriptlösungen_ gut oder schlecht sei mal dahingestellt...

ich habe einen MovieClip erstellt und in der Bilbliothek einen Verknüpfungsnamen gegeben;
der MovieClip hat noch einen MovieClip("MC_text"), den ich dann größer werden lasse,dieser hat ein dynamisches Textfeld mit dem namen "T_linkname"

als Hintergrund für die links habe ich auch einen MC genommen;

restliche Erklärung im Actionscript-Code;

das schreibst Du alles in die Hauptzeitleiste in den dementsprechenden frame;
am besten, in eine eigene Ebene(die oberste...), diese ebene bezeichnest Du mit "actionscript"

stop();
//mit einer Schleife attache ich 8mal den MovieClip aus der Bühne, gib ihm den namen"MC_link_+i",eine tiefe+i, und gib ihm gleich die position, die er haben soll;
for (i=0; i<8; i++) {
    _root.attachMovie("protolink", "MC_link_"+i, 50*i, {_x:580, _y:135+i*40});
}
//---------------------------------------------------------------------------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------------------------------------------------------------
// ich schreibe eine prototype-funktion, diese rufen dann alle 8 link_movieclips auf;innerhalb der prototypefunktion verwende ich paramter("linkname","adresse"), die dann vom link_movieclip übergeben werde, siehe dann unten
MovieClip.prototype.linksystem = function(linkname, adresse) {
    //this bezieht sich bei einer function immer auf den aufrufer;
    //this.MC_text.T_linkname wird formatiert: ausrichtung zentriert, automatische größe(je nach Textlänge);
    this.MC_text.T_linkname.autoSize = "CENTER";
    //der Text des Textfeldes wird zugewiesen(parameter"linkname";
    this.MC_text.T_linkname.text = linkname;
    //onRollOver function:gehe zu deinem zweiten frame,weil der eine andre farbe hat
    this.onRollOver = function() {
        this.gotoAndStop(2);
    };
        //onRollOOut function:gehe zu deinem ersten frame ,weil der die alte farbe hat
    this.onRollOut = function() {
        this.gotoAndStop(1);
    };
    //bei onReleas, rufe die url auf(parameter"adresse");
    this.onRelease = function() {
        getURL(adresse, "_blank");
    };
};
//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
//ich erstelle ein verschachteltes Array,quasi sind in dem Hauptarray nochmals 8 (weil 8 links) Arrays, mit deren Inhalt;
var linkArray = [["MC_link_0", "Home", "http://www.counter-strike-maps.de.tc"], ["MC_link_1", "About us", "http://www.counter-strike-maps.de.tc"], ["MC_link_2", "Timmy", "http://www.counter-strike-maps.de.tc"], ["MC_link_3", "Jan", "http://www.counter-strike-maps.de.tc"], ["MC_link_4", "Denis", "http://www.counter-strike-maps.de.tc"], ["MC_link_5", "Trax", "http://www.counter-strike-maps.de.tc"], ["MC_link_6", "Beats", "http://www.counter-strike-maps.de.tc"], ["MC_link_7", "Impressum", "http://www.counter-strike-maps.de.tc"]];
//mittels einer schleife lese ich den Arrayinhalt aus und rufe dann die prototype-Funktion auf und mach auch noch die animation;
//"i<linkArray.length" bedeutet, dass mann ".length aus" dem array auslesen kann, somit läuft die schleife so oft, wie das Hauptarray Inhalte hat(eben 8 Unter-Arrays) 
for (i=0; i<linkArray.length; i++) {
    // erstes Auslesen aus dem Array:"link" = jeweils das Unter-Array
    var link = linkArray[i];
    //"linkbutton" = der erste Inhalt vom Unter-Array
    var linkbutton = link[0];
    //"linktext" = der zweite Inhalt vom Unter-Array
    var linktext = link[1];
    //"linkadress" = der dritte Inhalt vom Unter-Array
    var linkadresse = link[2];
    //jetzt wird die prototype-Funktion von jedem link-movieclip aufgerufen, mit den zugehörigen parametern;
    _root[linkbutton].linksystem(linktext, linkadresse);
    //für die schriftanimation müssen wir den inneren Movieclip, in dem das Textfeld ist, ganz klein machen:
    _root[linkbutton].MC_text._xscale = _root[linkbutton].MC_text._yscale=0;
    // dann mal die slide-Animation durchführen....wenn die link-movieclips._x größer als 390 sind, dann sliden sie
    _root[linkbutton].onEnterFrame = function() {
        if (this._x>=390) {
            this._x -= 5;
            //wenn sie nicht größer als 390 sind, dann bitte das onEnterFrame-event deleten
        } else {
            this._x = 390;
            delete this.onEnterFrame;
            // neuerliches auslesen des array, weill die schleife durch ist
            for (a=0; a<linkArray.length; a++) {
                var link2 = linkArray[a];
                var linkbutton2 = link2[0];
                //und nun, weil ja alle linkmovieclips auf 390 sind, kann man die schriftanimation durchführen;
                _root[linkbutton2].MC_text.onEnterFrame = function() {
                    this._xscale<=100 ? this._xscale += 10 : 0;
                    this._yscale<=100 ? this._yscale += 10 : 0;
                };
            }
        }
    };
} 

[Denjo132]

das is wirklich hardcore... aber nach 20 minuten drauf starren hab ich das dann doch verstanden wie du das gemacht hast
aber danke funzt ja alles wunderbar
nur wo kann ich die schrift ändern?

[Denjo132]

ahhh... ich habs im text_MC
nochma danke

[Denjo132]

da fällt mir noch ne frage ein wie kann ich ein sound einspieln wenn der button die farbe von grau auf die andere ändert? und wenn man auf den button klickt
wie gesagt ich kenn mich mit flash noch nich aus...
wollt mir aber bald ma n buch zum thema kaufen

[andretti]

aloha!

den sound in die blibliothek importieren und verknüpfen für actionscript;

//neue variabel für rollOver-sound definieren
var overSound = new Sound();
//den dementsprechenden sound der variabel zuweisen
var overSound.attachSound("verknüpfungsnameInDerBibliothek");
//neue variabel für click-sound definieren
var clickSound = new Sound();
//den dementsprechenden sound der variabel zuweisen
var clickSound.attachSound("verknüpfungsnameInDerBibliothek");
MovieClip.prototype.linksystem = function(linkname, adresse) {
        //this bezieht sich bei einer function immer auf den aufrufer;
        //this.MC_text.T_linkname wird formatiert: ausrichtung zentriert, automatische größe(je nach Textlänge);
        this.MC_text.T_linkname.autoSize = "CENTER";
        //der Text des Textfeldes wird zugewiesen(parameter"linkname";
        this.MC_text.T_linkname.text = linkname;
        //onRollOver function:gehe zu deinem zweiten frame,weil der eine andre farbe hat
        this.onRollOver = function() {
                this.gotoAndStop(2);
//overSound einmal anspielen bitte:
overSound.start(0,1);
        };
        //onRollOut function:gehe zu deinem ersten frame ,weil der die alte farbe hat
        this.onRollOut = function() {
                this.gotoAndStop(1);
        };
        //bei onRelease, rufe die url auf(parameter"adresse");
        this.onRelease = function() {
//clicksound einmal anspielen bitte:
clickSound.start(0,1);
                getURL(adresse, "_blank");
        };
}; 

[Denjo132]

**Fehler** Szene=Szene 1, Ebene=Ebene 1, Bild=1:Zeile 12: Syntaxfehler.
     var overSound.attachSound("rolloversound.mp3");
 
Anzahl der ActionScript-Fehler: 1    Gemeldete Fehler: 1 

kannn es sein dass das "var" davor weg muss?
aber jetzt hör ich kein sound beim drüber fahrn

[Denjo132]

ahhh!!! ich hatte vergessn die AS verknüpfung in der bibliothek zu machen
jetzt gehts alles...
danke