Problem beim auslesen einer XML

[_crypto_]

Also habe mir überlegt es doch mal so wie iTunes zu machen
und mit einer dynamischeren XML-Datei dem User es zu erlauben
die Oberfläche besser anpassen zu können. Dafür kann er die XML so verändern:

<?xml version="1.0" encoding="UTF-8"?>

<folder name="Aggro Berlin">
  <playList name="->Ansage Nr.1">
    <song name="-->Aggro.mp3" />
  </playList>
  <playList name="->Ansage Nr.3">
    <song name="-->Boss.mp3" />
  </playList>
</folder>

<folder name="Frauenarzt">
  <playList name="->Porno Party">
    <song name="-->Komm Lass Uns F**ken.mp3" />
  </playList>
</folder>

so nun möchte ich in Flash natürlich jeden Ordner auslesen -> ihm seine playLists zufügen -> mit den entsprechenden Liedern. Das klapt alles ganz gut bis das es Probleme gibt dies alles in einen Array zu packen:

var XML_Libary:XML = new XML();
var XML_Folders:Array = [[[]]];
 
XML_Libary.ignoreWhite = true;
XML_Libary.load("Libary.xml");
XML_Libary.onLoad = function(success)
{
    if(success) {
        // <folder>
        for(var i:Number=0; i<XML_Libary.childNodes.length; i++) {
            XML_Folders[i] = XML_Libary.childNodes[i].attributes.name;
            
            // <playList>
            for(var j:Number=0; j<XML_Libary.childNodes[i].childNodes.length; j++) {
                XML_Folders[i][j] = XML_Libary.childNodes[i].childNodes[j].attributes.name;
                
                // <song>
                for(var k:Number=0; k<XML_Libary.childNodes[i].childNodes[j].childNodes.length; k++) {
                    XML_Folders[i][j][k] = XML_Libary.childNodes[i].childNodes[j].childNodes[k].attributes.name;
                }
            }
        }
        trace(XML_Folders[0][1][0]); // undefined
    }
} 

[Omega Psi]

Deine XML ist falsch:

<?xml version="1.0" encoding="UTF-8"?>
<folders><!-- Ein Wurzelelement fehlte -->
	<folder name="Aggro Berlin">
		<playList name="->Ansage Nr.1">
			<song name="-->Aggro.mp3" />
		</playList>
		<playList name="->Ansage Nr.3">
			<song name="-->Boss.mp3" />
		</playList>
	</folder>
	<folder name="Frauenarzt">
		<playList name="->Porno Party">
			<song name="-->Komm Lass Uns F**ken.mp3" />
		</playList>
	</folder>
</folders>

XML_Libary.load("Libary.xml");/* Meintest du Library? ;) - also immer? */ 

Trotzdem schaust nicht ganz richtig aus...

[Omega Psi]

Versuch's mal so:

var XML_Library:XML = new XML();
var folders:Array = new Array();
XML_Library.ignoreWhite = true;
XML_Library.load("Library.xml");
XML_Library.onLoad = function(success) {
    if (success) {
        for (var i:Number = 0; i<XML_Library.firstChild.childNodes.length; i++) {
            var folder:Folder = new Folder(XML_Library.firstChild.childNodes[i].attributes.name);
            for (var j:Number = 0; j<XML_Library.firstChild.childNodes[i].childNodes.length; j++) {
                var playlist:Playlist = new Playlist(XML_Library.firstChild.childNodes[i].childNodes[j].attributes.name);
                for (var k:Number = 0; k<XML_Library.firstChild.childNodes[i].childNodes[j].childNodes.length; k++) {
                    playlist.addSong(XML_Library.firstChild.childNodes[i].childNodes[j].childNodes[k].attributes.name);
                }
                folder.addPlaylist(playlist);
            }
            folders.push(folder);
        }
        printFolders();
    }
};
function printFolders() {
    for (var i:Number = 0; i<folders.length; i++) {
        trace(folders[i].getName()); // Folder ausgeben
        for (var j:Number = 0; j<folders[i].playlists.length; j++) {
            trace(folders[i].getPlaylistAt(j).getName());
            for (var k:Number = 0; k < folders[i].getPlaylistAt(j).songs.length; k++) {
                trace(folders[i].getPlaylistAt(j).getSongAt(k));
            }
        }
    }
} 

class Folder {
    var name:String;
    var playlists:Array;
    public function Folder(name:String) {
        this.name = name;
        this.playlists = new Array();
    }
    public function getName():String {
        return this.name;
    }
    public function addPlaylist(pl:Playlist) {
        this.playlists.push(pl);
    }
    public function getPlaylistAt(index:Number):Playlist {
        return playlists[index];
    }
} 

class Playlist {
    public var name:String;
    public var songs:Array;
    public function Playlist(name:String) {
        this.name = name;
        this.songs = new Array();
    }
    public function getName():String {
        return this.name;
    }
    public function addSong(songname:String) {
        this.songs.push(songname);
    }
    public function getSongAt(index):String {
        return songs[index];
    }
} 

Ausgabe:

Aggro Berlin
->Ansage Nr.1
-->Aggro.mp3
->Ansage Nr.3
-->Boss.mp3
Frauenarzt
->Porno Party
-->Komm Lass Uns F**ken.mp3

Ist zwar net so ganz scheyn gekapselt, but u get the idea und es ist später als gedacht...

Btw: Variablenname klein schreiben... liest sich besser, da Klassennamen laut Konvention groß geschieben werden.