mit createEmptyMovieClip erstelltes mc auf knopfdruck sliden lassen

[SmoothCriminal]

hallo íhr...
also ich habe ein problem...is ja klar.. und zwar erstelle ich ein kartenspiel.
in mein swf lade ich zuerst die karten von einer php seite
die gibt ungefähr sowas aus: karten=ro/4.gr/2 und so weiter..
diese karten werten unten am rand der reihe nach aufgelistet.. als bilder
außerdem übergebe ich jeder karte eine funktion sodas die karte beim drübergehen nach oben geht und bei rollout wiedre nach unten geht..
das funzt auch alles wunderbar...
nur leider bekomme ich es nicht hin dass die karte beim draufklicken aus dem bildschirm slidet...
bitte helft mir

function kartenladen() {
    var AX = new LoadVars();
    AX.anweisung = "karten";
    AX.sendAndLoad("fkarten.php?cache="+Math.random(), AX, "POST");
    AX.onLoad = function() {
        if (this.karten != undefined) {
            var kart = this.karten;
            var karten = kart.split(".");
//karten ist nun ein array und jetzt erstelle ich für jede karte ein mc und lade ein bild hinein
            for (i=0; i<karten.length; i++) {
                var hilfs = karten[i].split("/")[1];
                if (hilfs != undefined) {
                    var zahl = karten[i].split("/")[1];
                    var farbe = karten[i].split("/")[0];
                } else {
                    var farbe = "";
                    var zahl = karten[i];
                }
                _root.hand.createEmptyMovieClip("karte"+i, i);
                _root.hand["karte"+i]._x = 10+(50*(i));
                _root.hand["karte"+i]._y = -70;
                _root.hand["karte"+i].createEmptyMovieClip("karterand", 2);
                _root.hand["karte"+i].karterand.loadMovie("rand.swf?cache="+Math.random());
                _root.hand["karte"+i].createEmptyMovieClip("karteinnen", 1);
                _root.hand["karte"+i].karteinnen._x = 3;
                _root.hand["karte"+i].karteinnen._y = 2;
                _root.hand["karte"+i].karteinnen.loadMovie("karten/"+farbe+zahl+".jpg");
// wenn die karte nicht bedient werden darf wird sie nach unten gerutscht.. aber das ist erst mal uninteressant
                if (farbe == this.bedienen or zahl == "Z" or zahl == "N") {
                    kartebewegen(i);
                } else {
                    _root.hand["karte"+i]._y = -30;
                }
            }
        }
    };
}
function kartebewegen(i) {
    this.i = i;
    _root.hand["karte"+i].onRelease = function() {
        //so und an diese stelle sollte nun die slide funktion
    };
    _root.hand["karte"+i].onRollOver = function() {
        _root.hand["karte"+i]._y = -140;
    };
    _root.hand["karte"+i].onRollOut = function() {
        _root.hand["karte"+i]._y = -70;
    };
}      
kartenladen(); 

danke schonmal

[Der Frager]

Hallo!
Wo sollen die denn hinsliden? Einfach aus dem Bildschirm raus? Rechts oder links?

[Der Frager]

Gut, dann gehe ich mal von rechts aus...

var sw = Stage.width;
_root.hand["karte"+i].onRelease = function() {
    this.onEnterFrame = function() {
        if (Math.round(this._x)<sw) {
            this._x += (sw-this._x)/2;
        } else {
            removeMovieClip(this);
        }
    };
}; 

[SmoothCriminal]

das is ja toll

na wie ich mich eben gefreut habe... sag mal ... das is ja tolll danke schön......

[Der Frager]

Bitte! Also klappt's anscheinend .

[SmoothCriminal]

duhuuuu.....

geht das auch langsamer??

und der makel ist das das wenn das mc die maus verlässt wieder kurz zurück hüpft ... ach so es soll nach oben weg sliden....

aber sonst funzt es gut ich mein ich hab das ja schon jetz selber noch rumgebogen das es nach oben slidet...

[Der Frager]

So?

_root.hand["karte"+i].onRelease = function() {
    delete this.onRollOver;
    delete this.onRollOut;
    this.onEnterFrame = function() {
        if (Math.round(this._y+this._height)>0) {
            this._y -= (this._y+this._height)/5;//Je höher die Zahl hier (5), desto langsamer geht's
        } else {
            removeMovieClip(this);
        }
    };
}; 

[SmoothCriminal]

ja genau so wollte ich das haben ....

danke... üprigens gucke ich auch immer columbo... und der name passt ... also "frager"