onMouseDown auf dynamisch erstellten MC

[greyTux]

Hi alle!

mein problem: ich erstelle für ein puzzle dynamisch 64 MCs, in die dann ein jpg geladen wird, und verteile sie auf der spielfläche.
soweit funktioniert noch alles prima.
allerdings möchte ich dann jedem puzzleteil einen onMouseDown-listener hinzufügen, der startDrag ausführt, hier reagiert leider nichts mehr.

ich bin noch nich so bewandert in AS, verzeiht mir also anfängerfehler

hier mein bisheriger code:

var i = 0;
    for (y=0; y<pieces; y++) {
        for (x=0; x<pieces; x++) {
            _root.createEmptyMovieClip("teil"+i, i);
            _root["teil"+i].onMouseDown=function(){
                    trace("maus wurde gedrückt");
                 }
            teil[i] = eval("_root.teil"+i);
            teil[i]._x = width*x;
            teil[i]._y = height*y;
            if (i<9) {
                var teilNummer = "0"+(i+1);
            } else {
                var teilNummer = (i+1);
            }
            teil[i].loadMovie("teil_"+teilNummer+".jpg");
            i++;
        }
    } 

[thebiz]

Hy.

Nimm doch onPress statt onMouseDown.
Würde ich einfach mal so spontan sagen.

[greyTux]

da tut sich leider auch nichts

ich nehme eher an, dass ich schon beim MC instanzieren oder beim drauf zugreifen etwas falsch mache... aber was!?

[thebiz]

Na nach näherem Hinsehen,
sieht der Code auch etwas merkwürdig aus.

Was ist teil[i]?
was ist width?

warum nicht _root["teil"+i]....?
warum nicht _width?

Ist piecies bekannt?

[greyTux]

ok, sorry, habe der einfachheit halber nicht den ganzen code gepostet.

hier also alle benötigten teile:

var teil = new Array();
 
function init(width, height, pieces) {
    var i = 0;
    for (y=0; y<pieces; y++) {
        for (x=0; x<pieces; x++) {
            _root.createEmptyMovieClip("teil"+i, i);
            _root["teil"+i].onPress=function(){
                    trace("maus wurde gedrückt");
         }
            teil[i] = eval("_root.teil"+i);
            teil[i]._x = width*x;
            teil[i]._y = height*y;
            if (i<9) {
                var teilNummer = "0"+(i+1);
            } else {
                var teilNummer = (i+1);
            }
            teil[i].loadMovie("teil_"+teilNummer+".jpg");
            i++;
        }
    }
} 

[greyTux]

kann mir hier niemand helfen?
ich denke, dass dies sicher ein funktion ist, welche oft gebraucht wird...

nochmals ganz kurz mein problem: ein movieclip muss dynamisch erstellt werden, und anklickbar sein.
wenn ich aktionen DIREKT in den MC schreibe (z.B. onClipEvent(mouseDown) ... ), gibt es den fehler, dass diese aktion nur bei instanzierten MCs erlaubt ist. Wenn ich, wie oben gepostet, die aktionen direkt beim instanzieren zuweise, funktioniert es auch nicht (ohne Fehlermeldung)

[rendner[i]]

PHP-Code:

 _root["teil"+i].onRelease=function(){
                                trace("maus wurde gedrückt");
                        } 


[flash bier]

wenn Du per loadMovie etwas in einen MovieClip reinlädst, verlierst du hierdurch sämtliche Event-Handler und sonstigen Code/Variablen, die diesem MovieClip zugewiesen sind.
Dein teil[i] ist sozusagen völlig leer und besteht dann nurnoch aus dem Bild, welches du da reinlädst.

Um dieses Problem zu lösen könntest du einfach in teil[i] nochmals einen MovieClip erstellen (createEmptyMovieClip) und in diesen lädst du das Bild rein.
So bleiben alle Variablen und Handler auf teil[i] erhalten und Dein Bild ist trotzdem in teil[i] enthalten.

var teil = new Array();
 
function init(width, height, pieces) {
        var i = 0;
        for (y=0; y<pieces; y++) {
                for (x=0; x<pieces; x++) {
                        _root.createEmptyMovieClip("teil"+i, i);
                        _root["teil"+i].onPress=function(){
                                trace("maus wurde gedrückt");
                        }
                       teil[i] = eval("_root.teil"+i);
                       teil[i]._x = width*x;
                       teil[i]._y = height*y;
                        if (i<9) {
                                var teilNummer = "0"+(i+1);
                        } else {
                                var teilNummer = (i+1);
                        }
                        teil[i].createEmptyMovieClip("image",1);// Hier noch einen MC erstellt
                        teil[i].image.loadMovie("teil_"+teilNummer+".jpg");// der das Bild aufnimmt
                        i++;
                }
        }
} 

MfG flash bier

[greyTux]

danke für die antwort. leider schaff ichs nicht

hier mal meine dateien:download

das ansatz ist ja: die MCs werden erstellt und mit einem teilbild gefüllt. jeden MC sollte man dann mit der Maus verschieben können.

...sry, war wohl zu langsam... werds gleich mal probieren

[greyTux]

okay, soweit geht das! danke flash bier

leider komme ich wieder nicht weiter: der MC sollte mit der maus gezogen werden. also habe folgenden code eingefügt:

_root["teil"+i].onMouseDown=function(){
    _root["teil"+i].startDrag();
}
_root["teil"+i].onMouseUp=function(){
    stopDrag();
} 

da tut sich leider nichts greife ich hier falsch auf den MC _root["teil"+i] zu? könnte ich das ganze nich auch weiter unten mit

teil[i].onMouseDown=function(){
  teil[i].startDrag();
}
teil[i].onMouseUp=function(){
  stopDrag();
} 

...oder so ähnlich machen?

[flash bier]

mit "this" bezieht sich der Code in onPress auf das Objekt selbst.
startDrag hast du auch noch falsch gecoded:

_root["teil"+i].onPress=function(){
        this.startDrag(true);
}
_root["teil"+i].onRelease=function(){
        this.stopDrag();
} 

MfG flash bier

[greyTux]

alles ok. Danke für die Hilfe!!!
vielleicht muss ich mich später wieder melden...