menue ausfahren

[TeeRackz]

moinsen,
Baue grad ein Menü aus sieben schaltflächen.
Bei Klick auf eine Schaltfläche sollen die in der _y höhe darunter liegenden schaltflächen nach unten fahren, um ein untermenü freizugeben.
Wenn schon ein anderes Untermenue geöffnet ist, soll sich dieses schliessen, indem die entsprechenden Schaltflächen wieder hochfahren.
Mache das grade sehr umständlich über mehrere Abfragen.

Das Script fragt bei onPress ab, ob der darunterliegende mc bereits ausgefahren ist, wenn nicht fährt dieser nach unten bis der untere Rand der y-höhe des darüberliegenden mcs erreicht ist. Anschliessend werden alle anderen schaltflächen abgefragt, ob diese 20px unter der jeweils darüberliegenden schaltfläche liegen. wenn nicht fährt der entsprechende mc solange hoch, bis er 20 pixel unter der darüberliegenden schaltfläche ist.

dieses script liegt auf allen Schaltflächen mit der Änderung der jeweiligen Namen. Im Ergebnis fährt der zweite Btn runter und legt das erste Untermenue frei. Bei allen anderen Btns funktioniert es nicht
Hoffe das script und mein problem ist verständlich formuliert. gerne würde ich das script auch straffen.

[TeeRackz]

hier das script

PHP-Code:

on (press) {
    this._parent.onEnterFrame = function() {
        if (this.mc2._y<this.mc1._y+this.mc1._height) {
            this.mc2._y = Math.round(this.mc2._y+this.mc2._y*0.1);
        }
        if (this.mc3._y>this.mc2._y+20) {
            this.mc3._y = Math.round(this.mc3._y-this.mc3._y*0.1);
        } else {
            this.mc3._y = this.mc2._y+20;
        }
        if (this.mc4._y>this.mc3._y+20) {
            this.mc4._y = Math.round(this.mc4._y-this.mc4._y*0.1);
        } else {
            this.mc4._y = this.mc3._y+20;
        }
        if (this.mc5._y>this.mc4._y+20) {
            this.mc5._y = Math.round(this.mc5._y-this.mc5._y*0.1);
        } else {
            this.mc5._y = this.mc4._y+20;
        }
        if (this.mc6._y>this.mc5._y+20) {
            this.mc6._y = Math.round(this.mc5._y-this.mc5._y*0.1);
        } else {
            this.mc6._y = this.mc5._y+20;
        }
        if (this.mc7._y>this.mc6._y+20) {
            this.mc7._y = Math.round(this.mc6._y-this.mc6._y*0.1);
        } else {
            this.mc7._y = this.mc6._y+20;
        }
        if (this.mc8._y>this.mc7._y+20) {
            this.mc8._y = Math.round(this.mc6._y-this.mc7._y*0.1);
        } else {
            this.mc8._y = this.mc7._y+20;
        }
    };
    trace(this._height);
} 


[pape]

hi!

poste mal bitte deine fla (als mx), oder ne beispiel fla.. nur mit dem code kann ich nicht viel anfangen...
aber um deinen code zu kürzen würde ich dir ne for schleife empfehlen:

on (press) {
    this._parent.onEnterFrame = function() {
        if (this.mc2._y<this.mc1._y+this.mc1._height) { 
            this.mc2._y = Math.round(this.mc2._y+this.mc2._y*0.1); 
        } 
        for (i=2; i<anz; i++) {
            if (this["mc"+i]._y<this.mc1._y+this["mc"+(i-1)]._height) {
                this["mc"+i]._y = Math.round(this["mc"+i]._y+this["mc"+i]._y*0.1);
            } else {
                this["mc"+i]._y = this["mc"+(i-1)]._y+20;
            }
        }
    };
    trace(this._height);
} 

grz
Robert

[TeeRackz]

Hi Robert, Fla poste ich gleich.
Danke für Dein Script
Sowas schwebte mir auch schon vor. Nur gibts bei dieser for-schleife ein Prob.
Für den ersten Button funktioniert das bestens, der Zweite hätte aber folgendes Script

