onPress = funktion auf alle bis auf den angeklickten?

[Mr.Twister]

hi (mal wieder :-)

mal angenommen, ich habe 5 mcs auf der bühne (oder zusammen in einem mc).
wenn ich auf einen dieser 5 mcs klicke, sollen alle bis auf den angeklickten etwas machen (z.B. mal play())

der angeklickte soll aber nichts machen.

danke für hilfe!

[kelor]

angenommen die heißen 'mc1', 'mc2', etc...

//anzahl der mc´s festlegen:
var mc_count=5;
 
//array für die mc´s
myArr = [];
 
// alle mc´s in ein array pushen
 
for(var i=1; i<=mc_count;i++){
     myArr.push(this['mc'+i] )
 
     // funktionen z.bsp. onPress generieren:
         this['mc'+i].onPress=function(){
 
               //alle außer sich selbst:
                 for(var j=0;j<_root.myArr.length;j++){
                       if(_root.myArr[j] != this){
                           
                         // hier nun, was geschehen soll: (bsp.: trace)
                            trace('hey!  sagt : '+_root.myArr[j]);
                       }
                 }
         }                      
} 

ich gebe zu, dass mir diese lösung nicht sonderlich gefällt...
aber eine andere die ich hätte, würde zu viele erklärungen kosten...

diese hier sollte wunderbar laufen und übersichtlich sein...
*habs ausm kopp getippt*

bei probs einfach fragen...

hoffe das ist das , was du gesucht hattest...

greetz

kelor

[Mr.Twister]

hi kelor,

erstmal danke.

bei mir wendet er die funktion nur auf sich an und lässt alle anderen in ruhe.

ich kann dir ja nochmal ebenetwas mehr erzählen:

also es geht um einen drag&drop fall:
mal angenommen, ich schiebe einen mc auf ein ziel und es rastet da ein.
dann will ich einen weiteren mc auf das ziel schieben und möchte, daß der bereits auf dem ziel liegende mc dann an seine ursprungsposition zurückkehrt.

ich habe den mcs (die sich in einem parent mc befinden) keine instanznamen gegeben und #include deren scripte aus einem AS file.

die reihenfolge der mcs kann stark variieren, weshalb ich den mcs ungern eine zahlenreihenfolge in den namen vergeben möchte, sondern wenn, dann höchstens individuelle namen.

vielleicht fällt dir ja spontan noch was dazu ein.

[kelor]

hey [mr.twister] tornado... das kann aber nicht sein...

habe eben meinen code mal schnell in eine fla gestopft.
funktioniert genau so, wie es sollte...

wenn ich auf 'mc1' klicke, bekomme ich mc2, mc3, mc4, mc5 angezeigt...

wenn ich auf 'mc3' bekomme ich mc1,mc2,mc4,mc5 angezeigt...
genau so, wie es beabsichtigt ist...

der code funktioniert also so, wie er sollte.

nun zu deinem fall:

wie wäre es, wenn du einfach die ausgangspositionen deiner mc´s in einem object speicherst und einfach alle, außer dem aktiven, wieder auf diese pos setzt...

// ich benenne die mc´s einfach mal :hugo, fritz, emma, karl
 
// var count ist die anzahl der mc´s:
 
var count=4;
 
// array zum ablegen der mc´s und der objekte, die die daten enthalten
mc_arr= [hugo,fritz,emma,karl];
mc_obj=[];
 
// objekte für die einzelnen mc´s anlegen:
 
for(var i=1;i<=count;i++){
     var mc =mc_arr[i-1];
     var k=mc._name;
     mc_obj[k]={x:mc._x, y: mc._y};
}
delete mc;
delete k;
delete i; 

sodele...jetzt hast du 4 objekte, die wie deine mc´s heißen
auf die mc´s kannst du nun via :
mc_arr[n] zugreifen


auf die objekte via:
var mcName=mc_arr[n]._name;
mc_obj[mcName];


und auf deren werte, via:
mc_obj[mcName].x

oder

mc_obj[mcName].y

jetzt kannst du ja meine fkt von oben nehmen und überprüfen, welcher der aktive ist...

verstanden?

hilft das jetzt weiter?


greetz

kelor

[Mr.Twister]

hi!

also erstmal sorry, daß ich wohl dein AS aus dem ersten beitrag falsch angewendet hab.

und zu deinem zweiten posting:
danke dafür, ich habe jetzt ne halbe stunde versucht, damit zurechtzukommen, es mag auch gut funktionieren, mir fehlt nur leider das nötige hintergrundwissen, um das script sinnvoll anzuwenden.

ANHANG

ich habe hier mal eine einfache version meines falls gebastelt.

Es tut mir leid, daß ich noch nicht so weit bin, was AS angeht, aber vielleicht magst du ja trotzdem kurz mal einen blick in die datei werfen (ist sowohl 2004 version als auch MX version in der zip enthalten) und mir dann nochmal schildern, wie der fall zu lösen wäre bzw. wo ich was von deinem script einsetze und wie ich es ansteuere.

