Problem bei dynamisch erstellten MovieClips

[Novanic]

Hi Leute,

Dieser Code liegt bei mir in der _root (1. Ebene, 1. Bild).

Scheinbar wird onEnterFrame nur einenmal von jedem Objekt aufgerufen (also nur 3 mal). Müsste die onEnterFrame nicht immer wiederholt werden? Wie kann das sein, normaler weise müsste da doch voll die Post abgehen. *g*

VarEnemy=_root.createEmptyMovieClip("Enemy"+i,10+i );
VarEnemy.loadMovie("enemy"+ (i-1) +".jpg");
VarEnemy.ID=i;
VarEnemy._x = 408;
VarEnemy._y = 331;

VarEnemy.onEnterFrame = function() {
if(_root.collisionE[this.ID] == true && _root.chooseE[this.ID] == false) {
num = random(4);
}

switch(num) {
case 1:
this.EnemyLeft(this.ID);
break;
case 2:
this.EnemyRight(this.ID);
break;
case 3:
this.EnemyUp(this.ID);
break;
case 4:
this.EnemyDown(this.ID);
break;
}
}

Danke schonmal im Voraus! :-)

Gruß Nova

[sonar]

1. hattest du doch schon nen Thread irgendwo zu dem Thema
2. bei diesem Code hier fehlt doch noch die for-Schleife außen rum..?
3. formatiere doch bitte deinen Code hier mit den AS-Tags, dann erkennt man auch, was wie zusammen gehört
4. geht ein enterFrame verloren, wenn was externes in einen MC geladen wird

[Novanic]

Oha,

ja die For-Schleife fehlt tatsächlich.

Aber das onEnterFrame wird ja erst nach dem loadMovie definiert, also dürfte das doch nicht verloren gehen oder? Und wenn doch wie soll man das ändern?
Hab das Problem leider noch net gefunden. :-(

Der Code liegt so in der _root (da ist keine Funktion oder so drum):

for (i = 1; i <= 3; i++) {
    VarEnemy = _root.createEmptyMovieClip("Enemy"+i,10+i); 
    VarEnemy.loadMovie("enemy"+ (i-1) +".jpg");
    VarEnemy.ID=i;
    VarEnemy._x = 408;
    VarEnemy._y = 331;
    
    VarEnemy.onEnterFrame = function() {
        trace(this)
        if(_root.collisionE[this.ID] == true && _root.chooseE[this.ID] == false) {
            num = random(4);
        }
 
        switch(num) {
            case 1:
                this.EnemyLeft(this.ID);
                break;
            case 2:
                this.EnemyRight(this.ID);
                break;
            case 3:
                this.EnemyUp(this.ID);
                break;
            case 4:
                this.EnemyDown(this.ID);
                break;
        }
    }
} 

Gruß Nova

[Serge]

tach auch...

ich denke, esliegt definitiv an dem laden des bildes.
Die enterframe funktion wird also nach fertig laden des jpgs überschrieben.

Die schnellste Lösung wäre sicherlich das erstellen eines Container MC'S in den Enemy MC's

for (i = 1; i <= 3; i++) { 
    VarEnemy = _root.createEmptyMovieClip("Enemy"+i,10+i); 
    VarEnemyCont = VarEnemy.createEmptyMovieClip("container",i); 
    VarEnemyCont.loadMovie("enemy"+ (i-1) +".jpg"); 
    VarEnemy.ID=i; 
    VarEnemy._x = 408; 
    VarEnemy._y = 331; 
     
    VarEnemy.onEnterFrame = function() { 
        trace(this) 
        if(_root.collisionE[this.ID] == true && _root.chooseE[this.ID] == false) { 
            num = random(4); 
        } 
 
        switch(num) { 
            case 1: 
                this.EnemyLeft(this.ID); 
                break; 
            case 2: 
                this.EnemyRight(this.ID); 
                break; 
            case 3: 
                this.EnemyUp(this.ID); 
                break; 
            case 4: 
                this.EnemyDown(this.ID); 
                break; 
        } 
    } 
} 

das sollte funktionieren

Grüße
Serge