movieclips & "magnetische" abstoßung

[Thunderrace]

Hallo,
In meinem Flash-Film befinden sich mehrere movieclips. Diese lassen sich per drag&drop verschieben. Ich würde gerne realisieren, dass sich die mc's nicht berühren...d.h. unterschreitet ein mc einen definierten Mindestabstand, so soll er die anderen abstoßen.
Meine action-script Kenntnisse sind leider nicht sehr gut, deshalb meine Frage, ob jemand vielleicht schon einmal ein ähnliches Problem hatte oder ein passendes Tutorial kennt (konnte leider keines finden)...

[pape]

Quick & Dirty habe ich Dir das grad mal zusammengetippt:
Einfach neue Datei und ins erste Frame kopieren.

Wie gesagt quick&dirty, aber so haste schonmal nen Ansatz

PHP-Code:

var min_abstand = 5;
var breite:Number = 50;
var hoehe:Number = breite;
var anzahl:Number = 16;

var verteilung = Math.ceil(Math.sqrt(anzahl));
var abstandX:Number = (Stage.width-(breite*verteilung))/(verteilung+1);
var abstandY:Number = (Stage.height-(hoehe*verteilung))/(verteilung+1);
var max_annaeherung:Number = Math.max(breite, hoehe);
max_annaeherung = Math.sqrt(max_annaeherung*max_annaeherung*2)+min_abstand;


for(var i:Number = 0; i<anzahl; i++)
{
    var mc = make_mc(breite, hoehe, this, "mc"+i);
    mc._x = i%verteilung*(breite + abstandX)+abstandX;
    mc._y = Math.floor(i/verteilung)*(hoehe + abstandY)+abstandY;
    mc.onEnterFrame = function ()
    {
        check_nachbarn(this);
    }
    mc.onPress = function () {
        startDrag(this);
        _root.curr_active = this;
    }
    mc.onRelease = function () {
        stopDrag();
        delete _root.curr_active;
    }
}

function check_nachbarn(mc:MovieClip):Void
{

        var tmp:MovieClip;
        mitte_mc_x = mc._x+breite/2;
        mitte_mc_y = mc._y+hoehe/2;

    for(var i:Number = 0; i<anzahl; i++)
    {
        tmp = mc._parent["mc"+i];
        if (tmp == mc || tmp == _root.curr_active) continue;
        do {
            mitte_tmp_x = tmp._x+breite/2;
            mitte_tmp_y = tmp._y+hoehe/2;

            abstands_vektor_x = mitte_mc_x-mitte_tmp_x;
            abstands_vektor_y = mitte_mc_y-mitte_tmp_y;
                
            abstand_laenge = Math.sqrt(abstands_vektor_x*abstands_vektor_x + abstands_vektor_y*abstands_vektor_y);
            if (abstand_laenge<max_annaeherung)
            {
                tmp._x += tmp._x > mc._x ? 1: -1;
                tmp._y += tmp._y > mc._y ? 1: -1;
            }
        } while (abstand_laenge<max_annaeherung);
    }
}

function make_mc(w:Number, h:Number, tl:MovieClip, name:String):MovieClip
{
    var tmp:MovieClip = tl.createEmptyMovieClip(name, tl.getNextHighestDepth());
    tmp.beginFill(0xFF0000);
    tmp.moveTo(0, 0);
    tmp.lineTo(w, 0);
    tmp.lineTo(w, h);
    tmp.lineTo(0, h);
    tmp.lineTo(0, 0);
    tmp.endFill();
    return tmp;
} 


[Thunderrace]

Hallo Robert,
Vielen Dank für Dein Script! Wahnsinn!!!!

Ganz so aufwendig hätte es jedoch gar nicht sein müssen, weil die mc's sind bereits auf der bühne vorhanden. Ich würde diese dann lediglich mit mc1, mc2 etc benennen... das hieße, man müßte gar keine mc's generieren...

Ich habe versucht jetzt nur den unteren Teil deines Scripts zu verwenden:

