onClipEvent(EnterFrame) - unschön?

[johanness]

Hallo,

ich verwende um meine Buttons langsam erscheinen zu lassen folgendes SCript, das auf den Buttons liegt:

onClipEvent(enterFrame) {
    if(i<100) {
        i++;
        this._alpha = i;
    } else {
        delete this.onEnterFrame;
    }
} 

Da sich dieser Aufruf ja immer erfolgt und i immer weiter hoch zählt, die Frage: Ist diese Variante unschön?
Sollte ich da noch eine Abfrage reinmachen, ob alle Buttons voll erschienen sind. Und wenn ja eine Frame weiter, in der kein Script mehr auf dem Button liegt?

[johanness]

Ok, benutze jetzt was anderes:

this.onEnterFrame = function() {
    if(this.um1_btn1._alpha < 100) {
        this.um1_btn1._alpha += 1;
    } else {
        delete this.onEnterFrame;
    }
} 

Trotzdem: Sollte man eine Lösung mit oEF nicht immer umgehen?

[Smirgel]

hi,
sagen wir mal du hast 6 buttons, die auf _root liegen (butt0-butt5), dann könnteste das mit so einem script machen (bildaktion):

i = 0;
maxbuttons = 6;
this.onEnterFrame = function() {
    _root["butt"+i]._alpha++;
    if (_root["butt"+i]._alpha>100) {
        i++;
    }
    if (i == maxbuttons) {
        delete this.onEnterFrame;
        trace("fertig");
nextFrame();
    }
}; 

das blendet die buttons der reihe nach ein, stoppt dann das script und geht aufs nächste frame.

grüße.
smirgel.

[RustyCake]

Sollen die buttons erst aktiv werden wenn des alpha bei 100 ist!?

[johanness]

@RustyCake

Ich schätze mal das ist egal, weil das einblenden ca. 1-2 Sek dauert und da noch keiner klicken will. Aber eigetnlich: egal!

@smirgel

Danke, werd's mir mal ansehen!

[johanness]

Ja, Smirgel's Script geht gut!!
Aber gibt's vielleicht auch schon eines, dass den Button mit der höheren Zahl bereits einblenden anfängt, wenn der davor zB bei 60%-alpha ist?

[RustyCake]

timeline = this;
MovieClip.prototype.btn_alf = function(wert, speed) {
    this.enabled = 0;
    this.onEnterFrame = function() {
        if (this._alpha<wert) {
            this._alpha += speed;
        } else {
            this.enabled = 1;
            delete this.onEnterFrame;
        }
    };
};
for (i=1; i<=5; i++) {
    timeline["btn_mc"+i]._alpha = 0;
    timeline["btn_mc"+i].onPress = function() {
        trace(this._name);
    };
}
var j = 1;
sID = setInterval(function () {
    timeline["btn_mc"+j].btn_alf(100, 2);
    j++;
    if(j>=6){
        clearInterval(sID);
    }
}, 500); 

[johanness]

Vielen Dank! Echt spitze, wenn man hier paar hat die alles, was man oft bracuht, immer parat haben Werd's mir mal anschaun...

[johanness]

So... Also irgnedwie mag mich das Script nicht
Meine Buttons heißen "um1_btn1" bis "um1_btn4"

// Festlegen der Untermenü-Button-Anzahl "Redaktion" (von Null auf 1)
um1_btn_anzahl = 4;
um1_btn_anzahl++;
 
 
// Alle Radaktions-Buttons unsichtbar machen /////////////////////////
for(var i=1; i<= um1_btn_anzahl; i++) {
    this["um1_btn"+i]._alpha = 0;
}
// Alle Radaktions-Buttons unsichtbar machen: Ende ///////////////////
 
 
 
 
/////// Die "Redaktions"-Buttons nacheinander einfaden: Start ///////////
MovieClip.prototype.btn_fading = function(wert, speed) {
        this.enabled = 0;
        this.onEnterFrame = function() {
                if (this._alpha<wert) {
                        this._alpha += speed;
                } else {
                        this.enabled = 1;
                        delete this.onEnterFrame;
                }
        };
};
 
var j = 1;
sID = setInterval(function () {
        this["um1_btn"+j].btn_fading(100, 2);
        j++;
        if(j>=um1_btn_anzahl){
                clearInterval(sID);
        }
}, 500);
/////// Die "Redaktions"-Buttons nacheinander einfaden: Ende /////////// 
 

[johanness]

Ok, habs doch noch, aber wie kann es sein, dass es so geht (im Vergleich mit oben). Es ist nur 1!! Unterschied!

// Festlegen der Untermenü-Button-Anzahl "Redaktion" (von Null auf 1)
um1_btn_anzahl = 4;
um1_btn_anzahl++;
 
 
// Alle Radaktions-Buttons unsichtbar machen /////////////////////////
for(var i=1; i<= um1_btn_anzahl; i++) {
    this["um1_btn"+i]._alpha = 0;
}
// Alle Radaktions-Buttons unsichtbar machen: Ende ///////////////////
 
 
 
 
/////// Die "Redaktions"-Buttons nacheinander einfaden: Start ///////////
timeline = this;  //HIER IST DER EINZIGE UNTERSCHIED
MovieClip.prototype.btn_fading = function(wert, speed) {
        this.enabled = 0;
        this.onEnterFrame = function() {
                if (this._alpha<wert) {
                        this._alpha += speed;
                } else {
                        this.enabled = 1;
                        delete this.onEnterFrame;
                }
        };
};
 
var j = 1;
sID = setInterval(function () {
        timeline["um1_btn"+j].btn_fading(100, 2);  // UND HIER DANN VERWENDET
        j++;
        if(j>=um1_btn_anzahl){
                clearInterval(sID);
        }
}, 500);
/////// Die "Redaktions"-Buttons nacheinander einfaden: Ende ///////////