mc wird nicht angezeigt

[helpmeplease]

hallo,

ich sehe hier keine fehler - dennoch wird der mc nicht angezeigt:

PHP-Code:

this.createEmptyMovieClip(mymc, this.getNextHighestDepth());
this.mymc._x = 50;
this.mymc._y = 50;
this.mymc._width = 50;
this.mymc._height = 50;
this.mymc.opaqueBackground = 0xFF0000; 


bedanke mich für jeden hinweis ...

[mildesign]

vermutlich ist die _width und _height immernoch 0 da sich nichts im MC befindet. Also wird logischerweise nichts angezeigt.

Zeichne ein Rechteck mit der drawing API in den mc dann sollte das gehen

[mildesign]

Ergänzung

PHP-Code:

this.createEmptyMovieClip(mymc, this.getNextHighestDepth()); 


in

PHP-Code:

this.createEmptyMovieClip("mymc", this.getNextHighestDepth()); 


umwandeln

[helpmeplease]

also das mit dem mymc hab ich nicht genau dargestellt; mymc ist eine variable die gefüllt wird deshalb ohne anführungszeichen - so schaut es aus - ich lade jetzt auch ein bild - dennoch kein mc zu sehen

mymc = "myMC" + XMLdaten_id[i];
trace(mymc);
			
this.createEmptyMovieClip(mymc, this.getNextHighestDepth());
this.mymc._x = 50;
this.mymc._y = 50;
this.mymc._width = 50;
this.mymc._height = 50;
this.mymc.loadMovie("test.jpg");

kann mir bitte nochmal jemand drüberschauen - ich kapier es nicht wieso da nix angezeigt wird. kann ich irgendwie testen ob der mc existiert?

[mildesign]

*drüberschau*

PHP-Code:

mymc = "myMC" + XMLdaten_id[i];
trace(mymc);
            
this.createEmptyMovieClip(mymc, this.getNextHighestDepth());
this[mymc]._x = 50;
this[mymc]._y = 50;
this[mymc]._width = 50;
this[mymc]._height = 50;
this[mymc].loadMovie("test.jpg"); 


Allerdings wird deine Größe bei loadmovie ignoriert dh das Bild wird mit 100% angezeigt da es den bisherigen Inhalt des MC überschreibt.

du kannst auch eine Variable mit der Referenz auf das Object verwenden. das spart Tipparbeit

PHP-Code:

var t:MovieClip = createEmptyMovieClip(mymc, this.getNextHighestDepth());
t._x=50;
... 


[helpmeplease]

hallo mildesign,

ich hoffe du hast nochmal geduld mit mir - jetzt poste ich doch den ganzen part:

PHP-Code:

this.createEmptyMovieClip("tester", this.getNextHighestDepth());
this.tester._x = 50;
this.tester._y = 50;
this.tester.loadMovie("test.jpg");


var XMLdaten = new XML();
XMLdaten.ignoreWhite = true;
XMLdaten.load("data.xml");
XMLdaten.onLoad = function(success) {
    
    XMLdaten_id = [];
    XMLdaten_namen = [];
    XMLdaten_images = [];
    
    if (success) {
        
        for (var i=0; i<XMLdaten.firstChild.childNodes.length; i++) {
            XMLdaten_id[i] = XMLdaten.firstChild.childNodes[i].attributes.id;
            XMLdaten_namen[i] = XMLdaten.firstChild.childNodes[i].attributes.name;
            XMLdaten_images[i] = XMLdaten.firstChild.childNodes[i].attributes.image;
            
            trace(XMLdaten_id[i]);
            trace(XMLdaten_namen[i]);
            
            mymc = "myMC" + XMLdaten_id[i];
            trace(mymc);
            
            this.createEmptyMovieClip(mymc, this.getNextHighestDepth());
            this[mymc]._x = 50;
            this[mymc]._y = 50;
            this[mymc]._width = 50;
            this[mymc]._height = 50;
            this[mymc].loadMovie("test.jpg");
        }
    
    }
} 


also wenn ich den movieclip ausserhalb der for schleife mache wird er generiert - innerhalb der schleife sehe ich keinen

dann bedank ich mich nochmal "sakrisch" im voraus ...

[mildesign]

this bezieht sich in der onLoad Function aus das XML Object und nicht auf die HZL.

PHP-Code:

var HZL:MovieClip = this // refernz auf die Hauptzeitleiste somit wird _root vermieden
this.createEmptyMovieClip("tester", this.getNextHighestDepth()); 
this.tester._x = 50; 
this.tester._y = 50; 
this.tester.loadMovie("test.jpg");

...
HZL.createEmptyMovieClip(mymc, this.getNextHighestDepth()); 
            HZL[mymc]._x = 50; 
            HZL[mymc]._y = 50; 


[helpmeplease]

wie gesagt ich bedank mich "sakrisch" - damit geht es bzw. jetzt weiss ich endlich warum und wieso - da tu ich jetzt schon 2 stunden herum?

danke!!