MC abbremsen?!

[maxbahr01]

Hallo hab ´n kleines Problem und zwar möchte ich meine MC von A nach B bewegen wobei er zum Schluss hin abbremsen soll und abrubt stoppen.
Hatte auch schon mal jemanden von euch gefragt der mich auf ne andere Flashsite verwiesen hatte wo einige Scripte waren, leider konnte ich mit denen nich so recht wat anfangen. Das Script für die Bewegung des MC ist angefügt. Schauts euch mal an.
Wäre für jede Hilfe dankbar.

onClipEvent(load) {
    this._x = -320;
    this._y = 200;
}
onClipEvent(enterFrame) {
    if (this._x<220) {
        this._x +=20;
    }
    if (this._y<340) {
        this._y +=20;
    }
} 

[Der Frager]

onClipEvent(load) {
        this._x = -320;
        this._y = 200;
}
onClipEvent(enterFrame) {
        if (this._x<220) {
                this._x +=(220-this._x)/5;
        }
        if (this._y<340) {
                this._y +=(340-this._y)/5;
        }
} 

Ich würde das allerdings vom Clip runternehmen, da man sonst das (enterFrame) nicht löschen kann. Das verbraucht dann unnütz Rechenleistung.

[Cysign]

ma kann "onEnterFrame" nich löschen, wenn es auf dem clip liegt?

[Der Frager]

Nein.

onClipEvent(enterFrame) {
     delete this.onEnterFrame
     trace("läuft")
} 

[Cysign]

cool, dankö. das erklärt mir, warum ich gestern die ganze zeit am verzweifeln war, bis ich es anderst gelöst hatte

hatte irgendwo mal was davon gelesen, dass man onEnterFrames killen kann...dann ein bisschen gegoogelt und das dann versucht zu bauen, lief aber die ganze zeit weiter.

[maxbahr01]

Zitat von Der Frager

Ich würde das allerdings vom Clip runternehmen, da man sonst das (enterFrame) nicht löschen kann. Das verbraucht dann unnütz Rechenleistung.

Ist es denn ratsam das Script vom MC runter zu nehmen? Und wenn ja wie muss ich dann den Instanznamen im Script angeben. Du meinstest doch damit dass ich das Script in die Hauptzeitleiste verlege, oder?

[Der Frager]

Jau. Das hier in die Hauptzeitleiste:

this.deinMC._x = -320;
this.deinMC._y = 200;
this.deinMC.onEnterFrame = function() {
    if (Math.round(this._x)<220 && Math.round(this._y)<340) {
        this._x += (220-this._x)/5;
        this._y += (340-this._y)/5;
    } else {
        delete this.onEnterFrame;
        this._x=220, this._y=340;
        trace("onEnterFrame deleted!");
    }
}; 

...und dem MC einen Instanznamen geben (im Beispiel deinMC). Das war's dann.

Und hier nochmal ein ähnliches Teil als Prototype:

MovieClip.prototype.flyin = function(startX, startY, zielX, zielY, speed) {
        this._x = startX;
        this._y = startY;
        this.onEnterFrame = function() {
                if (Math.round(this._x) != zielX && Math.round(this._y) != zielY) {
                        this._x += (zielX-this._x)/speed;
                        this._y += (zielY-this._y)/speed;
                } else {
                        delete this.onEnterFrame;
                        this._x = zielX;
                        this._y = zielY;
                }
        };
};
deinMC.flyin(0, 0, 500, 400, 10);