function check_nachbarn(mc:MovieClip):Void
{

        var tmp:MovieClip;
        mitte_mc_x = mc._x+breite/2;
        mitte_mc_y = mc._y+hoehe/2;

    for(var i:Number = 0; i<anzahl; i++)
    {
        tmp = mc._parent["mc"+i];
        if (tmp == mc || tmp == _root.curr_active) continue;
        do {
            mitte_tmp_x = tmp._x+breite/2;
            mitte_tmp_y = tmp._y+hoehe/2;

            abstands_vektor_x = mitte_mc_x-mitte_tmp_x;
            abstands_vektor_y = mitte_mc_y-mitte_tmp_y;
                
            abstand_laenge = Math.sqrt(abstands_vektor_x*abstands_vektor_x + abstands_vektor_y*abstands_vektor_y);
            if (abstand_laenge<max_annaeherung)
            {
                tmp._x += tmp._x > mc._x ? 1: -1;
                tmp._y += tmp._y > mc._y ? 1: -1;
            }
        } while (abstand_laenge<max_annaeherung);
    }
}

function make_mc(w:Number, h:Number, tl:MovieClip, name:String):MovieClip
{
    var tmp:MovieClip = tl.createEmptyMovieClip(name, tl.getNextHighestDepth());
    tmp.beginFill(0xFF0000);
    tmp.moveTo(0, 0);
    tmp.lineTo(w, 0);
    tmp.lineTo(w, h);
    tmp.lineTo(0, h);
    tmp.lineTo(0, 0);
    tmp.endFill();
    return tmp;
}

Darauf haben die mc's auf der Bühne jedoch dann leider nicht mehr reagiert.
Wäre Dir für einen weiteren Tip sehr dankbar

[pape]

Hab Dir den Code mal kommentiert. Wie gesagt, ist er nicht sehr gut, sondern soll nur einen Ansatz darstellen. Einfach kopieren ist nicht
Bischen Eigeninitiative musst Du schon mitbringen, denn ein Forum ist nicht dafür gedacht "wie geht das? - programmier mir das mal jemand!".

function check_nachbarn(mc:MovieClip):Void
{
 
        var tmp:MovieClip;
//Mitte des mcs berechnen (kommt auf die Ausrichtung an, ggf hier korrigieren, wenn nicht oben links ausgerichtet)
        mitte_mc_x = mc._x+breite/2;
        mitte_mc_y = mc._y+hoehe/2;
//alle mcs durchlaufen (anzahl muss definiert sein (!) und angeben wieviele mcs es gibt)
    for(var i:Number = 0; i<anzahl; i++)
    {
        //Referenz auf den in diesem Durchlauf geprüften mc
        tmp = mc._parent["mc"+i];
        // Der mc wird nicht mit sich selbst geprüft (tmp==mc) oder falls er der aktive mc ist (aktiv war in meinem script der mc, der geklickt wurde.
        //Der sollte sich nämlich nicht bewegen, da er von der Maus gesteuert wird)
        if (tmp == mc || tmp == _root.curr_active)
                //gehe direkt zum nächsten Schleifendurchlauf und brich diesen hier ab.
                continue;
        do {
            //Berechne  die Mitte des aktuell betrachteten nachbarns
            mitte_tmp_x = tmp._x+breite/2;
            mitte_tmp_y = tmp._y+hoehe/2;
 
           //Abstand zwischen den Mitten der Mcs berechnen
            abstands_vektor_x = mitte_mc_x-mitte_tmp_x;
            abstands_vektor_y = mitte_mc_y-mitte_tmp_y;
 
            // Laenge des Abstandsvektors (bischen Vektorrechnen ;) )                
            abstand_laenge = Math.sqrt(abstands_vektor_x*abstands_vektor_x + abstands_vektor_y*abstands_vektor_y);
 
            //falls der Abstand zu gering ist (max_annaeherung gibt die maximale Annaeherung an.. muss natürlich auch definiert sein)
            if (abstand_laenge<max_annaeherung)
            {
                //dann bewege den nachbarn tmp vom mc weg
                //jenachdem ob nach (links oder rechts) und (oben oder unten) muss man +1 oder -1 rechnen.
                tmp._x += tmp._x > mc._x ? 1: -1;
                tmp._y += tmp._y > mc._y ? 1: -1;
            }
        //solange diese Schritte wiederholen, bis der Mc weit genug weg ist.
        } while (abstand_laenge<max_annaeherung);
    }
}