Preloader-Script: Textfeld verschwindet

[johanness]

Hallo,

sobald der Ladevorgang beginnt verschwindet das Textfeld - obwohl _visible nicht auf false gesetzt wird?

Hab sicher nur wieder was übersehen...

stop();
_global.tiefe = 0;
/////////////////////////////////////////////////////////
var h = 5;
var b = 100;
this.createEmptyMovieClip("rahmen", _global.tiefe++);
this.rahmen.beginFill (0xFFFFFF, 100);
this.rahmen.lineStyle (1, 0xAAAAAA, 100);
this.rahmen.moveTo (0, 0);
this.rahmen.lineTo (b, 0);
this.rahmen.lineTo (b, h);
this.rahmen.lineTo (0, h);
this.rahmen.endFill();
this.rahmen._x = 200;
this.rahmen._y = 335;
/////////////////////////////////////////////////////////
this.createEmptyMovieClip("balken", _global.tiefe++);
this.balken.beginFill (0xCCCCCC, 100);
this.balken.moveTo (0, 0);
this.balken.lineTo (b-1, 0);
this.balken.lineTo (b-1, h-1);
this.balken.lineTo (0, h-1);
this.balken.endFill();
this.balken._x = 201;
this.balken._y = 336;
this.balken._xscale = 0;
/////////////////////////////////////////////////////////
this.formatNormal = new TextFormat();
this.formatNormal.font =  "px-Ver-8pt";
this.formatNormal.color = 0x666666;
this.formatNormal.size = 8;
this.formatNormal.underline = false;
/////////////////////////////////////////////////////////
this.createTextField("txtStatus", _global.tiefe++, 200, 340, 100, 30);
this.txtStatus.text = "Lade...";
this.txtStatus.embedfonts = true;
this.txtStatus.setTextFormat(formatNormal);
/////////////////////////////////////////////////////////
this.createEmptyMovieClip("container", _global.tiefe++);
this.container._x = 0;
this.container._y = 0;
/////////////////////////////////////////////////////////
this.container._visible = 0;
this.txtStatus._visible = 1;
this.balken._visible = 1;
this.rahmen._visible = 1;
/////////////////////////////////////////////////////////
extern_laden = function (clip) {
    // -------------------------------------------------
    this.container.loadMovie(clip);
    this.createEmptyMovieClip("control", _global.tiefe++);
    // -------------------------------------------------
    tl = this;
    this.control.onEnterFrame = function() {
    
        if (tl.container.getBytesLoaded()>=4) {
            // -----------------------------------------
            tl.balken._visible = 1;
            tl.rahmen._visible = 1;
            tl.txtStatus._visible = 1;      
            tl.container._visible = 0;
            // -----------------------------------------
            gesamt = tl.container.getBytesTotal();
            bereits = tl.container.getBytesLoaded();
            prozent = Math.ceil((bereits/gesamt)*100);
            // -----------------------------------------
            tl.txtStatus.text = "Lade...   " + prozent + "% von " + Math.ceil(tl.container.getBytesTotal()/1024) + "kB";
            tl.balken._xscale = prozent;
            trace(tl.txtStatus.text);
            // -----------------------------------------
            if (prozent == 100) {
                tl.container._visible = 1;
                tl.txtStatus._visible = 0;
                tl.balken._visible = 0;
                tl.rahmen._visible = 0;
                delete this.onEnterFrame;
            }
        }
    };
};
//////////////////////////////////////////////////////////
extern_laden("flash.swf");
////////////////////////////////////////////////////////// 
 

[johanness]

Wenn ich folgende Zeile auskommentiere, dann wird immerhin der anfangs definierte Text im Textfeld dargestellt:

// Auskommentieren
tl.txtStatus.text = "Lade...   " + prozent + "% von " + Math.ceil(tl.container.getBytesTotal()/1024) + "kB"; 

Aber was kann daran falsch sein?

[atothek]

na du "pappnase" wenn du die 100% ereichst stellste die

tl.txtStatus._visible = 0;

ja wieder auf false;

[johanness]

Soll er ja auch! Aber der verschwindet davor ja schon, wenn die die obige Zeile reinschreibe. Dann kommt gar net erst ein Text

[atothek]

na dann versuch mal folgende variante