ich gehe in der 2004er version extra über ein externes AS script, was ich auf alle kreis mcs lege, damit ich die swf möglichst klein halte.
und ich schreibe das script für das draggen der mcs extra nicht in die zeitleiste, weil ich da wiederrum erst ein array für alle mcs anlegen müsste, was ich mit dieser methode nicht brauche.

also ich wäre dir auf jeden fall für weitere hilfe sehr dankbar!

ich hoffe, daß meine bitte nicht zu dreist ist :-)
*kopfeinziehundwegrenn*

MGF - twister.

[kelor]

also einmal die mx-version [KEIN 2oo4] :

1. entferne alle scripte auf den dragable mc´s...komplett weg damit!

2. folgendes script auf die hauptzeitleiste ins bild[ da wo schon der rest von meinem script stand- entferne das und setzte folgendes script dafür ein!!]

// ich benenne die mcŽs einfach mal :hugo, fritz, emma, karl
// var count ist die anzahl der mcŽs:
_root.besetzt = null;
var count = 3;
// array zum ablegen der mcŽs und der objekte, die die daten enthalten
mc_arr = [drag1, mcdrag2, dragger3];
mc_obj = [];
// objekte für die einzelnen mcŽs anlegen:
for (var i = 1; i<=count; i++) {
    var mc = mc_arr[i-1];
    var k = mc._name;
    mc_obj[k] = {x:mc._x, y:mc._y};
    mc.onPress=function(){
       this.startDrag();
       this.swapDepths(50);
    }
    mc.onRelease=function(){
       this.stopDrag()
       if(this.hitTest(this._parent.plattenspieler)){
                       //platte liegt auf teller
               this._x = this._parent.plattenspieler._x +25;
               this._y = this._parent.plattenspieler._y +25;
               if(_root.besetzt != null){
                   _root[_root.besetzt]._x=_root.mc_obj[_root.besetzt].x;
                   _root[_root.besetzt]._y=_root.mc_obj[_root.besetzt].y;
               }
               _root.besetzt = this._name;
       }else{
                       //platte geht zurück
               this._x = _root.mc_obj[this._name].x;
               this._y = _root.mc_obj[this._name].y;
       }
    }
}
delete mc;
delete k;
delete i; 

sodele...jetzt aber...


ersetzt dir den jeweiligen mc auf deinem zielobjekt und setzt dorthin zurück, wo er her kam...

die mx 2oo4 version kommt gleich...


greetz


kelor

[Mr.Twister]

WOOOOOW ! ! ! !

ich danke dir vielmals, jetzt klappt das ja wunderbar!
das mit dem "besetzt" hab ich das auch schon ewig und drei tage versucht, aber es hat bei mir nie so geklappt, wie es sollte.
ich versuche grad, das AS zu verstehen, aber da muss ich wohl noch n bißchen dazulernen :-)
aber es funzt ja schonmal.

ich könnte das ja schon so nehmen, wie es da steht, aber ich warte trotzdem noch eben auf die 2004 version.

nochmal vielen vielen dank!
durch deine hilfe komme ich jetzt echt weiter.

[kelor]

habe es dir mal mit einer klasse aufgelöst...
würde aber auch anders gehen.

halt ein bischen 2oo4-style


1. in der *.fla nimm alle includes von den dragablen-mc´s raus!

2. in der *.fla ins erste einzige bild folgendes:

_root.besetzt = null;
 
// deine mc´s
var my_mcs =[drag1,mcdrag2,dragger3];
 
// instanz deiner klasse
var discMC:dragMcClass= new dragMcClass(my_mcs); 

und in der *.as datei, die den gleichen namen hat, wie die klasse:

class dragMcClass {
 
  var count:Number;
  var mc_arr:Array;
  var arr_obj:Array=[];
 
         // constructor
         function dragMcClass(arr:Array){
                  mc_arr=arr;
                  count=mc_arr.length;
                  setObjects();
         }
 
         //methode zum setzen der wertepaare[x - y] und der mc-methoden
         function setObjects(){
 
                  for (var i=1; i<=count; i++) {
                       var mc = mc_arr[i-1];
                       var k = mc._name;
 
                       // iss zwar nicht sauber, funZt aber...
                       // verweis in den mc´s auf das objekt
                       mc.watchObj = this;
 
                                   // assi-array mit objekten füllen, die den namen der mc´s haben
                       arr_obj[k] = {x:mc._x, y:mc._y};
 
                       //setzen der onEvents für die mc´s
 
                       mc.onPress=function(){
                          this.startDrag();
                          this.swapDepths(50);
                       }
                       mc.onRelease=function(){
                          
                          var obj = this.watchObj;
                          this.stopDrag()
                          if(this.hitTest(this._parent.plattenspieler)){
                             //platte liegt auf teller
                             this._x = this._parent.plattenspieler._x +25;
                             this._y = this._parent.plattenspieler._y +25;
 
                             // wenn plattenteller bereits belegt ist
                             if(_root.besetzt != null){
                                _root[_root.besetzt]._x=obj.arr_obj[_root.besetzt].x;
                                _root[_root.besetzt]._y=obj.arr_obj[_root.besetzt].y;
                             }
                     // belegt 'besetzt' mit dem mc-namen, der aktuell auf dem teller liegt
                             _root.besetzt = this._name;
                          }else{
                             //platte geht zurück
                             this._x = obj.mc_obj[this._name].x;
                             this._y = obj.mc_obj[this._name].y;
                          }
                      } // end of 'release'
 
                 } // end of 'for'
        }// end of 'setObjects'
} 

