Movieclip rotieren Tutorial

[Rudi Ratlos]

/*
Mit folgendem kleinen Tut könnt ihr MovieClips um ein gedachtes Zentrum, unabhängig vom
tatsächlichen Zentrum drehen.
Prinzipiell kann man das Zentrum eines MC ja bekanntlich nicht verändern. Allerdings ist es
natürlich möglich, festzustellen, wie weit sich ein Punkt bewegt, der vom Zentrum entfernt ist.
Das kann man sich zunutze machen, um die Position des MC zu korrigieren. 
Ich habe das hier mal am Beispiel der Rotation gemacht, mit zoomen geht's auch, man muß nur
die Berechnungen etwas anders gestalten. Mach ich vielleicht später mal...
*/
//Dreht Clip um gedachten Punkt
rotateClip = function(clip_mc, rotation_number, virtualX_number, virtualY_number) {
    //clip_mc       - der zu drehende Clip
    //rotation_number   - der Wert, der zur aktuellen Rotation addiert wird
    //virtualX_number   - x-Position des virtuellen Drehpunkts (im Koordinatensystem des Zielclips)
    //virtualY_number   - y-Position des virtuellen Drehpunkts (im Koordinatensystem des Zielclips)
    //1. virtuellen Drehpunkt vor Rotation sichern
    var oldVirtualX_number = clip_mc._x + Math.cos(clip_mc._rotation * Math.PI / 180) * virtualX_number - Math.sin(clip_mc._rotation * Math.PI / 180) * virtualY_number;
    var oldVirtualY_number = clip_mc._y + Math.sin(clip_mc._rotation * Math.PI / 180) * virtualX_number + Math.cos(clip_mc._rotation * Math.PI / 180) * virtualY_number;
    //2. Zielclip drehen
    clip_mc._rotation += rotation_number;
    //3. resultierende Position des virtuellen Drehpunkts ausrechnen
    var newVirtualX_number = clip_mc._x + Math.cos(clip_mc._rotation * Math.PI / 180) * virtualX_number - Math.sin(clip_mc._rotation * Math.PI / 180) * virtualY_number;
    var newVirtualY_number = clip_mc._y + Math.sin(clip_mc._rotation * Math.PI / 180) * virtualX_number + Math.cos(clip_mc._rotation * Math.PI / 180) * virtualY_number;
    //Tatsaechlichen Drehpunkt dementsprechend verschieben
    clip_mc._x -= newVirtualX_number - oldVirtualX_number;
    clip_mc._y -= newVirtualY_number - oldVirtualY_number;
    
    
    //Zum testen, den virtuellen Punkt sichtbar machen
    this.attachMovie("test", "test2", 1);
    this["test2"]._x = oldVirtualX_number;
    this["test2"]._y = oldVirtualY_number;
};
 
 
 
 
//Funktion testen (benoetigt mc auf der Buehne - test_mc)
test_mc.onRelease = function() {
    //Irgendein Punkt
    //rotateClip(test_mc, 10, 140, 80);
    //Punkt ausserhalb des MC
    //rotateClip(test_mc, 10, -40, -100);
    //Ecke oben links
    //rotateClip(test_mc, 10, -40, -20);
    //Logische Mitte
    //rotateClip(test_mc, 10, 60, 40);
    //Mitte dynamisch ermitteln (ist etwas umständlich - vielleicht habt ihr ja was einfacheres auf Lager?)
    rotateClip(test_mc, 10, (test_mc.getBounds(this).xMax - test_mc.getBounds(this).xMin) / 2 + test_mc.getBounds(this).xMin, (test_mc.getBounds(this).yMax - test_mc.getBounds(this).yMin) / 2 + test_mc.getBounds(this).yMin);
}; 

Ein kleines Dankeschön ans Flashforum von mir,

RR

[~pyropete~]

Haste net gerade noch nen Link wo man sich's mal angucken kann?

--pp

[Rudi Ratlos]

Kopier den Code einfach in einen Film. Du brauchst nur einen Clip zum Testen pinseln...

RR

[marc]

Packe es direkt in die Tutorials. Danke dir!

[~pyropete~]

Zitat von Rudi Ratlos

Kopier den Code einfach in einen Film. Du brauchst nur einen Clip zum Testen pinseln...

RR

Ok, schon ganz nett.

--pp

[salazar]

sehr praktisch! danke für die bereitstellung des scripts
cya, sal

[honifred]

super! wird jede woche bestimmt einmal danach gefragt. jetzt brauch ich nur den link zu booken

danke!

[pape]

nette sache
weiter so!

pape

[Marlboro]

Habe an was ähnlichem recht lange gekaut...

dankeschön, so muss ich schon net fragen!

[toohardforme]

und wie schaff ichs das sich das ding von alleine dreht - ohne onclipevent?!

[salazar]

Zitat von toohardforme

und wie schaff ichs das sich das ding von alleine dreht - ohne onclipevent?!

also ohne onEnterFrame schleife oder vergleichbares wird es wohl kaum funktionieren! was haste denn vor?

cya, sal

[kurthurtig]

sodele habs mal versucht, damit es sich von allein dreht.

habe das onRelease in ein onPress geändert: funktioniert
habe ein onEnterFrame eingefügt:

rotateClip.onEnterFrame = function(clip_mc, rotation_number, virtualX_number, virtualY_number) {
...
} 

klappt nicht. was mach ich falsch?

edit:
habe auch versucht eine zweite funktion reinzuschreiben:

rotateClip = function(clip_mc, rotation_number, virtualX_number, virtualY_number) {
rotate.onEnterFrame = function() {
...
}
} 

geht auch nicht

edit²:
habe es jetzt so hinbekommen, dass ich beim aufrufen den enterFrame mache. dann klappts. aber warum funktioniert es andersrum nicht?!?

[odyssee]

Zitat von kurthurtig

edit²:
habe es jetzt so hinbekommen, dass ich beim aufrufen den enterFrame mache. dann klappts. aber warum funktioniert es andersrum nicht?!?

Ich bin mir nicht ganz sicher, ob ich deine Frage richtig verstanden habe, aber meiner Meinung nach ist dies Script nach dem du suchst:

test_mc.onRelease = function() {
// Automatisches Drehen
this.onEnterFrame = function(){
rotateClip(test_mc, 10, 140, 80);
}
};

Wenn du willst, dass sich der Clip dreht, ohne das du diesen vorher klicken musst, damit er sich dreht, sieht das Script wie folgt aus:

test_mc.onEnterFrame = function(){
rotateClip(this, 10, 140, 80);
}

Hoffe, dass dies dir weiterhilft.
Odyssee

[Koronki]

vielen Dank für dieses Tutorial, kann ich wunderbar für mein kleines Ratespiel mit Figur gebrauchen