extern_laden = function (clip) {
    // -------------------------------------------------
    this.container.loadMovie(clip);
    this.createEmptyMovieClip("control", _global.tiefe++);
    // -------------------------------------------------
    this.control.tl = this;
    this.control.onEnterFrame = function() {
        if (tl.container.getBytesLoaded()>=4) {
            // -----------------------------------------
            this.tl.balken._visible = 1;
            this.tl.rahmen._visible = 1;
            this.tl.txtStatus._visible = 1;
            this.tl.container._visible = 0;
            // -----------------------------------------
            gesamt = this.tl.container.getBytesTotal();
            bereits = this.tl.container.getBytesLoaded();
            prozent = Math.ceil((bereits/gesamt)*100);
            // -----------------------------------------
            this.tl.txtStatus.text = "Lade...   "+prozent+"% von "+Math.ceil(this.tl.container.getBytesTotal()/1024)+"kB";
            this.tl.balken._xscale = prozent;
            trace(this.tl.txtStatus.text);
            // -----------------------------------------
            if (prozent == 100) {
                this.tl.container._visible = 1;
                this.tl.txtStatus._visible = 1;
                this.tl.balken._visible = 0;
                this.tl.rahmen._visible = 0;
                delete this.onEnterFrame;
            }
        }
    };
}; 

[RustyCake]

Hi johanness

@ atothek
this.tl.container._visible = 1;
this ist dem fall nicht angebracht, weil sich des auf den Clip in dem der EnterFrame läuft beziehen würde,!!!

/////////////////////////////////////////////////////////////////////////////////////////////////////////////////
tl.txtStatus.text = "Lade...   "+prozent+"% von "+Math.ceil(tl.container.getBytesTotal()/1024)+"kB";
tl.txtStatus.setTextFormat(tl.formatNormal);
tl.balken._xscale = prozent;
trace(tl.txtStatus.text);
/////////////////////////// kleiner Vorschlag noch////////////////////////////////////////////////////////////
tl.txtStatus.removeTextField();
tl.balken.removeMovieClip();
tl.rahmen.removeMovieClip();
///////////////////////////////////////////////////////////////////////////////////////////////////////////////// 
 

[atothek]

@rusty na das this ist schon korrekt da ich eine referenz in den clip schreibe

this.control.tl = this;
--------------------------
this.control.onEnterFrame = function() {
... 

in diesem fall ist tl bestandteil von container und kann mit this angesprochen werden oder verstehe ich mal wieder was falsch ????

see ya

[RustyCake]

Yupp! weil sich "txtStatus",
"balken" und "rahmen" nicht innerhalb des containers befinden sondern auf der HTM

[atothek]

nu bin ich verwirrt also meinst du das ich falsch liege?

[RustyCake]

Yo! ein bisschen, weil sich Dein tl uaf die timeline des containers bezieht, da sind aber die mc's und des textfeld net drinne!

Der fehler von johanness ist der das er dem textfeld wieder ein neues Format mitteilen muß

[atothek]

na dann verstehe ich aber nicht warum ich eine referenz in die variable schreibe in der der gesamte "absolute" pfad enthalten ist wenn ich zB.

trace(this.tf.balken);

schreiben erhalte ich

_level0.balken

wenn ich

trace(this.tf);

schreibe erhalte ich

_level0

das heißt doch das ich mit diesem absolutem pfad genau den mc anspreche der auch gemein ist

aber mit dieser art von logig tat ich mich immer schon schwer

[johanness]

Hi Rusty,
nochmal hi atothek!

@atothek:
Dein Script oben funktioniert leider auch nicht! Da geht nicht mal mehr der Vorschrittsbalken

Andere Lösungsvorschläge ?

[atothek]

Rusty hat recht das mit dem this klappt nur unter flash2004 hab icvh verpeilt sorry und desweiteren muß dem TF das format neu zugewiesen werden

extern_laden = function (clip) {
    // -------------------------------------------------
    this.container.loadMovie(clip);
    this.createEmptyMovieClip("control", _global.tiefe++);
    // -------------------------------------------------
    tl = this;
    this.control.onEnterFrame = function() {
        if (tl.container.getBytesLoaded()>=4) {
            
            // -----------------------------------------
            tl.balken._visible = 1;
            tl.rahmen._visible = 1;
            tl.txtStatus._visible = 1;
            tl.container._visible = 0;
            // -----------------------------------------
            gesamt = tl.container.getBytesTotal();
            bereits = tl.container.getBytesLoaded();
            prozent = Math.ceil((bereits/gesamt)*100);
            // -----------------------------------------
            tl.txtStatus.text = "Lade...   "+prozent+"% von "+Math.ceil(tl.container.getBytesTotal()/1024)+"kB";
            tl.txtStatus.setTextFormat(tl.formatNormal);
            tl.balken._xscale = prozent;
            trace(tl.txtStatus.text);
            
            // -----------------------------------------
            if (prozent == 100) {
                tl.container._visible = 1;
                tl.txtStatus._visible = 1;
                tl.balken._visible = 1;
                tl.rahmen._visible = 0;
                delete this.onEnterFrame;
            }
        }
    };
}; 

das funtzt bei mir mit flash 6 AS1

[johanness]

Vielen Dank!
Es hat also nur die Zeile gefehtl, in der dem Textfeld das Textformat neu zugeteilt wird. Seit wann muss man denn das machen!?

[RustyCake]

Immer schon!!