onArrival sollte film laden

[das_sirius]

hallo leute,

vielleicht kann mir wer von euch weiterhelfen.

ich habe drei fenster die wunderbar über die bühne sliden und mein ziel wäre es das wenn ich einen meiner 5 links anklicke und die fenster ihre position eingenommen haben sich ein externes swf reinladet.
leider waren meine bisherigen versuche alle vergebens.
vielleicht weis ja wer von euch wie das geht.. ich bin schon am verzweifeln.

ich sag schonmal danke zu allen die es versuchen.

// --> receiver passt auf, wenn der MC schreit...
var receiver = new Object();
receiver.onArrival = function(who, x, y) {
    trace(who + " ist bei " + x + "/" + y + " angekommen");
    //--> mach ma noch eine Abfrage rein, dass eben nur fenster1 das fenster2 steuert
    //who == "fenster" ? fenster2.move(fenster2._x, 67, 12, 2) : null;
//leider funkt die zeile unten auch nicht so wirklich - ladet zwar aber total unkontrolliert
    who == "fenster" ? onArrival(420, 60, 15, 1) & loadContent(_root.leer,"extern.swf") : null;
 
};
//--> der receiver wird bei den Fenstern angemeldet:
fenster.addListener(receiver);
fenster2.addListener(receiver);
fenster3.addListener(receiver); 

[ANTICHRIST]

Die haben aber eine fixe Zielposition, ja ???

Dann mach das doch so, das du onClick des Menüpunktes ein Prüfungsinterval startest in dem die gewünschten Positionen abgefragt werden und dann der Film geladen wird.... Quasi :

function Horst() {
    if (fenster1._x == ZIELX1 && fenster2._x == ZIELX2 && fenster3._x == ZIELX3) {
    if(fenster1._y == ZIELY1 && fenster2._y == ZIELY2 && fenster3._y == ZIELY3) {
     clearInterval(Jochen);
     loadMovie(laberlaber);
}
}
}
 
Menu1.onRelease = function() {
Jochen = setInterval(Horst, 10);
} 

[das_sirius]

danke für die antwort.
leider funkt das so bei mir nicht. es werden für jeden link externe files reingeladen (unterschieliche logischerweise).

vielleich hast du oder wer anders noch einen anderen lösungsvorschlag für mich zur hand.

[romän]

hi,

ich verstehe die Zeile nicht:

who == "fenster" ? onArrival(420, 60, 15, 1) & loadContent(_root.leer,"extern.swf") : null; 

Was genau soll die machen?
Wieso rufst du da noch mal onArrival auf (und dann mit 4 Parametern)?
Willst du ein bestimmtes Fenster noch mal verschieben?

Nur das Laden sollte einfach so funktionieren:

if(who == "fenster") _root.leer.loadMovie("extern.swf"); 

gruß,
roman

@antichrist: was hat Horst mit Jochen zu tun?

[ANTICHRIST]

A) Was heißt externe Files ???
B) Was hat das damit zu tun ???

C) Horst und Jochen sind schwul, arbeiten im Düsseldorfer Medienhafen bei einer Werbeagentur und leben zusammen

[das_sirius]

okok .... also das ganze script schaut bislang so aus.
das mit dem lösungsansatz von romän ist schon ganz ok nur bei 5 links muss ich die zielkoordinaten irgendwie mit ins spiel bringen, denke ich mir. da ich ja nicht sagen kann das fenster1 soll mal das mal das einladen.
das ganze script schaut bislang so aus. vielleicht ist es damit verständlicher erklärt was ich beabsichtige.

