onRollOut & MovieClip

[teddy86]

Hallo!

Auf meinem MC liegt das Script:

onClipEvent (enterFrame) {
    targetx = 10 - this._x - this._xmouse / 2;
    this._x = this._x + (targetx - this._x) / 5;
} 

Welches den MC relativ zur Mausposition bewegt.
Wenn die Maus den MC nun aber verlässt, soll der MC zurück zu targetx =10!

Wie stell ich dass am Besten an? onRollOut? Hätte gerne ein einfaches Codeschnipselchen das ich direkt auf den MC legen kann.. Wer kann mir helfen?

Lieben Gruß
Teddy

[johanness]

Um festzustellen, ob du Maus außerhalb des Flash-Movies liegt brauchst du JavaScript. Was aber auch möglich wäre: du erstellst einen MC mit alpha=0, der über die ganze Bühne mit einem Pixel Rand geht. Dann kannst du den einfach als "Bühnengröße" verwenden. Darf halt in dem 1px-Rand nichts wichtiges sein...

[teddy86]

Es geht ja nicht darum ob die Maus außerhalb des Bühnenrandes ist oder nicht. Erstmal gehts nur darum, ob die maus auf dem mc liegt oder nicht.

meine frage ging dahin wie der code aussieht mit dem ich feststellen kann ob die maus nicht über einem MC "xyz" liegt...

mfg
teddy

[thebiz]

Hy.

Das kannst Du mit hitTest() lösen.
hitTest() registriert z.B. ob die Maus ein Objekt
berührt.

Gruß
John

edit:
Oder Du kannst es auch per onRollOver und onRollOut
machen. Dann musst Du z.B. bei einem onRollOver einen
onEnterFrame() auslösen, den Du dann beim onRollOut
wieder eliminierst. (delete mc.onEnterFrame

[psyk]

Hi,
hab mir mal erlaubt die Vorschläge von thebiz in AS um zusetzen.
Einzige wasse noch machen mußt ist das Script in den ersten Frame deiner Zeitleiste zulege und dein MC eine Instance bspw. "mein_mc" zugeben.

Die hitTest Variante

mein_mc.onEnterFrame = function() {
    if (this.hitTest(_root._xmouse, _root._ymouse, true)) {
        var targetX = 10-this._x-_root._xmouse/2;
        this._x = this._x+(targetX-this._x)/5;
    } else {
        this._x = 10;
    }
}; 

Oder mit RollOver/Out:

mein_mc.onRollOver = function() {
    this.onEnterFrame = function() {
        var targetX = 10-this._x-_root._xmouse/2;
        this._x = this._x+(targetX-this._x)/5;
    };
};
mein_mc.onRollOut = function() {
    delete this.onEnterFrame;
    this._x = 10;
}; 

[jeypack]

@psyk: Bei deiner Vorgehensweise läuft er aber nicht wieder zurück, sondern springt. Ich mein ja nur...

Also ich verstehe dein Problem so:

Du möchtest, dass der mc folgt, aber nur bei einem rollOver.
Ein rollOut dürfte dann ja nicht passieren, wenn der mc folgt, oder ich versteh was falsch.

// dies hier ins erste frame der maintimeline
MovieClip.prototype.followOnRollOver = function() {
    this.useHandCursor = false;
    this.scr = this.getBounds(_root);
    this.x = this._x;
    this.y = this._y;
    this.onEnterFrame = function() {
        if (_xmouse>=this.scr.xMin && _xmouse<=this.scr.xMax && _ymouse>=this.scr.yMin && _ymouse<=this.scr.yMax) {
            this._x += Math.ceil((_xmouse-this._x)/5);
        } else {
            this._x += Math.ceil((this.x-this._x)/3);
            if (Math.floor(Math.sqrt(((this._x-this.x)*(this._x-this.x))+((this._y-this.y)*(this._y-this.y))))<5) {
                this._x = this.x;
                delete this.onEnterFrame;
            }
        }
    };
};
// hier für entsprechenden mc die Methode bei rollOver aufrufen
rechteck_mc.onRollOver = function() {
    this.followOnRollOver();
}; 

ausprobieren...

[psyk]

@jeypack: Nicht schlecht!
Bei deiner Vorgehensweise läuft er aber auf eine relativen Punkt x zurück, Vorgabe war aber 10. Ich mein ja nur...

PHP-Code:

// dies hier ins erste frame der maintimeline
MovieClip.prototype.followOnRollOver = function() {
    this.useHandCursor = false;
    this.scr = this.getBounds(_root);
    this.x = 10
    this.y = this._y;
    this.onEnterFrame = function() {
        if (_xmouse>=this.scr.xMin && _xmouse<=this.scr.xMax && _ymouse>=this.scr.yMin && _ymouse<=this.scr.yMax) {
            this._x += Math.ceil((_xmouse-this._x)/5);
        } else {
            this._x += Math.ceil((this.x-this._x)/3);
            if (Math.floor(Math.sqrt(((this._x-this.x)*(this._x-this.x))+((this._y-this.y)*(this._y-this.y))))<5) {
                this._x = this.x;
                delete this.onEnterFrame;
            }
        }
    };
};
// hier für entsprechenden mc die Methode bei rollOver aufrufen
rechteck_mc.onRollOver = function() {
    this.followOnRollOver();
}; 


[jeypack]

Zitat von psyk

@jeypack: Nicht schlecht!
Bei deiner Vorgehensweise läuft er aber auf eine relativen Punkt x zurück, Vorgabe war aber 10. Ich mein ja nur...

Da hast du natürlich recht.

Ist halt alles auch relativ abhängig vom Registrierungspunkt des mc.

Ich denke, auf jeden Fall ist diese Vorgehensweise echt performance-günstich, da er den onEnter ja immer wieder abschaltet.

Gruß

[thebiz]

Das onEnterFrame schaltet nur ab,
wenn auch this.x erreicht wird.

Kann es da nicht zu Ungenauigkeiten kommen?
Ich glaube damit hatte ich schon so manchmal zu kämpfen.

Da kann man ja sicherheitshalber noch eine
if-Abfrage einbauen. wenn this._x z.B. in die nähere Region
von this.x kommt.

Nur mal so marginal erwähnt

[jeypack]

Zitat von thebiz

Das onEnterFrame schaltet nur ab,
wenn auch this.x erreicht wird.

Kann es da nicht zu Ungenauigkeiten kommen?
Ich glaube damit hatte ich schon so manchmal zu kämpfen.

Da kann man ja sicherheitshalber noch eine
if-Abfrage einbauen. wenn this._x z.B. in die nähere Region
von this.x kommt.

Nur mal so marginal erwähnt

Das hast du aber nur so erwähnt, ne?
Ich mein, so beim Überfliegen. Du musst dir das mal ganz genau anschauen.
Ich frag da nämlich mit 'Pytagoras' (der alte Grieche) die Entfernung ab.
Wenn die kleiner als 5, dann deleten und auf Ausgangsstellung.

[thebiz]

Oh, wie schlecht von mir
Sorry. Ich bin zugegeben doch
nur drüber geflogen.

G
John