die AS-Datei MUSS genauso heißen, wie die klasse.
in deinem fall also dragMcClass.as !!!

hoffe, dass hilft dir nun weiter...

greetz

kelor

[Mr.Twister]

hi, das klappt auch super.
auch wenn ich in der zwischenzeit mit der MX version zurechtgekommen bin, was mir positiverweise auch die externe AS datei ersparte. die hielt ich eh eher für einen komprosmiss.

ich möchte noch eben *deine leistung in allen ehren* anmerken, daß wenn ich eine scheibe auf das ziel ziehe und die selbe anschließend nochmal auf das ziel ziehe, daß sie dann nur noch an den anfangspunkt springt.
ist zwar auch logisch, da sie sich ja selbst den befehl gibt, sich als "besetzer" zu sehen, weshalb sie sich rauskickt und an die ursprungsposi geht, aber diesen kleinen "bug" halte ich für ziemlich irrelevant. ist ja auch sowieso ne recht irsinnige aktion, die scheibe 2x aufs ziel zu ziehen.

so, wie ich ja bereits sagte, bin ich dir sehr dankbar, du hast mir quasi den tag gerettet :-)

schönen abend noch!

[kelor]

einfach folgende zeile in der 'dragMcClass' erweitern, dann klappt´s auch mit dem nachbarn:

// wenn plattenteller bereits belegt ist
if(_root.besetzt != null ){ 

um folgendes erweitern:

if(_root.besetzt != null && _root.besetzt != this._name){ 

greetz

kelor

[Mr.Twister]

oah, yeah - so einfach kanns gehen *freu*

du schreibst in deiner signatur was von einem buch.
gibts irgendwo mehr infos dazu?

[kelor]

mr.twister...

da haben sich leider beim kopieren und beim schnellen eintragen 2 fehler eingeschlichen...

1. es muss:

if(_root.besetzt != null || _root.besetzt != this._name){ 

heißen... also ein 'oder' anstelle eines 'und'


und

es muss die 'else'-bedingung MUSS natürlich so heißen:

}else{
         //platte geht zurück
         this._x = obj.arr_obj[this._name].x;
         this._y = obj.arr_obj[this._name].y;
} 

also *.arr_obj und NICHT *.mc_obj


der gesamte code der 'dragMcClass' sieht also folgendermaßen aus:

class dragMcClass {
 
  var count:Number;
  var mc_arr:Array;
  var arr_obj:Array=[];
 
         // constructor
         function dragMcClass(arr:Array){
                  mc_arr=arr;
                  count=mc_arr.length;
                  setObjects();
         }
 
         //methode zum setzen der der wertepaare und der mc-methoden
         function setObjects(){
 
                  for (var i=1; i<=count; i++) {
                       var mc = mc_arr[i-1];
                       var k = mc._name;
                       mc.watchObj = this;
                       arr_obj[k] = {x:mc._x, y:mc._y};
 
                       //setzen der onEvents für die mc´s
 
                       mc.onPress=function(){
                          this.startDrag();
                          this.swapDepths(50);
                       }
                       mc.onRelease=function(){
                          var obj = this.watchObj;
                          this.stopDrag();
                             //wenn platte über teller
                          if(this.hitTest(this._parent.plattenspieler)){
                             // wenn plattenteller bereits belegt ist
                             if(_root.besetzt != null || _root.besetzt != this._name){
                                _root[_root.besetzt]._x=obj.arr_obj[_root.besetzt].x;
                                _root[_root.besetzt]._y=obj.arr_obj[_root.besetzt].y;
                             }
                             this._x = this._parent.plattenspieler._x +25;
                             this._y = this._parent.plattenspieler._y +25;
                             _root.besetzt = this._name;
                          }else{
                             //platte geht zurück
                             this._x = obj.arr_obj[this._name].x;
                             this._y = obj.arr_obj[this._name].y;
                          }
                             
                      } // end of 'release'
 
                 } // end of 'for'
        }// end of 'setObjects'
} 

sorry for that...war mein fehler


mein buch wird ende april erscheinen...


greetz

kelor

[Mr.Twister]

ahja, okay, alles klar.

dann warte ich mal bis ende april und gucke mal, was der kelor da so auf den buchmarkt gebracht hat :-)