PHP-Code:

on (press) { 
this._parent.onEnterFrame = function() { 
if (this.mc3._y<this.mc2._y+this.mc2._height) { 
this.mc3._y = Math.round(this.mc3._y+this.mc3_y*0.1); 
} 
} 


die For-Schleife sähe so aus

PHP-Code:

*for (i=3; i<anz; i++) { 
if (this["mc"+i]._y<this.mc2._y+this["mc"+(i-1)]._height) { 
this["mc"+i]._y = Math.round(this["mc"+i]._y+this["mc"+i]._y*0.1); 
} else { 
this["mc"+i]._y = this["mc"+(i-1)]._y+20; 
} 
} 


Problem ist:
jetzt wird mc1 nicht mehr abgefragt und somit kann sich mc2 nicht positionieren, die Nummern der anzusprechenden mcs sind nicht fortlaufend i[1,3,4,5,6,7] und bei button drei wäre i[1,2,4,5,6,7] usw… kann man for-schleifen unterbrechen, oder sollte ich für jeden Button einen Array festlegen aus dem die einzelnen werte nacheinander i zugeordnte werden?
wie würde sowas mit arrays gehen?
wissensdurstiger AS-Anfänger wartet auf antwort.
Gruss,
Tee

[pape]

hi!
ich warte besser auf die fla, bevor ich weiteres sage, denn ich kann irgrndwie grade nicht nachvollziehen was du meinst...
aus einer for schleife kommst du mit break; raus!

bsp:

anz = 5;
for (i=1;i<anz;i++) {
    trace(i);
    if(i==3) {
        break;
    }
}
 
trace("fertig");
//ausgabe:
1
2
3
fertig 

[TeeRackz]

hier die fla,
nicht erschrecken
die scripte liegen auf den dreiecken im kreis.
bisher nur für button eins und zwei (sind zwei verschiedene scripte)
die buttons liegen in der dritten tiefen ebene. wenn du diese fla testes siehst bestimmt sofort was ich bezwecken will (und leider auch den mir unerklärlichen fehler )
Gruss,
Tee

[pape]

Zitat von pape

deine fla (als mx), oder ne beispiel fla

->unerwartetes datei format...

[TeeRackz]

ups, sorry,
hier die mxer

Edit: gelöscht und weiter unten ne bereinigte abgelegt

[pape]

hmm.. ichblick noch nicht durch die stuktur durch, sorry...

was macht

var erste;
if (erste=1) {
    this.onEnterFrame = function() {
        if (this.B._y<this.A._y+this.A._height) {
            this.B._y += 2;
        }
    };
} 

naja.. was es macht ist klar, aber wo werden A und B bzw erste gesetzt?
und was soll

this._parent.rusty(this);
this._parent._parent.mc_vorhang.gotoAndPlay(2);
this._parent._parent.mc_vorhang.lader = [this._name+".swf"]; 

bezwecken?...hmmm

[TeeRackz]

Zitat von pape

hmm.. ichblick noch nicht durch die stuktur durch, sorry...

was macht

var erste;
if (erste=1) {
    this.onEnterFrame = function() {
        if (this.B._y<this.A._y+this.A._height) {
            this.B._y += 2;
        }
    };
} 

hmm das sind noch reste von meinen versuchen, ist bereinigt

naja.. was es macht ist klar, aber wo werden A und B bzw erste gesetzt?
und was soll

this._parent.rusty(this);
this._parent._parent.mc_vorhang.gotoAndPlay(2);
this._parent._parent.mc_vorhang.lader = [this._name+".swf"]; 

bezwecken?...hmmm

Das sind die Unterpunkte, die andere swfs in einen container laden. die button_instanzen heissen genau wie die swfs. mc_vorhang ist ne blende zwischen den einzelnen ladevorgängen. rusty(this) ruft ne funktion auf die aber nicht mehr vorhanden ist(reste von einer alten menueversion, ne art vertikales yugop. der guet rusty hatte mir damals ein wenig unter die Arme gegriffen)…… Ist aber für dieses Problem nicht wichtig.
Mir geht es um die Ebene darüber (das hoch und runterfahren der Oberpunkte). und die scripte die auf den kleinen dreiecken liegen und diese bewegung steuern sollen.
hab hier nochmal ne bereinigte version als mxer

[pape]

so.. nach keine ahnung wieviel zeit, habe ich jetzt ne function für dich zusammengeschustert bekommen:

lösche alle buttonscripts ( von den buttons zum ausfahren)!

die kriegen nämlich alle die selbe aktion und das kann man dann auch bequem in ner for schleife von der zeitleiste aus machen (siehe script/fla)!

2 functions : eine zum einfahren und eine zum ausfhren

die functions sind nicht großartig noch mal durchgeguckt und optimiert!
aber sie funktionieren, soweit ich das getestet habe!

biddöö:

anzahl = 7; //anzahl an buttons
speed = 5; //Aus-/Einfahrgeschwindigkeit
abstand = 20; //abstand der buttons im eingefahrenen zustand
 
for (var i = 1; i<=anzahl; i++) {
    this["mc"+i]["menue"+i].onPress = function () {
        this._parent._parent.ausfahren(this._parent);
    }
}
 
function ausfahren (abmc) {
    if (this.ausgefahrenermc) {
        if (abmc == this.ausgefahrenermc) {
            this.einfahren(abmc);
        } else {
            einfahren(this.ausgefahrenermc);
            this.neuen_ausfahren = abmc;
        }
    } else if (!this.amausfahren) {
        this.amausfahren = true;
        var mc_nr = Number(String(abmc).slice(-1));
        trace("es wurde mc"+mc_nr+" an geklickt");
        this.createEmptyMovieClip("ausfahrer", 1964);
        ausfahrer.onEnterFrame = function () {
            var o = this._parent;
            if (o["mc"+(mc_nr+1)]._y<abmc._y+abmc._height) {
                for (i=mc_nr+1; i<=anzahl+1; i++) {
                    o["mc"+i]._y += speed;
                }
            } else {
                delete this.onEnterFrame;
                o.ausgefahrenermc = abmc;
                o.amausfahren = false;
                this.removeMovieClip();
            }
        }
    }
}
 
function einfahren (abmc) {
    var mc_nr = Number(String(abmc).slice(-1));
    this.createEmptyMovieClip("einfahrer", 1964);
    einfahrer.onEnterFrame = function () {
        var o = this._parent;
        if (this._parent["mc"+(mc_nr+1)]._y>abmc._y+abstand) {
            for (i=mc_nr+1; i<=anzahl+1; i++) {
                this._parent["mc"+i]._y -= speed;
            }
        } else {
            delete this.onEnterFrame;
            delete o.ausgefahrenermc;
            if (o.neuen_ausfahren) {
                ausfahren(o.neuen_ausfahren);
                delete o.neuen_ausfahren;
            }
            this.removeMovieClip();
        }
    }
}
 
stop(); 

wenn du fragen hast dann frag einfach!

Gruß,
Robert

Edit:
mir ist schon was aufgefallen was überflüssig ist *gg*:

die erste if abfrage im einfahren script kann komplett raus!

habe die fla und das script aktualisiert (also so wie es jetzt da steht ists richtig!)

edit2: noch was kann raus
auch in der einfahren function:

ameinfahren = true;
//...und
o.ameinfahren = false; 

einfach löschen

habe die fla und das script aktualisiert...!

[TeeRackz]

ohmann was soll ich da noch sagen? *dankendhändeschüttel*
skål
wenn ich die scripte sehe wird mir alles klar was da passiert, aber selber sowas konstruieren peil ich noch nicht.
kurzer check: 1964 ist die z-ebene in der du den neuen mc createst um genug puffer beim runterzählen zu haben oder? //
mmmhhh, jetzt ist es ja so das ein menue einfährt , anschliessend fährt das nächste aus. wie könnten beide vorgänge parallel ablaufen? also noch während das eine einfährt, fährt das andere aus.

[pape]

Zitat von TeeRackz

kurzer check: 1964 ist die z-ebene in der du den neuen mc createst um genug puffer beim runterzählen zu haben oder?

ja! das ist ne x belibige zahl.. sollte nicht zu klein sein..

da fällt mir ein, dass es besser wäre beim ein (oder aus is egal) fahren script den mc auf 1965 (oder jedenfalls woanders) hinzulegen!
habe ich vergessen da ich die eine function per copy&past und dann leicht abwandeln erstellt habe ...grml... muss ich wohl besser aufpassen...hmm

Zitat von TeeRackz

mmmhhh, jetzt ist es ja so das ein menue einfährt , anschliessend fährt das nächste aus. wie könnten beide vorgänge parallel ablaufen? also noch während das eine einfährt, fährt das andere aus.

das habe ich eben auch überlegt, abe mir ist dazu irgendwie nicht direkt was eingefallen und dann habe ich es so gemacht!
Ich denk jetzt noch mal drüber nach und falls mir was einfällt sage ich dir natürlcih bescheid!

bis dann
Robert

[TeeRackz]

hey robert,
besten dank erstmal. wenn ich das von der theorie richtig überblicke, dann hängt die abfrage ob der einzufahrene mc schon eingefahren ist in einer schleife fest bis diese bedingung erfüllt ist, erst dann wird dem auszufahrendem mc mitgeteilt solange auszufahren bis seine grenzbedingung erreicht ist. oder ist das nonsense?
Tee

[pape]

ja das ist richtig!

ersetz mal das script oder lad dir die (bald - wiel das grade nicht funktioniert ) angehängte fla runter!

is eigentlich recht easy mit dem glechzeitig ein und ausfahren

anzahl = 7; //anzahl an buttons
speed = 5; //Aus-/Einfahrgeschwindigkeit
abstand = 20; //abstand der buttons im eingefahrenen zustand
 
for (var i = 1; i<=anzahl; i++) {
    this["mc"+i]["menue"+i].onPress = function () {
        this._parent._parent.ausfahren(this._parent);
    }
}
 
function ausfahren (abmc) {
    if (this.ausgefahrenermc) {
        if (abmc == this.ausgefahrenermc) {
            this.einfahren(abmc);
        } else {
            einfahren(this.ausgefahrenermc);
        }
        delete this.ausgefahrenermc;
    } if (!this.amausfahren) {
        this.amausfahren = true;
        var mc_nr = Number(String(abmc).slice(-1));
        trace("es wurde mc"+mc_nr+" an geklickt");
        this.createEmptyMovieClip("ausfahrer", 1964);
        ausfahrer.onEnterFrame = function () {
            var o = this._parent;
            if (o["mc"+(mc_nr+1)]._y<abmc._y+abmc._height) {
                for (i=mc_nr+1; i<=anzahl+1; i++) {
                    o["mc"+i]._y += speed;
                }
            } else {
                delete this.onEnterFrame;
                o.ausgefahrenermc = abmc;
                o.amausfahren = false;
                this.removeMovieClip();
            }
        }
    }
}
 
function einfahren (abmc) {
    var mc_nr = Number(String(abmc).slice(-1));
    this.createEmptyMovieClip("einfahrer", 1965);
    einfahrer.onEnterFrame = function () {
        var o = this._parent;
        if (this._parent["mc"+(mc_nr+1)]._y>abmc._y+abstand) {
            for (i=mc_nr+1; i<=anzahl+1; i++) {
                this._parent["mc"+i]._y -= speed;
            }
        } else {
            delete this.onEnterFrame;
            this.removeMovieClip();
        }
    }
}
 
stop(); 

grz

Edit:
klene anmerkung:
hier bei ist es jetzt auch sehr wichtig, dass die einfahr und ausfahr mcs auf iunterschiedlichen tiefen liegen, da sonst der ausfahrer den einfarer ü+berschreibt und nicht zueinde eingefahren wird^^..das wollen wir ja nicht