//--> jeder MC darf ab sofort rumschreien...
ASBroadcaster.initialize(MovieClip.prototype);
//--> ...und sich bewegen:
MovieClip.prototype.move = function(x, y, delay, ID) {
    var mc = this;
    clearInterval(mc["moveInt" + ID]);
    mc["moveInt" + ID] = setInterval(function () {
        // trace("Interval running for " + mc._name);
        mc._x += (-mc._x + x) / delay;
        mc._y += (-mc._y + y) / delay;
        if (Math.abs(Math.floor(-mc._x + x)) <= 1 && Math.abs(Math.floor(-mc._y + y)) <= 1) {
            clearInterval(mc["moveInt" + ID]);
            mc._x = Math.round(mc._x);
            mc._y = Math.round(mc._y);
            mc.broadcastMessage("onArrival", mc._name, mc._x, mc._y);
        }
    }, 10);
};
// --> receiver passt auf, wenn der MC schreit...
var receiver = new Object();
receiver.onArrival = function(who, x, y) {
    trace(who + " ist bei " + x + "/" + y + " angekommen");
    //--> mach ma noch eine Abfrage rein, dass eben nur fenster1 das fenster2 steuert
    //who == "fenster" ? fenster2.move(fenster2._x, 67, 12, 2) : null;
//leider funkt die zeile unten auch nicht so wirklich - ladet zwar aber total unkontrolliert
 
    //who == "fenster" ? "onArrival"(420, 60, 15, 1) & loadContent(_root.leer,"extern.swf") : null;
//ladet aber ich kann dann nicht pro link ein anderes swf einladen
    if(who == "fenster") _root.leer.loadMovie("extern.swf");
 
 
};
//--> der receiver wird bei den Fenstern angemeldet:
fenster.addListener(receiver);
fenster2.addListener(receiver);
fenster3.addListener(receiver);
//legt die Startposition der Fenster fest
fenster.move(420, 67, 10, 1);
fenster2.move(61, 67, 10, 2);
fenster3.move(465, 230, 10, 3);
//++++++++++++++++++++++++++++++++++Button-mc´s+++++++++++++++++++++++++++++++++++++
var dly = 15;
 
this.fenster3.btn1.onRelease = function() {
    fenster.move(420, 60, dly, 1);
    fenster2.move(61, -320, dly, 2);
    fenster3.move(465, 223, dly, 3);    
};
this.fenster3.btn2.onRelease = function() {
    fenster.move(420, 460, dly, 1);
    fenster2.move(61, -320, dly, 2);
    fenster3.move(465, 430, dly, 3);
};
this.fenster3.btn3.onRelease = function() {
    fenster.move(245, -100, dly, 1);
    fenster2.move(-230, 67, dly, 2);
    fenster3.move(290, 60, dly, 3);
};
this.fenster3.btn4.onRelease = function() {
    fenster.move(-250, 177, dly, 1);
    fenster2.move(270, 450, dly, 2);
    fenster3.move(315, 420, dly, 3);
};
this.fenster3.btn5.onRelease = function() {
    fenster.move(750, 177, dly, 1);
    fenster2.move(245, -320, dly, 2);
    fenster3.move(290, 60, dly, 3);
}; 

[romän]

wenn du die onRelease-Handler dynamisch setzt, kannst du zu dem Zeitpunkt auch das File bestimmen, das geladen werden soll:

this.fenster3.btn1.onRelease = function() {
fenster._file = "extern1.swf";
        fenster.move(420, 60, dly, 1);
        fenster2.move(61, -320, dly, 2);
        fenster3.move(465, 223, dly, 3);
};
this.fenster3.btn2.onRelease = function() {
fenster._file = "extern2.swf";
        fenster.move(420, 460, dly, 1);
        fenster2.move(61, -320, dly, 2);
        fenster3.move(465, 430, dly, 3);
};
// usw...
 
// und onArrival so umändern
receiver.onArrival = function(who, x, y) {
        trace(who + " ist bei " + x + "/" + y + " angekommen");
        if(who == "fenster") _root.leer.loadMovie(_root.fenster._file);
}; 

gruß,
roman

@anitchrist:

[das_sirius]

hey!! genial!!!

das funktioniert prima... 1000 dank für deine hilfe romän und dank auch an den halter des hundes mit der kettensäge