MovieClipLoader - Breite von externen Bild mit onLoadComplete auslesen

[djdwarf]

Hallo FF!


Ich erstelle gerade eine Gallery mit externen Bildern und bin durch das Forum auf den MovieClipLoader gestoßen. Leider scheint gerade dessen Vorteil bei mir irgendwie nicht zu klappen. Ich erhalte im onLoadComplete immer noch die Breite:0 wenn ich sie trace. Was läuft da falsch?

PHP-Code:


    i = 0;
        
        var mcl:MovieClipLoader = new MovieClipLoader ();
        var lstnr:Object = new Object();
        mcl.addListener(lstnr);
        
        
        function lade_gallery() {            
            _root.current_thumb = this.createEmptyMovieClip ("holder_mc_"+i, this.getNextHighestDepth ());
            mcl.loadClip (_root.file_pfad+gallery[i]['image'], _root.current_thumb);
        }
        
        lstnr.onLoadInit = function () {
            trace(i+" gestartet");
        };
        
        lstnr.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
            trace(Math.ceil((bytesLoaded/bytesTotal)*100)+"%"); 
        }
        
        lstnr.onLoadComplete = function(){
            trace(i+" fertig: "+_root.current_thumb);
            trace(i+" width: "+_root.current_thumb._width);
            trace(i+" height: "+_root.current_thumb._height);
            _root.current_thumb._x+=200*i;
            if (i+1 == gallery.length) {
                    // alle fertig
                    play();
                } else {
                    // nächsten laden
                    i++;
                    lade_gallery();
                }
        }

lade_gallery(); 


Wenn ich zwei Frames später nach der Breite frage, erhalte ich den korrekten Wert. Sollte das nicht aber durch den onLoadComplete abgefangen werden?

Generell scheint da noch irgendwas falsch zu laufen. Meine Trace-Ausgabe schaut wie folgt aus:

100%
0 fertig: _level0.instance143.holder_mc_0
0 width: 0
0 height: 0
1 gestartet
100%
1 fertig: _level0.instance143.holder_mc_1
1 width: 0
1 height: 0
2 gestartet
100%
2 fertig: _level0.instance143.holder_mc_2
2 width: 0
2 height: 0
3 gestartet
100%
3 fertig: _level0.instance143.holder_mc_3
3 width: 0
3 height: 0
3 gestartet

Fehlt da am Anfang nicht ein "0 gestartet" .. ? o.O


Vielleicht kann mir da ja jemand helfen.


Gruß,
Dwarf

Ich erhalte im onLoadComplete immer noch die Breite:0 wenn ich sie trace. Was läuft da falsch?

onLoadComplete bedeutet, dass nur das Laden abgeschlossen ist. Der MC muss aber nicht zwangsläufig befüllt sein, das ist genauso wie bei einem normalen loadMovie. Du musst also noch zusätzlich überprüfen, ob der MC eine Höhe/Breite größer 0 hat. Mit der MovieClipLoader-Klasse geht das ziemlich einfach, indem du einfach den onLoadInit auswertest.

[djdwarf]

Zitat von agedoubleju

onLoadComplete bedeutet, dass nur das Laden abgeschlossen ist. Der MC muss aber nicht zwangsläufig befüllt sein, das ist genauso wie bei einem normalen loadMovie. Du musst also noch zusätzlich überprüfen, ob der MC eine Höhe/Breite größer 0 hat.

Ach soo ... das hatte ich dann falsch verstanden. Danke!

Zitat von agedoubleju

Mit der MovieClipLoader-Klasse geht das ziemlich einfach, indem du einfach den onLoadInit auswertest.

nanu, da hatte ich dann ja einiges falsch verstanden. Dachte der onLoadInit bezieht sich auf den Start des Ladevorgangs. Aber tatsache .. mit:

PHP-Code:

lstnr.onLoadInit = function () {
            trace(i+" gestartet");
            trace(i+" object: "+_root.current_thumb);
            trace(i+" width: "+_root.current_thumb._width);
            trace(i+" height: "+_root.current_thumb._height);
        }; 


Erhalte ich meine Werte.

Dachte die Reihenfolge wäre:

onLoadInit -> onLoadProgress -> onLoadComplete

Versteh ich dann jetzt richig, dass es so korrekt ist:

onLoadProgress -> onLoadComplete -> onLoadInit

?


Danke für deine Hilfe!

Gruß,
Dwarf

[Mr.Twister]

onLoadInit() bekommt einen Parameter mit übergeben. Mit dem solltest du arbeiten:

MovieClipLoaderListener.onLoadInit = function(target:MovieClip):void {
    trace(target);
} 

So kannst du auch Fallunterscheidungen machen, wenn du den gleichen Listener mehrfach verwendest.

PS:API lesen erleichtert manchmal das Finden von Antworten.