MC under Mouse?

[seborg]

ahoj,

gibe es eine möglichkeit herauszufinden, welcher movieclip sich gerade unter dem cursor befindet? und wenn es mehrere sind, denn den, der über allen anderen liegt? ist das irgendwie eingebaut oder muss ich mir das selbst schreiben indem ich durch alle ebenen aller MCs loope und per hittest abfrage, ob jemand unter dem cursor liegt, oder so?

gruss
sebastian

[bloba]

mach doch ne _xmouse abfrage

[v0id]

oder wie wärs mit nem onRollOver?

[HAY]

hi
oder mach halt auf alle mc die du testen willst ein

mc0.onRollOver = function() {
    trace(this._name)
} 

gruss harry

[seborg]

hmm, ich habe das wohl nicht gut erklärt:

ich bin irgendein movieclip. mit mir zusammen liegen noch beliebig viele movieclips auf der bühne die neben mir, über mir oder unter mir liegen können. auf die programmierung dieser clips habe ich keinen einfluss (mein mitprogrammierer würde mich töten ;-) wenn der benutzer die maus bewegt will ich herausfinden, über welchem movieclip der cursor ist. wenn mehrere, an der stelle wo gerade der cursor ist, übereinander liegen, will ich wissen, welcher von denen zuoberst liegt. ich fürchte, das muss ich mir selbst programmieren, was?

gruss
sebastian

[bloba]

da sollte getDepth helfen um raus zufinden wo er liegt

[seborg]

ich glaube, so gehts:

Movieclip.prototype.mcUnderMouse = function() {
    var topmost = Number.NEGATIVE_INFINITY;
    var topmc = null;
    for (i in this) {
        if(typeof(this[i]) == "movieclip") {
            var mc = this[i];
            if(mc.hitTest(_root._xmouse, _root._ymouse, true)) {
                var depth = mc.getDepth();
                if(depth > topmost) {
                    topmost = depth;
                    topmc = mc;
                    //wenn mc auch aus mehreren mcs besteht, den obersten von denen nehmen
                    var tempmc = mc.mcUnderMouse();
                    if(tempmc != null) {
                        topmc = tempmc; 
                    }
                }
            }
        }
    }
    return topmc;
}; 

den zuallerobersten kriegt man dann mit

trace(_root.mcUnderMouse()); 

alles ohne gewähr, das ist ziemlich schnell zusammengehackt.

gruss
sebastian

[seborg]

noch ne kleine verbesserung um unendliche rekursionsschleifen zu verhindern, die bei einigen pathologischen umständen auftreten können....

//is this a _parent or _parent._parent etc of in_mc
Movieclip.prototype.isAncestorOf = function(in_mc) {
    if(in_mc == null || in_mc == undefined) {
        trace("in_mc is not valid in Movieclip.isAncestorOf()");
        return false;
    }
    var s1 = this._target;
    var s2 = in_mc._target; 
    return s2.indexOf(s1, 0) == 0;
};
 
/***********************************************/
//                                            //
// get the topmost movieclip under the mouse //
//                                          //
/******************************************/
Movieclip.prototype.mcUnderMouse = function() {
    trace("Movieclip.prototype.mcUnderMouse "+this);
    var topmost = Number.NEGATIVE_INFINITY;
    var topmc = null;
    for (i in this) {
        if(typeof(this[i]) == "movieclip") {
            var mc = this[i];
            if(!mc.isAncestorOf(this)) {
                if(mc.hitTest(_root._xmouse, _root._ymouse, true)) {
                    var depth = mc.getDepth();
                    if(depth > topmost) {
                        topmost = depth;
                        topmc = mc;
                        //wenn mc auch aus mehreren mcs besteht, den obersten von denen nehmen
                        var tempmc = mc.mcUnderMouse();
                        if(tempmc != null) {
                            topmc = tempmc;
                        }
                    }
                }
            }
        }
    }
    return topmc;
};