MovieClipLoader in einer Schleife

[skee]

hallo,
ich habe ein kleines problem mit MovieClipLoader.
Ich möchte 5 Bilder laden aber, leider schaffe ich es nur, das letzte Bild zu laden.Und für dieses wird auch die onLoadInit-Funktion aufgerufen, für die vorherigen aber nicht.
Ich vermute, dass ich hier für jedes Bild einen loader definieren muss, ich weiss aber nicht, wie das funktioniert.
Hier mal mein Code:

listener = new Object();
listener.onLoadInit = function(mc) {
trace(mc);
};
loader = new MovieClipLoader();
loader.addListener(listener);
  for (var i = 0; i<=4; i++) {
  img = _root.createEmptyMovieClip("thumb"+i, this.getNextHighestDepth());
  //trace("Schleife: thumb"+i);
  loader.loadClip("../img/kartenitems/"+i+".png", img);
  }

Wäre um jede Hilfe dankbar.

Skee

[SpecOps-12]

Du lädtst alle Bilder in "img". Img wird durch den loader-Content überschrieben.
Ich glaub zusätzlich auch nicht, dass die MovieClipLoader-Klasse mehrere loadClip-Operationen gleichzeitig ausführen kann.

PHP-Code:

import mx.utils.Delegate;

var home:MovieClip = this;
var mcLoader:MovieClipLoader;
var listener:Object;

// Container-Array für neu angelegte MovieClips:
var clipArray:Array;

var i:Number;

// Mehr oder minder Constanten
var pfad:String = "meineBilder/galerie1/";
var loaderArray:Array = new Array("bild1.jpg", "bild2.jpg", "bild3.jpg", "bild4.jpg", "bild5.jpg", "bild6.jpg");
var loaderArray_length:Number = loaderArray.length;

function initMovieClipLoader():Void {
    i = 0;
    clipArray = [];
    mcLoader = new MovieClipLoader();
    listener = new Object();
    mcLoader.addListener(listener);
    startLoading();
}

function startLoading():Void {
    listener.onLoadInit = Delegate.create(home, initHandler);
    listener.onLoadProgress = Delegate.create(home, progressHandler);
    loadNext();
}

function loadNext():Void {
    if (i<loaderArray.length) {
        clipArray.push(home.createEmptyMovieClip("bild"+i, home.getNextHighestDepth()));
        mcLoader.loadClip(String(pfad+loaderArray[i]),clipArray[i]);
        i++;
    } else {
        afterLoading();
    }
}

function initHandler(t:MovieClip):Void {
    loadNext();
}

function progressHandler(t:MovieClip, bL:Number, bT:Number):Void {
    var prozent:Number = Math.round(bL/bT*100);
    trace("prozent = "+prozent);
}

function afterLoading():Void {
    delete listener.onLoadInit;
    delete listener.onLoadProgress;
    mcLoader.removeListener(listener);
    trace("Laden abgeschlossen");
}

initMovieClipLoader(); 


Schau dir auch mal mein Tutorial zu Bildergalerien an. Ab Beispiel 3 wird gezeigt, wie man mehrere Bilder mit dem MovieClipLoader laden kann.